sasquatch-git

pkgname=sasquatch-git
pkgrel=4
pkgver=r58.3e0cc40
pkgdesc='Patched unsquashfs utility with support for vendor-specific SquashFS implementations'
arch=('x86_64')
url='https://github.com/devttys0/sasquatch'
license=('unknown')
depends=('lzo' 'xz' 'zlib')
makedepends=('git')
provides=('sasquatch')
conflicts=('sasquatch')
source=("${pkgname}::git+${url}.git"
        'https://downloads.sourceforge.net/project/squashfs/squashfs/squashfs4.3/squashfs4.3.tar.gz')
sha512sums=('SKIP'
            '854ed7acc99920f24ecf11e0da807e5a2a162eeda55db971aba63a03f0da2c13b20ec0564a906c4b0e415bd8258b273a10208c7abc0704f2ceea773aa6148a79')

prepare() {
    cd "${srcdir}/squashfs4.3"
    patch -p0 < "${srcdir}/${pkgname}/patches/patch0.txt"
}

pkgver() {
    cd "${srcdir}/${pkgname}"
    printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "${srcdir}/squashfs4.3/squashfs-tools"
    make EXTRA_CFLAGS=-fcommon
}

package() {
    cd "${srcdir}/squashfs4.3/squashfs-tools"
    make INSTALL_DIR="${pkgdir}/usr/bin" install
}