patlefort

obs-plugin-input-overlay 5.0.6

Aug 7th, 2026
149
0
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Bash 1.92 KB | Source Code | 0 0
  1. # Maintainer: Patrick Northon <[email protected]>
  2. # Contributor: Yidaozhan Ya <[email protected]>
  3. # Contributor: Artem Klevtsov <[email protected]>
  4.  
  5. _pkgname='input-overlay'
  6. pkgname=obs-plugin-${_pkgname}
  7. pkgver=5.0.6
  8. pkgrel=1
  9. groups=('obs-plugins')
  10. pkgdesc='obs-studio plugin to show keyboard, gamepad and mouse input on stream.'
  11. arch=("x86_64")
  12. url="https://github.com/univrsal/${_pkgname}"
  13. license=('GPL-2.0-only')
  14. depends=('obs-studio' 'libxtst' 'libxkbfile' 'sdl2' 'qt6-base' 'libxt' 'libstdc++' 'libgcc')
  15. makedepends=('git' 'cmake')
  16. source=(
  17.     "git+https://github.com/univrsal/${_pkgname}.git#tag=${pkgver}"
  18.     "univrsal-libuiohook::git+https://github.com/univrsal/libuiohook.git#commit=bee164726dc62e8f8c3a1a4a778164ce8a769143")
  19. sha256sums=('b9383e6781be3bfe8353a5a905b3d288174b095238f1147fd41d7619c919536e'
  20.             'a72d5c5a0963c44973e674ae088ab18dcc9c6f1e5251b8a5f3a02188455be49e')
  21.  
  22. _srcdir="${_pkgname}"
  23.  
  24. prepare() {
  25.     cd "${_srcdir}"
  26.  
  27.     #git submodule init
  28.     #git config 'submodule.deps/libuiohook.url' "$srcdir/univrsal-libuiohook"
  29.     #git -c 'protocol.file.allow=always' submodule update
  30.     rm -f 'deps/libuiohook' || rmdir 'deps/libuiohook'
  31.     ln -s "$srcdir/univrsal-libuiohook" 'deps/libuiohook'
  32.  
  33.     sed -i '/set(CMAKE_CXX_FLAGS "-march=native")/d' 'CMakeLists.txt'
  34. }
  35.  
  36. build() {
  37.     export CXXFLAGS+=' -msse4.1'
  38.     cmake -S "${_srcdir}" -B 'build' -DCMAKE_BUILD_TYPE='None' -DCMAKE_INSTALL_PREFIX='/usr'
  39.     cmake --build 'build'
  40. }
  41.  
  42. package() {
  43.     cd "${_srcdir}"
  44.     install -dm755 "${pkgdir}/usr/lib/obs-plugins"
  45.     install -dm755 "${pkgdir}/usr/share/obs/obs-plugins/${_pkgname}/locale"
  46.     install -dm755 "${pkgdir}/usr/share/obs/obs-plugins/${_pkgname}/presets"
  47.     install -Dm755 "${srcdir}/build/${_pkgname}.so" -t "${pkgdir}/usr/lib/obs-plugins/"
  48.     cp -R 'data/locale'/* "${pkgdir}/usr/share/obs/obs-plugins/${_pkgname}/locale/"
  49.     cp -R 'presets'/* "${pkgdir}/usr/share/obs/obs-plugins/${_pkgname}/presets/"
  50. }
  51.  
Advertisement
Add Comment
Please, Sign In to add comment