Sejda PKGBUILD 7.7.2

# Maintainer:  Chris Severance aur.severach aATt spamgourmet dott com
# Maintainer: Thibault Molleman <aur at thibaultmol d0t link>
# Contributor: Frederic Bezies <fredbezies at gmail dot com>
# Contributor: James An <[email protected]>
# Contributor: Jonas Heinrich <[email protected]>

pkgname='sejda-desktop'
pkgver='7.7.2'
pkgrel='1'
license=('LicenseRef-EULA')
pkgdesc='PDF editor'
arch=('x86_64')
depends=(libxcb libxfixes nspr alsa-lib libcups at-spi2-core libxrandr libdrm libxrender pango nss libxcomposite cairo libxdamage libxkbcommon mesa gtk3)
depends+=(libx11 glibc bash expat libxext libxtst dbus libxi gcc-libs glib2)
url='http://www.sejda.com/desktop'
source=("https://downloads.sejda-cdn.com/sejda-desktop_${pkgver}_amd64.deb")
md5sums=('888968b7a3bee0f9fdc2d4077b5652ad')
sha512sums=('83ed6723ef240e238fd056be53b305bd84d908fac1983049bb4bd6f55b6d06319b76e3df948d13bcb2f919f7a016dbbbcdda5270d17787dbe655461b00dd6d60')
options=('!strip')

prepare() {
  bsdtar -xf 'control.tar.gz'
  sed -e 's:/opt/:opt/:g' 'postinst' > 'postinst.Arch'
}

package() {
  bsdtar --no-same-owner --no-same-permissions -xf 'data.tar.gz' -C "${pkgdir}"
  cd "${pkgdir}"
  install -d 'usr/bin'
  ln -s '/opt/sejda-desktop/sejda-desktop' 'usr/bin/sejda-desktop'

  find -type 'f' '(' -name '.DS_Store' -o -iname '*.bat' ')' -delete

  # fix permissions
  bash "${srcdir}/postinst.Arch"

  # symlink licenses
  install -d "usr/share/licenses/${pkgname}"
  local _i
  for _i in 'EULA.pdf' 'LICENSE.electron' 'LICENSES.chromium.html'; do
    ln -s "/opt/sejda-desktop/${_i}" "usr/share/licenses/${pkgname}/${_i}"
  done
}