audacity-wxgtk2 PKGBUILD

# Maintainer: evorster <[email protected]>
# Contributor: osch <[email protected]>

pkgname=audacity-wxgtk2
pkgver=3.2.5
pkgrel=1
pkgdesc="Record and edit audio files"
arch=('x86_64')
url="https://audacityteam.org"
license=('GPL2' 'CCPL')
groups=('pro-audio')
depends=('libmad' 'libid3tag' 'gtk2' 'glib2' 'soundtouch' 'ffmpeg' 'vamp-plugin-sdk'
'portsmf' 'portmidi' 'twolame' 'suil' 'lilv' 'lv2' 'serd' 'sord' 'sratom' 'python'
'flac' 'libvorbis' 'libogg' 'vamp-plugin-sdk' 'portaudio' 'libsoxr' 'libsndfile' 'lame'
'expat' 'alsa-lib' 'jack' 'util-linux' 'util-linux-libs' 'curl' 'zlib')
makedepends=('cmake' 'autoconf' 'automake' 'libtool' 'git' 'conan1' 'vst3sdk')
provides=("audacity")
conflicts=("audacity")
source=("https://github.com/audacity/audacity/archive/Audacity-${pkgver}.tar.gz")
sha256sums=('7ee4f6f3ea985114b8fda578c67faf163e1d2cc8b2f0bad1b259a9367d2ccb1b')

prepare() {
  cd "audacity-Audacity-${pkgver}"

  sed -i -e '/#include <iterator>/i #include <limits>' libraries/lib-utility/MemoryX.h
  sed -i 's/#THEME_PREFS/THEME_PREFS/g' src/Experimental.cmake

  mkdir -p build
  cd build

  depsDir=$(readlink -f ./.offline)
  export CONAN_USER_HOME="$depsDir/conan"

  conan config home
  conan config init
  conan config set storage.download_cache="$CONAN_USER_HOME/download_cache"
  conan remove "*" --src --builds --force
}

build() {
  cd "audacity-Audacity-${pkgver}"/build

  export VST3SDK='/usr/share/vst3sdk'
  export CFLAGS+=" -DNDEBUG"
  export CXXFLAGS+=" -DNDEBUG"

  cmake -G "Unix Makefiles" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DAUDACITY_BUILD_LEVEL=2 \
        -Daudacity_has_networking=off \
        -Daudacity_lib_preference=system \
        -Daudacity_use_expat=system \
        -Daudacity_use_ffmpeg=loaded \
        -Daudacity_use_zlib=system \
        -Daudacity_use_curl=system \
        -Daudacity_use_wxwidgets=local \
        -Daudacity_use_vst3sdk=system \
        ..

  make
  conan remove "*" --src --builds --force
}

package() {
  cd "audacity-Audacity-${pkgver}"/build
  make DESTDIR="${pkgdir}" install
  chmod -R go=u "${pkgdir}"
  chmod -R go-w "${pkgdir}"
}