R296

OBJECT Report 296 Batch Post Sales Orders
{
  OBJECT-PROPERTIES
  {
    Date=24-04-14;
    Time=12:00:00;
    Version List=NAVW17.10,CGITS7.00.03,(00654882);
  }
  PROPERTIES
  {
    CaptionML=[DAN=Massebogf›r salgsordrer;
               ENU=Batch Post Sales Orders];
    ProcessingOnly=Yes;
    OnPreReport=BEGIN
                  //{CGITS/001/START}
                  IF ("Job Queue Entry".GETFILTER(ID) <> '') THEN BEGIN
                    JobQueueEntry.RESET;
                    JobQueueEntry.SETFILTER(ID,"Job Queue Entry".GETFILTER(ID));
                    JobQueueEntry.FINDFIRST;

                    WITH JobQueueEntry DO BEGIN
                      SalesHeaderView := "Sales Header".GETVIEW;
                      IF NOT GUIALLOWED THEN BEGIN
                        SalesHeaderView := GetTableView(DATABASE::"Sales Header",SalesHeaderView);
                        ShipReq := "Yes/No 1";
                        InvReq := "Yes/No 2";
                        ReplacePostingDate := "Yes/No 3";
                        ReplaceDocumentDate := "Yes/No 4";
                        CalcInvDisc := "Yes/No 5";
                        IF "Date 1" <> 0D THEN
                          PostingDateReq := "Date 1"
                        ELSE
                          PostingDateReq := CALCDATE("Date Formula 1",WORKDATE);

                        "Sales Header".SETVIEW(SalesHeaderView);
                        IF FORMAT("Date Formula 2") <> '' THEN
                          "Sales Header".SETRANGE("Promised Delivery Date",0D,CALCDATE("Date Formula 2",WORKDATE));
                        IF FORMAT("Date Formula 3") <> '' THEN
                          "Sales Header".SETRANGE("Shipment Date",0D,CALCDATE("Date Formula 3",WORKDATE));
                        SalesHeaderView := "Sales Header".GETVIEW;
                      END ELSE
                        IF ConfirmUpdateTask THEN BEGIN
                          LOCKTABLE;
                          GET(GETFILTER(ID));
                          "Yes/No 1" := ShipReq;
                          "Yes/No 2" := InvReq;
                          "Yes/No 3" := ReplacePostingDate;
                          "Yes/No 4" := ReplaceDocumentDate;
                          "Yes/No 5" := CalcInvDisc;

                          IF (PostingDateReq = WORKDATE) THEN BEGIN
                            EVALUATE("Date Formula 1",'0D');
                            "Date 1" := 0D;
                          END ELSE
                            "Date 1" := PostingDateReq;

                          SetTableView(DATABASE::"Sales Header",SalesHeaderView);
                          MODIFY;
                          COMMIT;
                          CurrReport.QUIT;
                        END ELSE
                          CurrReport.QUIT;
                    END;
                  END;
                  //{CGITS/001/STOP}
                END;

  }
  DATASET
  {
    { 75001;   ;DataItem;                    ;
               DataItemTable=Table472;
               DataItemTableView=SORTING(ID);
               OnPreDataItem=BEGIN
                               //{CGITS/001/START}
                               CurrReport.BREAK;
                               //{CGITS/001/STOP}
                             END;
                              }

    { 6640;    ;DataItem;                    ;
               DataItemTable=Table36;
               DataItemTableView=SORTING(Document Type,No.) WHERE(Document Type=CONST(Order));
               ReqFilterHeadingML=[DAN=Salgsordre;
                                   ENU=Sales Order];
               OnPreDataItem=BEGIN
                               //{CGITS/001/START}
                               SETVIEW(SalesHeaderView);
                               //{CGITS/001/STOP}

                               IF ReplacePostingDate AND (PostingDateReq = 0D) THEN
                                 ERROR(Text000);

                               ApprovalTemplate.SETCURRENTKEY("Table ID","Document Type",Enabled);
                               ApprovalTemplate.SETRANGE("Table ID",DATABASE::"Sales Header");
                               ApprovalTemplate.SETRANGE("Document Type","Document Type"::Order);
                               ApprovalTemplate.SETRANGE(Enabled,TRUE);
                               IF ApprovalTemplate.FINDFIRST THEN
                                 SETRANGE(Status,Status::Released);

                               CounterTotal := COUNT;

                               //{CGITS/001/START}
                               IF GUIALLOWED THEN
                               //{CGITS/001/STOP}
                                 Window.OPEN(Text001);
                             END;

               OnAfterGetRecord=BEGIN
                                  IF CalcInvDisc THEN
                                    CalculateInvoiceDiscount;

                                  Counter := Counter + 1;

                                  //{CGITS/001/START}
                                  IF GUIALLOWED THEN BEGIN
                                  //{CGITS/001/STOP}
                                    Window.UPDATE(1,"No.");
                                    Window.UPDATE(2,ROUND(Counter / CounterTotal * 10000,1));
                                  //{CGITS/001/START}
                                  END;
                                  //{CGITS/001/STOP}

                                  Ship := ShipReq;
                                  Invoice := InvReq;
                                  CLEAR(SalesPost);
                                  SalesPost.SetPostingDate(ReplacePostingDate,ReplaceDocumentDate,PostingDateReq);
                                  IF IsApprovedForPostingBatch THEN
                                    IF SalesPost.RUN("Sales Header") THEN BEGIN
                                      CounterOK := CounterOK + 1;
                                      IF MARKEDONLY THEN
                                        MARK(FALSE);

                                    END;
                                END;

               OnPostDataItem=BEGIN
                                //{CGITS/001/START}
                                IF GUIALLOWED THEN BEGIN
                                //{CGITS/001/STOP}
                                  Window.CLOSE;
                                  MESSAGE(Text002,CounterOK,CounterTotal);
                                //{CGITS/001/START}
                                END;
                                //{CGITS/001/STOP}
                              END;

               ReqFilterFields=No.,Status }

  }
  REQUESTPAGE
  {
    PROPERTIES
    {
      SaveValues=Yes;
      OnOpenPage=BEGIN
                   SalesSetup.GET;
                   CalcInvDisc := SalesSetup."Calc. Inv. Discount";
                   ReplacePostingDate := FALSE;
                   ReplaceDocumentDate := FALSE;
                 END;

    }
    CONTROLS
    {
      { 1900000001;0;Container;
                  ContainerType=ContentArea }

      { 1900000002;1;Group  ;
                  CaptionML=[DAN=Indstillinger;
                             ENU=Options] }

      { 1   ;2   ;Field     ;
                  Name=Ship;
                  CaptionML=[DAN=Lever;
                             ENU=Ship];
                  SourceExpr=ShipReq }

      { 2   ;2   ;Field     ;
                  Name=Invoice;
                  CaptionML=[DAN=Fakturer;
                             ENU=Invoice];
                  SourceExpr=InvReq }

      { 3   ;2   ;Field     ;
                  Name=PostingDate;
                  CaptionML=[DAN=Bogf›ringsdato;
                             ENU=Posting Date];
                  SourceExpr=PostingDateReq }

      { 4   ;2   ;Field     ;
                  CaptionML=[DAN=Erstat bogf›ringsdato;
                             ENU=Replace Posting Date];
                  SourceExpr=ReplacePostingDate;
                  OnValidate=BEGIN
                               IF ReplacePostingDate THEN
                                 MESSAGE(Text003);
                             END;
                              }

      { 5   ;2   ;Field     ;
                  CaptionML=[DAN=Erstat bilagsdato;
                             ENU=Replace Document Date];
                  SourceExpr=ReplaceDocumentDate }

      { 7   ;2   ;Field     ;
                  CaptionML=[DAN=Beregn fakturarabat;
                             ENU=Calc. Inv. Discount];
                  SourceExpr=CalcInvDisc;
                  OnValidate=BEGIN
                               SalesSetup.GET;
                               SalesSetup.TESTFIELD("Calc. Inv. Discount",FALSE);
                             END;
                              }

    }
  }
  LABELS
  {
  }
  CODE
  {
    VAR
      Text000@1000 : TextConst 'DAN=Indtast bogf›ringsdatoen.;ENU=Please enter the posting date.';
      Text001@1001 : TextConst 'DAN=Ordrer bogf›res #1########## @2@@@@@@@@@@@@@;ENU=Posting orders  #1########## @2@@@@@@@@@@@@@';
      Text002@1002 : TextConst 'DAN=%1 ordrer ud af i alt %2 er nu bogf›rte.;ENU=%1 orders out of a total of %2 have now been posted.';
      Text003@1003 : TextConst 'DAN=Den valutakurs, som er knyttet til den nye bogf›ringsdato i salgshovedet, g‘lder ikke for salgslinjerne.;ENU=The exchange rate associated with the new posting date on the sales header will not apply to the sales lines.';
      SalesLine@1005 : Record 37;
      SalesSetup@1006 : Record 311;
      ApprovalTemplate@1021 : Record 464;
      SalesCalcDisc@1007 : Codeunit 60;
      SalesPost@1008 : Codeunit 80;
      Window@1009 : Dialog;
      ShipReq@1010 : Boolean;
      InvReq@1011 : Boolean;
      PostingDateReq@1012 : Date;
      CounterTotal@1013 : Integer;
      Counter@1014 : Integer;
      CounterOK@1015 : Integer;
      ReplacePostingDate@1016 : Boolean;
      ReplaceDocumentDate@1017 : Boolean;
      CalcInvDisc@1018 : Boolean;
      ">> CGITS_VAR <<"@75003 : Integer;
      JobQueueEntry@75000 : Record 472;
      SalesHeaderView@75002 : Text[1024];

    PROCEDURE CalculateInvoiceDiscount@1();
    BEGIN
      SalesLine.RESET;
      SalesLine.SETRANGE("Document Type","Sales Header"."Document Type");
      SalesLine.SETRANGE("Document No.","Sales Header"."No.");
      IF SalesLine.FINDFIRST THEN
        IF SalesCalcDisc.RUN(SalesLine) THEN BEGIN
          "Sales Header".GET("Sales Header"."Document Type","Sales Header"."No.");
          COMMIT;
        END;
    END;

    PROCEDURE InitializeRequest@2(ShipParam@1000 : Boolean;InvoiceParam@1001 : Boolean;PostingDateParam@1002 : Date;ReplacePostingDateParam@1003 : Boolean;ReplaceDocumentDateParam@1004 : Boolean;CalcInvDiscParam@1005 : Boolean);
    BEGIN
      ShipReq := ShipParam;
      InvReq := InvoiceParam;
      PostingDateReq := PostingDateParam;
      ReplacePostingDate := ReplacePostingDateParam;
      ReplaceDocumentDate := ReplaceDocumentDateParam;
      CalcInvDisc := CalcInvDiscParam;
    END;

    PROCEDURE ">> CGITS_FUNC <<"@75100();
    BEGIN
    END;

    PROCEDURE CGITSTranslation@75101(FieldID@75103 : Integer;InTrans@75104 : Text[100]) : Text[100];
    VAR
      TEXT75260@75107 : TextConst 'DAN=Statisk Bogf›ringsdato;ENU=Fixed Posting Date';
      TEXT75250@75001 : TextConst 'DAN=Lev‚r;ENU=Ship';
      TEXT75251@75002 : TextConst 'DAN=Faktur‚r;ENU=Invoice';
      TEXT75252@75003 : TextConst 'DAN=Erstat bogf›ringsdato;ENU=Replace Posting Date';
      TEXT75253@75004 : TextConst 'DAN=Erstat bilagsdato;ENU=Replace Document Date';
      TEXT75254@75005 : TextConst 'DAN=Beregn fakturarabat;ENU=Calc. Inv. Discount';
      TEXT75280@75006 : TextConst 'DAN="Dynamisk Bogf›ringsdato (0D = Arbejdsdato)";ENU="Dynamic Posting Date (0D = Work Date)"';
    BEGIN
      //{CGITS/001/START}
      CASE FieldID OF
        75250 : EXIT(TEXT75250);
        75251 : EXIT(TEXT75251);
        75252 : EXIT(TEXT75252);
        75253 : EXIT(TEXT75253);
        75254 : EXIT(TEXT75254);
        75260 : EXIT(TEXT75260);
        75280 : EXIT(TEXT75280);
      ELSE
        EXIT(InTrans);
      END;
      //{CGITS/001/STOP}
    END;

    BEGIN
    {
      CGITS/001/060513/JENSENKD  Implementation of CGI Task Scheduler Add In
    }
    END.
  }
  RDLDATA
  {
  }
}