util-faststonethumbs.cmd

@echo off
rem Froz 12.05.2016
if -%1==- goto hlp
title Построение миниатюр Faststone Image Viewer...
if not exist %1 echo %1 не найден, выходим.& goto e
if exist "%windir%\syswow64" (
  set FS="%programfiles(x86)%\FastStone Image Viewer\FSViewer.exe") else (
  set FS="%programfiles%\FastStone Image Viewer\FSViewer.exe"
)
if not exist %FS% echo %FS% не найден, выходим.& goto e
set FSDB="%appdata%\FastStone\FSIV\FSViewer.db"
if not exist %FSDB% echo %FSDB% не найден, выходим.& goto e
for /R %1 %%i in (.) do call :wrk "%%i"
echo.
echo Готово.
goto e

:hlp
set MSG="Построение миниатюр Faststone Image Viewer для заданной папки и подпапок."
set VB="%temp%\$%~n0-hlp$.vbs"
chcp 1251 >nul
echo MsgBox %MSG%,,"%~nx0">%VB%
chcp 866 >nul
%VB% & del %VB%

:e
pause
goto:eof


:: Subroutines ::
:wrk
echo Обрабатываем %1 ...
start "" %FS% %1
:wait
call :grepdb %FSDB%
set DBS=%DS%
call :grepdb %FSDB%
if not %DS%==%DBS% echo База данных дополнена.& goto wait
exit/b

:grepdb
ping 127.0.0.1>nul
for %%F in (%1) do set DS=%%~zF
exit/b