TiraEspinhos

$${

if(tiraespinhos);
    log("         ");
    log("         ");
    log("&6[&e>>!<<&6] &7Macro de remover &e&lespinhos &4desativada&7.");
    log("         ");
    log("         ");

    unset(thorns);
    unset(aqua);
    unset(tiraespinhos);
    stop();
else;
    log("         ");
    log("         ");
    log("&6[&e>>!<<&6] &7Macro de remover &e&lespinhos &aativada&7.");
    log("         ");
    log("         ");

    achievementget("Discord: ThiagoSzz#3482",310);

    set(tiraespinhos);

    log("&6[&e>>!<<&6] &7Iniciando processo.");

    do;
        log("&6[&e>>!<<&6] &7Pressione &c&l&oLCONTROL &7olhando para o baú.");
        do;
        while(!KEY_LCONTROL);

		log("&6[&e>>!<<&6] &4&lEvite &7mexer o mouse durante o processo.");
        do;
            key(use);
            wait(800ms);
        while(%GUI%!="GUICHEST");

        #qtd=0;

        for(#slot,0,53);
            getslotitem(%#slot%,#id);

            if((%#id%=310)||(%#id%=311)||(%#id%=312)||(%#id%=313));
                unset(thorns);
                unset(aqua);

                slot(9);

                wait(50ms);
                slotclick(%#slot%,l,true);
                wait(50ms);

                foreach(enchantments);
                    if((%ENCHANTMENTNAME%="Thorns")||(%ENCHANTMENTNAME%="Espinhos"));
                        set(thorns);
                    elseif((%ENCHANTMENTNAME%="Aqua Affinity")||(%ENCHANTMENTNAME%="Afinidade Aquática"));
                        set(aqua);
                    endif;
                next;

                if(thorns);
                    log("&6[&e>>!<<&6] &7Slot &e%#slot% &7- &aEspinhos&7.");
                    wait(200ms);

                    do;
                        echo(/desencantar);
                        wait(350ms);
                        getslotitem(0,#iditem);
                        wait(50ms);
                    while(%#iditem%!=399);

                    if(aqua);
                        slotclick(2,l,false);
                    else;
                        slotclick(1,l,false);
                    endif;

                    do;
                        wait(50ms);
                        getslotitem(2,#iditem);
                        wait(100ms);
                    while(%#iditem%!=35);

                    do;
                        slotclick(2,l,false);
                        wait(300ms);
                        getslotitem(0,#iditem);
                    while(%#iditem%!=403);
                    wait(50ms);

                    do;
                        gui();
                        wait(200ms);
                    while(%GUI%!="NONE");

                    do;
                        key(use);
                        wait(800ms);
                    while(%GUI%!="GUICHEST");

                    inc(#qtd,1);
                endif;

                wait(50ms);
                slotclick(89,l,true);
            endif;
        next;

        log("&6[&e>>!<<&6] &7Foram encontradas &c%#qtd% &7partes com espinhos neste baú.");
		log("        ");
		gui();
    loop;
endif;

}$$