-	script	Sample	-1,{

OnPCLoginEvent:
if( prestige_count ){
	atcommand "@adjgroup "+prestige_count;
}
end;

OnPrestige:
if( BaseLevel < 150 || JobLevel < 50 ){
	message strcharinfo(0),"You need to be Level 150 and Job Level 50.";
}else if( prestige_count >= .max_limit ){
	message strcharinfo(0),"You can only prestige maximum of "+.max_limit+" times.";
}else if( prestige_count >= 8 ){
	message strcharinfo(0),"You can only prestige through a Custom Quests.";
}else{
	explode( .@prestige_job_list$,prestige_job_list$,"|" );
	.@prestige_job_list_size = getarraysize( .@prestige_job_list$ );
	.@prestige_job_list$[ .@prestige_job_list_size ] = Class;
	prestige_job_list$ = implode( .@prestige_job_list$,"|" );
	prestige_count++;
	jobchange Job_Novice;
	resetlvl 1;
	StatusPoint = 100;
	message strcharinfo(0),"Prestiged for "+prestige_count+"/"+.max_limit+" times.";
}
end;

OnChangeClass:
if( !prestige_count ){
	dispbottom "You didnt prestiged yet.";
}else if( !.@atcmd_numparameters || !compare( prestige_job_list$+"|",.@atcmd_parameters$[0]+"|" ) ){
	dispbottom "@changeclass <job id> / @cc <job id>";
	dispbottom "=======================================";
	explode( .@prestige_job_list$,prestige_job_list$,"|" );
	.@prestige_job_list_size = getarraysize( .@prestige_job_list$ );
	while( .@i < .@prestige_job_list_size ){
		if( !compare( ":"+.@menu$+":" , ":"+.@prestige_job_list$[.@i]+":" ) ){
			.@menu$ = .@menu$ + .@prestige_job_list$[.@i] +":";
			.@job_menu[ .@job_menu_size ] = .@prestige_job_list$[.@i];
			.@job_menu_size++;
		}
		.@i++;
	}
	.@i = 0;
	while( .@i < .@job_menu_size ){
		dispbottom "ID: "+.@job_menu[.@i]+" - "+jobname( .@job_menu[.@i] );
		.@i++;
	}

}else if( !compare( prestige_job_list$+"|",.@atcmd_parameters$[0]+"|" ) ){
	dispbottom "This Job ID doesnt exist in your prestige.";
}else{
	.@job_id = atoi( .@atcmd_parameters$[0] );
	jobchange .@job_id;
	message strcharinfo(0),"Changed to "+jobname( .@job_id );
}
end;

OnInit:
// max pretige amount
.max_limit = 10;

// custom commands
bindatcmd "prestige",strnpcinfo(0)+"::OnPrestige";
bindatcmd "changeclass",strnpcinfo(0)+"::OnChangeClass";
bindatcmd "cc",strnpcinfo(0)+"::OnChangeClass";
end;
}