PKGBUILD rivendell

# Maintainer: Christian Kohlstedde <christian + arch at kohlsted.de>

pkgname=rivendell
pkgver=3.5.0
pkgrel=1

pkgdesc="Open Source Radio Automation"

arch=(x86_64)
url="http://www.rivendellaudio.org/"
license=('GPL2')

depends=(
  'curl'
  'libxi'
  'cdrtools'
  'id3lib'
  'cdparanoia'
  'libsndfile'
  'mariadb'
  'qt4' #This app is still being ported to qt5: https://github.com/ElvishArtisan/rivendell/tree/qt5
  'libsamplerate'
  'soundtouch'
  'jack'
  'alsa-lib'
  'flac'
  'faad2'
  'libmp4v2'
  'lame'
  'libmad'
  'twolame'
  'taglib'
  'libvorbis'
  'libcoverart'
  'libxslt'
# 'picard'
)

makedepends=(
  'libmusicbrainz5'
)

backup=('etc/rd.conf')

source=("https://github.com/ElvishArtisan/rivendell/releases/download/v3.5.0/rivendell-3.5.0.tar.gz")
sha256sums=('SKIP')

build() {
  cd "$pkgname-$pkgver"
  export RD_LIB_PATH="lib"

  sh autogen.sh
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib/rivendell/web \
    --libdir=/usr/lib \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --mandir=/usr/share/man \
    --disable-docbook
  make
}

package() {
  cd "$pkgname-$pkgver"

  #touch building-debian

  export RD_LIB_PATH="lib"
  export DESTDIR="$pkgdir"
  rm systemd/daemon-reload.sh
  touch systemd/daemon-reload.sh
  chmod +x systemd/daemon-reload.sh
  make install

  mkdir -p "$pkgdir"/etc/rivendell.d
  mkdir -p "$pkgdir"/etc/httpd/conf/extra/
  install -t "$pkgdir"/etc/rivendell.d -Dm755 conf/*.conf*
  install -Dm755 conf/rd.conf-sample "$pkgdir"/etc/rd.conf
  install -Dm755 conf/rd-bin.conf "$pkgdir"/etc/httpd/conf/extra/rd-bin.conf
  mv $pkgdir/$pkgname/lib/systemd $pkgdir/usr/lib
}