carpentry_slabs.zs

////Imports
import mods.artisanworktables.builder.RecipeBuilder;

////Variables
val artisansSaw = <ore:artisansHandsaw>;
val artisansHammer = <ore:artisansHammer>;
val stick = <minecraft:stick>;
var slabsForWood = {
	<minecraft:planks> : <minecraft:wooden_slab>,
	<minecraft:planks:1> : <minecraft:wooden_slab:1>,
	<minecraft:planks:2> : <minecraft:wooden_slab:2>,
	<minecraft:planks:3> : <minecraft:wooden_slab:3>,
	<minecraft:planks:4> : <minecraft:wooden_slab:4>,
	<minecraft:planks:5> : <minecraft:wooden_slab:5>,
	<aether_legacy:skyroot_plank> : <aether_legacy:skyroot_slab>,
	<botania:livingwood> : <botania:livingwood0slab>,
	<botania:livingwood:1> : <botania:livingwood1slab>,
	<botania:dreamwood> : <botania:dreamwood0slab>,
	<botania:dreamwood:1> : <botania:dreamwood1slab>,
	<botania:shimmerwoodplanks> : <botania:shimmerwoodplanks0slab>,
	<quark:vertical_planks> : <earthworks:itemslab_planks_vert_oak>,
	<quark:vertical_planks:1> : <earthworks:itemslab_planks_vert_spruce>,
	<quark:vertical_planks:2> : <earthworks:itemslab_planks_vert_birch>,
	<quark:vertical_planks:3> : <earthworks:itemslab_planks_vert_jungle>,
	<quark:vertical_planks:4> : <earthworks:itemslab_planks_vert_acacia>,
	<quark:vertical_planks:5> : <earthworks:itemslab_planks_vert_dark_oak>,
	<earthworks:block_timber> : <earthworks:itemslab_timber>,
	<earthworks:block_timber_birch> : <earthworks:itemslab_timber_birch>,
	<earthworks:block_timber_spruce> : <earthworks:itemslab_timber_spruce>,
	<earthworks:block_timber_jungle> : <earthworks:itemslab_timber_jungle>,
	<earthworks:block_timber_acacia> : <earthworks:itemslab_timber_acacia>,
	<earthworks:block_timber_dark_oak> : <earthworks:itemslab_timber_dark_oak>,
	<earthworks:block_wood_shingle> : <earthworks:itemslab_wood_shingle_oak>,
	<earthworks:block_wood_shingle:1> : <earthworks:itemslab_wood_shingle_spruce>,
	<earthworks:block_wood_shingle:2> : <earthworks:itemslab_wood_shingle_birch>,
	<earthworks:block_wood_shingle:3> : <earthworks:itemslab_wood_shingle_jungle>,
	<earthworks:block_wood_shingle:4> : <earthworks:itemslab_wood_shingle_acacia>,
	<earthworks:block_wood_shingle:5> : <earthworks:itemslab_wood_shingle_dark_oak>,
	<immersiveengineering:treated_wood> : <immersiveengineering:treated_wood_slab>,
	<immersiveengineering:treated_wood:1> : <immersiveengineering:treated_wood_slab:1>,
	<immersiveengineering:treated_wood:2> : <immersiveengineering:treated_wood_slab:2>,
	<mist:acacia_block:13> : <mist:acacia_slab>,
	<mist:aspen_block:13> : <mist:aspen_slab>,
	<mist:a_tree_block:13> : <mist:a_tree_slab>,
	<mist:birch_block:13> : <mist:birch_slab>,
	<mist:oak_block:13> : <mist:oak_slab>,
	<mist:pine_block:13> : <mist:pine_slab>,
	<mist:poplar_block:13> : <mist:poplar_slab>,
	<mist:snow_block:13> : <mist:snow_slab>,
	<mist:spruce_block:13> : <mist:spruce_slab>,
	<mist:s_tree_block:13> : <mist:s_tree_slab>,
	<mist:t_tree_block:13> : <mist:t_tree_slab>,
	<mist:willow_block:13> : <mist:willow_slab>,
	<plants2:crystal_planks> : <plants2:crystal_slab>,
	<plants2:crystal_planks:1> : <plants2:dark_crystal_slab>,
	<plants2:planks> : <plants2:ash_slab>,
	<plants2:planks:1> : <plants2:blaze_slab>,
	<plants2:planks:2> : <plants2:black_kauri_slab>,
	<plants2:planks:3> : <plants2:brazillian_pine_slab>,
	<plants2:planks:4> : <plants2:incense_cedar_slab>,
	<plants2:planks:5> : <plants2:murray_pine_slab>,
	<quark:stained_planks> : <quark:stained_planks_white_slab>,
	<quark:stained_planks:1> : <quark:stained_planks_orange_slab>,
	<quark:stained_planks:2> : <quark:stained_planks_magenta_slab>,
	<quark:stained_planks:3> : <quark:stained_planks_light_blue_slab>,
	<quark:stained_planks:4> : <quark:stained_planks_yellow_slab>,
	<quark:stained_planks:5> : <quark:stained_planks_lime_slab>,
	<quark:stained_planks:6> : <quark:stained_planks_pink_slab>,
	<quark:stained_planks:7> : <quark:stained_planks_gray_slab>,
	<quark:stained_planks:8> : <quark:stained_planks_silver_slab>,
	<quark:stained_planks:9> : <quark:stained_planks_cyan_slab>,
	<quark:stained_planks:10> : <quark:stained_planks_purple_slab>,
	<quark:stained_planks:11> : <quark:stained_planks_blue_slab>,
	<quark:stained_planks:12> : <quark:stained_planks_brown_slab>,
	<quark:stained_planks:13> : <quark:stained_planks_green_slab>,
	<quark:stained_planks:14> : <quark:stained_planks_red_slab>,
	<quark:stained_planks:15> : <quark:stained_planks_black_slab>,
	<quark:bark> : <quark:bark_oak_slab>,
	<quark:bark:1> : <quark:bark_spruce_slab>,
	<quark:bark:2> : <quark:bark_birch_slab>,
	<quark:bark:3> : <quark:bark_jungle_slab>,
	<quark:bark:4> : <quark:bark_acacia_slab>,
	<quark:bark:5> : <quark:bark_dark_oak_slab>,
	<rustic:planks> : <rustic:olive_slab_item>,
	<rustic:planks:1> : <rustic:ironwood_slab_item>,
	<terraqueous:planks> : <terraqueous:type_earth:50>,
	<terraqueous:planks:1> : <terraqueous:type_earth:51>,
	<terraqueous:planks:2> : <terraqueous:type_earth:52>,
	<terraqueous:planks:3> : <terraqueous:type_earth:53>,
	<terraqueous:planks:4> : <terraqueous:type_earth:54>,
	<terraqueous:planks:5> : <terraqueous:type_earth:55>,
	<terraqueous:planks:6> : <terraqueous:type_earth:56>,
	<terraqueous:planks:7> : <terraqueous:type_earth:57>,
	<terraqueous:planks:8> : <terraqueous:type_earth:58>,
	<terraqueous:planks:9> : <terraqueous:type_earth:59>,
	<thebetweenlands:weedwood_planks> : <thebetweenlands:weedwood_plank_slab>,
	<thebetweenlands:rubber_tree_planks> : <thebetweenlands:rubber_tree_plank_slab>,
	<thebetweenlands:giant_root_planks> : <thebetweenlands:giant_root_plank_slab>,
	<wizardry:wisdom_wood_planks> : <wizardry:wisdom_wood_slab>
} as IItemStack[IItemStack];

for wood, slab in slabsForWood {
	recipes.remove(slab);

	RecipeBuilder.get("basic")
		.setShaped([[wood, wood, wood]])
		.setTool(artisansSaw, 1)
		.addOutput(slab * 6)
		.requireGameStages("ALL", ["woodcutting_1", "wood_slab"])
		.excludeGameStages(["woodcutting_2"])
		.create();

	RecipeBuilder.get("basic")
		.setShaped([[wood, wood, wood]])
		.setTool(artisansSaw, 1)
		.addOutput(slab * 6)
		.setExtraOutputOne(stick * 2, 0.5)
		.setExtraOutputTwo(stick, 0.5)
		.setExtraOutputThree(stick, 0.5)
		.requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "wood_slab"])
		.excludeGameStages(["woodcutting_3"])
		.create();

	RecipeBuilder.get("basic")
		.setShaped([[wood, wood, wood]])
		.setTool(artisansSaw, 1)
		.addOutput(slab * 6)
		.setExtraOutputOne(stick * 4, 0.5)
		.setExtraOutputTwo(stick * 2, 0.5)
		.setExtraOutputThree(stick, 0.5)
		.requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3", "wood_slab"])
		.create();

	RecipeBuilder.get("basic")
		.setShaped([[slab], [slab]])
		.setTool(artisansHammer, 1)
		.addOutput(wood)
		.requireGameStages("ALL", ["woodcutting_2", "wood_slab"])
		.create();
}