Algoritmo "DISTANCIA_ORIGEM"
Var
    n, i, x_i, y_i, dist_i: INTEIRO
    perto_dist, perto_x, perto_y : INTEIRO
    longe_dist, longe_x, longe_y : INTEIRO
Inicio
    ESCREVAL("Digite a quantidade de pontos: ")
    LEIA(n)
    perto_dist := -1
    longe_dist := -1
    PARA i DE 1 ATE n FACA
        ESCREVAL("Digite a coordenada x do ponto")
        LEIA(x_i)
        ESCREVAL("Digite a coordenada y do ponto")
        LEIA(y_i)
        dist_i := x_i * x_i + y_i * y_i
        SE ((i = 1) OU (perto_dist = -1) OU (longe_dist = -1)) ENTAO
            perto_x := x_i
            perto_y := y_i
            longe_x := x_i
            longe_y := y_i
            perto_dist := dist_i
            longe_dist := dist_i
        FIMSE
        SE (dist_i < perto_dist) ENTAO
            perto_x := x_i
            perto_y := y_i
            perto_dist := dist_i
        SENAO
             SE (dist_i > longe_dist) ENTAO
                 longe_x := x_i
                 longe_y := y_i
                 longe_dist := dist_i
             FIMSE
        FIMSE
    FIMPARA
    SE ((longe_x = perto_x) E (longe_y = perto_y)) ENTAO
        ESCREVAL("Ponto único: (", perto_x, ", ", perto_y, ")")
    SENAO
        ESCREVAL("Ponto mais perto: (", perto_x, ", ", perto_y, ")")
        ESCREVAL("Ponto mais distante: (", longe_x, ", ", longe_y, ")")
    FIMSE
Fimalgoritmo