API tools faq
paste
Advertisement
johnlol

Devil Square M

johnlol
Aug 2nd, 2023
919
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
VeriLog 17.30 KB | Gaming | 0 0
raw download clone embed print report
  1. //===== Hercules Script ======================================
  2. //= Devil Square
  3. //===== By: ==================================================
  4. //= Kirlein (Tyirial Script Concept), Stillhard aka Dewa (Translation)
  5. //===== Current Version: =====================================
  6. //= 2.0
  7. //===== Description: =========================================
  8. //= Devil Square based off the mmorpg Muonline
  9. //===== Additional Comments: =================================
  10. //= ??? Completely rewrite by ~AnnieRuru~
  11. //= 2.0 First Version [Racaae]
  12. //============================================================
  13.  
  14. prontera,164,162,3  script  Guardião do Portal#DS  JP_RUFAKU,{
  15.  
  16.     set .DevilSquare,getvariableofnpc(.DevilSquare,"Controle#DS");
  17.     set .DS_MinLevel,getvariableofnpc(.DS_MinLevel,"Controle#DS");
  18.     set .DS_Zeny,getvariableofnpc(.DS_Zeny,"Controle#DS");
  19.     set .DS_PlayerMax,getvariableofnpc(.DS_PlayerMax,"Controle#DS");
  20.     set .DS_Treasure,getvariableofnpc(.DS_Treasure,"Controle#DS");
  21.    
  22.    
  23.     //cutin "jpn_rfak01",2;
  24.     mes "[Guardião do Portal]";
  25.     mes "Olá aventureiro.";
  26.     mes "Eu sou o guardião do portal de entrada para a ^FF0000Devil Square^000000.";
  27.     if (getgmlevel() >= .DS_GroupId)
  28.         mes "^0000ff-Use @gm_ds para controlar o evento.-^000000";
  29.     next;
  30.     switch(select("Entrar na Devil Square.:Informação.:Cancelar.")) {
  31.     case 1:
  32.         if (.DevilSquare != 1) {
  33.             mes "[Guardião do Portal]";
  34.             mes "O portal está fechado, ele se abre a cada meia hora.";
  35.             close2;
  36.             cutin "",255;
  37.             end;
  38.         }
  39.         else if (BaseLevel < .DS_MinLevel || Zeny < .DS_Zeny) {
  40.             mes "[Guardião do Portal]";
  41.             mes "Desculpe, o nível mínimo para entrar é " + .DS_MinLevel + " e a taxa de entrada é de " + .DS_Zeny + "z.";
  42.             close2;
  43.             cutin "",255;
  44.             end;
  45.         }
  46.         else if (getmapusers("ordeal_1-1") >= .DS_PlayerMax) {
  47.             mes "[Guardião do Portal]";
  48.             mes "Desculpe, mas parece que a Devil Square está cheia.";
  49.             mes "O número máximo de jogadores é " + .DS_PlayerMax + ".";
  50.             close2;
  51.             cutin "",255;
  52.             end;
  53.         }
  54.         set Zeny,Zeny - .DS_Zeny;
  55.         announce strcharinfo(0)+" entrou no Devil Square!",8;
  56.         warp "ordeal_1-1",151,130;
  57.         end;
  58.     case 2:
  59.         mes "[Guardião do Portal]";
  60.         mes "O portal para o Devil Square abre a cada quinze minutos, ele fica aberto por 3 minutos. Você deve falar comigo para entrar.";
  61.         next;
  62.         mes "[Guardião do Portal]";
  63.         mes "O número máximo de jogadores lá dentro é " + .DS_PlayerMax + ". Nesse caso, mesmo se o portal estiver aberto, você não poderá entrar mais.";
  64.         next;
  65.         mes "[Guardião do Portal]";
  66.         mes "Você e os outros terão que enfrentar várias ordas de monstros.";
  67.         mes "A cada orda os monstros ficarão mais fortes.";
  68.         next;
  69.         mes "[Guardião do Portal]";
  70.         mes "Se você conseguir vencer até o final, você terá a oportunidade que abrir " + .DS_Treasure + " Báus do Tesouro, talvez até consiga algum item valioso dentro.";
  71.         close2;
  72.         cutin "",255;
  73.         end;
  74.     case 3:
  75.         mes "[Guardião do Portal]";
  76.         mes "Até mais.";
  77.         close2;
  78.         cutin "",255;
  79.         end;
  80.     }
  81.  
  82. OnEventON:
  83.     waitingroom "DS: Portal Aberto!!",0;
  84.     end;
  85. OnEventOFF:
  86.     delwaitingroom;
  87.     end;
  88. }
  89.  
  90. ordeal_1-1,169,170,0    script  Controle#DS HIDDEN_WARP_NPC,2,2,{
  91. OnInit:
  92.  
  93. //===== Opções de configuração ===============================================
  94.  
  95.     .DS_GroupId = 99;   //Grupo necessario para acessar as configurações.
  96.     .DS_PlayerMax = 75; //Numero maximo de jogadores dentro do Devil Square. (0 para infinito)
  97.     .DS_MinLevel = 80;  //Nivel minimo para entrar na Devil Square.
  98.     .DS_Zeny = 20000;   //Zeny necessario para entrar na Devil Square.
  99.     .DS_Rounds = 10;    //Numero de ordas de monstros.
  100.     .DS_WaitTime = 15;  //Tempo -em segundos- de espera entre ordas (0 para desativar).
  101.     .DS_Treasure = 10;  //Numero de Baus do Tesouro invocados no final.
  102.     .DS_NoSkill = 1;    //Desabilitar habilidades durante a quebra de baus? (1 para sim, 0 para nao)
  103.    
  104.     //IDs dos itens no bau (jogador ganha 1 item aleatório da lista).
  105.     setarray .DS_Item,607,608,609,610,12588,13989,17126,14197,14618,14620,12214,14619,14621,14616,14617,16999,14234,13896,13553,13834,13813,17461,17470,17497,17523,616;
  106.     //Itens que sao anunciados quando ganhos.
  107.     setarray .DS_RareItem,12588,16999,12214,14234,13896,17461,17470,17497,17523;
  108.  
  109. //===== Fim das opções de configurações ======================================
  110.  
  111. //===== Monstros =============================================================
  112.  
  113.     //IDs dos monstros da 1º orda.
  114.     setarray .DS_MobList1,1015,1076,1028,1016,1071,1152;    //Esqueletos
  115.     //Quantidade dos monstros da 1º orda.
  116.     setarray .DS_MobQuan1,15,15,15,15,15,15;
  117.     //Mensagem do início da orda (OPCIONAL)
  118.     set .DS_Message1$,"Esqueletos por toda parte!!";
  119.    
  120.     //2º orda
  121.     setarray .DS_MobList2,1253,1193,1257,1191,1192,1163;    //Glast Heim
  122.     setarray .DS_MobQuan2,10,10,10,10,10,15;
  123.     //3º orda
  124.     setarray .DS_MobList3,1219,1198,1109,1131,1302,1272;    //Glast Heim 2
  125.     setarray .DS_MobQuan3,5,10,15,15,3,1;
  126.     //4º orda
  127.     setarray .DS_MobList4,2071,2068,1883,1885,2154,2156;
  128.     setarray .DS_MobQuan4,10,1,10,1,10,1;
  129.     //5º orda
  130.     setarray .DS_MobList5,1775,1776,1777,1778,1779; //Caverna de Gelo
  131.     setarray .DS_MobQuan5,15,25,15,10,1;
  132.     //6º orda
  133.     setarray .DS_MobList6,2015,2016,2017,2018,2019,2022;    //Nidhogg
  134.     setarray .DS_MobQuan6,10,10,10,10,10,1;
  135.     //7º orda
  136.     setarray .DS_MobList7,2083,2084,2085,2086,2087; //Scaraba
  137.     setarray .DS_MobQuan7,20,20,20,20,1;
  138.     //7º orda
  139.     setarray .DS_MobList7,2151,2152,2153,2154,2155,2156;    //Dewata
  140.     setarray .DS_MobQuan7,10,10,10,10,10,1;
  141.     //8º orda
  142.     setarray .DS_MobList8,2161,2162,2163,2164,2165,2166,2167,2168,2169;
  143.     setarray .DS_MobQuan8,10,10,10,10,1,3,3,3,3;
  144.     set .DS_Message8$,"Rainha Scaraba: Essa é a minha vingança!";
  145.     //9º orda
  146.     setarray .DS_MobList9,2473,2474,2475,2476;
  147.     setarray .DS_MobQuan9,25,25,1,1;
  148.     set .DS_Message9$,"Himmelmez: É dito que para me deter é necessário uma pessoa habilidosa.";
  149.     //10º orda
  150.     setarray .DS_MobList10,1917,1918,1919,1920,1921;
  151.     setarray .DS_MobQuan10,1,15,15,15,15;
  152.     set .DS_Message10$,"Imperador Morroc: Vamos acabar com isso!";
  153.  
  154. //===== Fim dos Monstros ===================================================
  155.  
  156.     bindatcmd "gm_ds",strnpcinfo(3)+"::OnAtcommand";
  157.     set .DevilSquare,0;
  158.     hideonnpc "Saída#DS";
  159.     killmonsterall "ordeal_1-1";
  160.     mapwarp "ordeal_1-1","prontera",156,143;
  161.     end;
  162.  
  163. //OnMinute00:
  164. //OnMinute15:
  165. //OnMinute30:
  166. //OnMinute45:
  167. OnClock0600:
  168. OnClock1800:
  169. OnStartEvent:
  170.     if (.DevilSquare) end;
  171.     hideonnpc "Saída#DS";
  172.     hideoffnpc "Guia#DS";
  173.     mapannounce "ordeal_1-1","Imperador Morroc: Tolos mortais, eu venci! Eu sou o Imperador Morroc!!",bc_map,0xFF0000;
  174.     killmonsterall "ordeal_1-1";
  175.     mapwarp "ordeal_1-1","prontera",156,143;
  176.    
  177.     donpcevent "Guardião do Portal#DS::OnEventON";
  178.     announce "O portal para o Devil Square se abriu!! 3 minutos até que ele se feche!",0;
  179.     set .DevilSquare,1;
  180.     sleep 60000;
  181.     if (.DevilSquare != 1) end;
  182.     announce "O portal para a Devil Square fechará em 2 minutos!",0;
  183.     sleep 60000;
  184.     if (.DevilSquare != 1) end;
  185.     announce "O portal para a Devil Square fechará em 1 minuto!",0;
  186.     sleep 60000;
  187.     if (.DevilSquare != 1) end;
  188.     announce "O portal para a Devil Square se fechou!",0;
  189.     donpcevent "Controle#DS::OnBeginEvent";
  190.     end;
  191.    
  192. OnBeginEvent:
  193.     donpcevent "Guardião do Portal#DS::OnEventOFF";
  194.     set .DevilSquare,2;
  195.     hideonnpc "Guia#DS";
  196.     sleep 3000;
  197.     if (getmapusers("ordeal_1-1") == 0) {
  198.         announce "Nenhum jogador compareceu ao Devil Square, o mal prevaleceu...",0;
  199.         set .DevilSquare,0;
  200.         end;
  201.     }
  202.     mapannounce "ordeal_1-1","???: Vamos ver como vocês lidam com meus monstros!",bc_map,0xFF0000;
  203.     sleep 3000;
  204.     initnpctimer;
  205.     donpcevent "Controle#DS::OnMob";
  206.     end;
  207.  
  208. OnMob:
  209.     set .@round, .DevilSquare-1;
  210.    
  211.     copyarray .@MobL, getd(".DS_MobList" + .@round),getarraysize(getd(".DS_MobList" + .@round));
  212.     copyarray .@MobQ, getd(".DS_MobQuan" + .@round),getarraysize(getd(".DS_MobQuan" + .@round));
  213.     if(getd(".DS_Message" + .@round + "$") != "") set .@Message$, getd(".DS_Message" + .@round + "$");
  214.  
  215.     if (.@Message$ != "")
  216.         mapannounce "ordeal_1-1",.@Message$,bc_map,0xFF0000;
  217.     else
  218.         mapannounce "ordeal_1-1","A " + .@round + "º orda de monstros apareceu!",0;
  219.     for (set .@i3, 0; .@i3 <getarraysize(.@MobL); set .@i3, .@i3 + 1) {
  220.         set .DS_MobTotal, .DS_MobTotal+.@MobQ[.@i3];
  221.     }
  222.     for (set .@i1, 0; .@i1<getarraysize(.@MobL); set .@i1, .@i1 + 1) {
  223.         for (set .@i2, 0; .@i2 < .@MobQ[.@i1]; set .@i2, .@i2 + 1) {
  224.             set .@mobGID, areamonster ("ordeal_1-1",121,121,178,178,"[DS] " + strmobinfo(1,.@MobL[.@i1]),.@MobL[.@i1],1,"Controle#DS::OnMyMobDead");
  225.             unitemote .@mobGID, e_gg;
  226.         }
  227.     }
  228.     end;
  229.  
  230. OnMyMobDead:
  231.     set .DS_MobTotal,.DS_MobTotal - 1;
  232.     if(.DS_MobTotal == 25) mapannounce "ordeal_1-1","Restam 25 monstros vivos!",0;
  233.     if(.DS_MobTotal == 5) mapannounce "ordeal_1-1","Restam apenas 5 monstros vivos!",0;
  234.     if(.DS_MobTotal == 1) mapannounce "ordeal_1-1","Resta apenas 1 monstro vivo!",0;
  235.     if(.DS_MobTotal == 0) {
  236.         set .DevilSquare, .DevilSquare+1;
  237.         if (.DevilSquare-2 == .DS_Rounds) {
  238.             stopnpctimer;
  239.             setmapflag "ordeal_1-1",mf_noloot;
  240.             setmapflag "ordeal_1-1",mf_nomobloot;
  241.             donpcevent "Controle#DS::OnBox";
  242.             end;
  243.         }
  244.         set .@round, .DevilSquare-1;
  245.         if (.DS_WaitTime != 0) {
  246.             mapannounce "ordeal_1-1","Todos os monstros foram derrotados! A " + .@round + "º orda de monstros aparecerá logo!",0;
  247.             sleep .DS_WaitTime*1000;
  248.         }
  249.         donpcevent "Controle#DS::OnMob";
  250.     }
  251.     end;
  252.  
  253. OnGMClose:
  254.     announce "O GM fechou o portal da Devil Square!",0;
  255.     donpcevent "Controle#DS::OnBeginEvent";
  256.     end;
  257.    
  258. OnGMEnd:
  259.     if (.DevilSquare == 1)
  260.         announce "O GM fechou o portal da Devil Square!",0;
  261.     else
  262.         mapannounce "ordeal_1-1","O GM terminou o evento!",0;
  263. OnEnd:
  264.     if (.DS_NoSkill) removemapflag "ordeal_1-1",mf_noskill;
  265.     donpcevent "Guardião do Portal#DS::OnEventOFF";
  266.     stopnpctimer;
  267.     set .DevilSquare,0;
  268.     hideonnpc "Saída#DS";
  269.     hideoffnpc "Guia#DS";
  270.     killmonsterall "ordeal_1-1";
  271.     sleep 500;
  272.     mapwarp "ordeal_1-1","prontera",156,143;
  273.     end;
  274.  
  275. OnBox:
  276.     set .DevilSquare, .DevilSquare+1;
  277.     if (.DS_NoSkill) setmapflag "ordeal_1-1",mf_noskill;
  278.     if (.DS_Treasure > 1)
  279.         mapannounce "ordeal_1-1","Parabéns!! " + .DS_Treasure + " Báus do Tesouro apareceram como recompensa do Reino de Rune-Midgard!",0;
  280.     else
  281.         mapannounce "ordeal_1-1","Parabéns!! 1 Báu do Tesouro apareceu como recompensa do Reino de Rune-Midgard!",0;
  282.     set .DS_MobTotal,.DS_Treasure;
  283.     areamonster "ordeal_1-1",121,121,178,178,"Báu do Tesouro",1324,.DS_Treasure,"Controle#DS::OnMyBoxDead";
  284.     end;
  285.  
  286. OnMyBoxDead:
  287.     set @id,rand(getarraysize(.DS_Item));
  288.     getitem .DS_Item[@id],1;
  289.     set .DS_MobTotal, .DS_MobTotal - 1;
  290.     for (set .@i, 0; .@i <getarraysize(.DS_RareItem); set .@i, .@i + 1) {
  291.         if (getelementofarray(.DS_RareItem,.@i) == .DS_Item[@id]) set .@rare,1;
  292.     }
  293.     if (.@rare == 1)
  294.         announce "Devil Square : "+ strcharinfo(0) +" abriu um Báu do Tesouro na Devil Square e ganhou 1 incrível " + getitemname(.DS_Item[@id]) + "!!",0;
  295.     else
  296.         announce "Devil Square : "+ strcharinfo(0) +" abriu um Báu do Tesouro na Devil Square!",0;
  297.     if (.DS_MobTotal == 0) {
  298.         set .DevilSquare,100;
  299.         removemapflag "ordeal_1-1",mf_noloot;
  300.         removemapflag "ordeal_1-1",mf_nomobloot;
  301.         if (.DS_NoSkill) removemapflag "ordeal_1-1",mf_noskill;
  302.         sleep 1000;
  303.         mapannounce "ordeal_1-1","Com isso o Devil Square acabou, obrigado por jogar!",0;
  304.         hideoffnpc "Saída#DS";
  305.     }
  306.     end;
  307.  
  308. OnTimer60000:
  309.     if(.DevilSquare < 2 || .DevilSquare-2 > .DS_Rounds) {
  310.         stopnpctimer;
  311.         end;
  312.     }
  313.     if (getmapusers("ordeal_1-1") == 0) {
  314.         announce "Todos os jogadores falharam em sobreviver na Devil Square!",0;
  315.         donpcevent "Controle#DS::OnEnd";
  316.         end;
  317.     } else {
  318.         if (getmapusers("ordeal_1-1") == 1)
  319.             announce "1 jogador ainda luta na Devil Square!",0;
  320.         else
  321.             announce getmapusers("ordeal_1-1") +" jogadores ainda lutam na Devil Square!",0;
  322.         initnpctimer;
  323.         end;
  324.     }
  325.  
  326. OnAtcommand:
  327.     if(getgroupid() < .DS_GroupId) end;
  328.     switch(select("Iniciar Devil Square.:Terminar Devil Square.:Modificar variáveis.:Ir para o mapa.:Cancelar.")) {
  329.     case 1:
  330.         mes "[Guardião do Portal]";
  331.         if (.DevilSquare == 0) {
  332.             donpcevent "Controle#DS::OnStartEvent";
  333.             mes "Evento iniciado!";
  334.             close;
  335.         }
  336.         mes "O evento já está em andamento.";
  337.         close;
  338.     case 2:
  339.         mes "[Guardião do Portal]";
  340.         if (.DevilSquare != 0) {
  341.             donpcevent "Controle#DS::OnGMEnd";
  342.             mes "Evento terminado!";
  343.             close;
  344.         }
  345.         mes "O evento não foi iniciado.";
  346.         close;
  347.     case 3:
  348.         switch(select("Mudar número de tesouros.:Mudar número máximo de jogadores.:Mudar número de ordas.:Cancelar.")) {
  349.         case 1:
  350.             mes "[Guardião do Portal]";
  351.             mes "Número atual: " + .DS_Treasure;
  352.             mes "Digite o novo número desejado.";
  353.             mes "Digite 0 para cancelar.";
  354.             next;
  355.             input .@new;
  356.             mes "[Guardião do Portal]";
  357.             if (.@new < 1) {
  358.                 mes "Ação cancelada.";
  359.                 close;
  360.             }
  361.             mes "Número antigo: " + .DS_Treasure;
  362.             mes "Número novo: " + .@new;
  363.             if(select("Completar mudança!:Cancelar!") == 2) {
  364.                 close;
  365.             }
  366.             set .DS_Treasure, .@new;
  367.             mes "Novo número de báus invocados como recompensa escolhido com sucesso!";
  368.             close;
  369.         case 2:
  370.             mes "[Guardião do Portal]";
  371.             mes "Número atual: " + .DS_PlayerMax;
  372.             mes "Digite o novo número desejado.";
  373.             mes "Digite 0 para cancelar.";
  374.             next;
  375.             input .@new;
  376.             mes "[Guardião do Portal]";
  377.             if (.@new < 1) {
  378.                 mes "Ação cancelada.";
  379.                 close;
  380.             }
  381.             mes "Número antigo: " + .DS_PlayerMax;
  382.             mes "Número novo: " + .@new;
  383.             if(select("Completar mudança!:Cancelar!") == 2) {
  384.                 close;
  385.             }
  386.             set .DS_PlayerMax, .@new;
  387.             mes "Novo número máximo de jogadores escolhido com sucesso!";
  388.             close;
  389.         case 3:
  390.             mes "[Guardião do Portal]";
  391.             mes "Número atual: " + .DS_Rounds;
  392.             mes "Digite o novo número desejado.";
  393.             mes "Digite 0 para cancelar.";
  394.             next;
  395.             input .@new;
  396.             mes "[Guardião do Portal]";
  397.             if (.@new < 1) {
  398.                 mes "Ação cancelada.";
  399.                 close;
  400.             }
  401.             mes "Número antigo: " + .DS_Rounds;
  402.             mes "Número novo: " + .@new;
  403.             if(select("Completar mudança!:Cancelar!") == 2) {
  404.                 close;
  405.             }
  406.             set .DS_Rounds, .@new;
  407.             mes "Novo número de ordas escolhido com sucesso!";
  408.             close;
  409.         case 4:
  410.             close;
  411.         }
  412.     case 4:
  413.         warp "ordeal_1-1",151,130;
  414.         end;
  415.     case 5:
  416.         close;
  417.     }
  418.  
  419. OnTouch:
  420.     if (getgmlevel() >= .DS_GroupId) {
  421.         mes "^777777(Menu GM)^000000";
  422.         mes "Monstros vivos(na variável): "+.DS_MobTotal;
  423.         mes "Mostros vivos(na real): "+mobcount("this","all");
  424.         mes "Variável .DevilSquare: "+.DevilSquare;
  425.         next;
  426.         switch(select("Cancelar.:Ir para próxima orda.:Mostrar Guia")) {
  427.         case 1:
  428.             close;
  429.         case 2:
  430.             if (.DevilSquare-2 >= .DS_Rounds || !.DevilSquare) {
  431.                 mes "As ordas já acabaram.";
  432.                 close;
  433.             }
  434.             mes "OK!";
  435.             close2;
  436.             killmonsterall "ordeal_1-1";
  437.             set .DS_MobTotal,0;
  438.             set .DevilSquare, .DevilSquare+1;
  439.             if (.DevilSquare-2 == .DS_Rounds) {
  440.                 stopnpctimer;
  441.                 setmapflag "ordeal_1-1",mf_noloot;
  442.                 setmapflag "ordeal_1-1",mf_nomobloot;
  443.                 donpcevent "Controle#DS::OnBox";
  444.                 end;
  445.             }
  446.             set .@round, .DevilSquare-1;
  447.             if (.DS_WaitTime != 0) {
  448.                 mapannounce "ordeal_1-1","Todos os monstros foram derrotados! A " + .@round + "º orda de monstros aparecerá logo!",0;
  449.                 sleep .DS_WaitTime*1000;
  450.             }
  451.             donpcevent "Controle#DS::OnMob";
  452.             end;
  453.         case 3:
  454.             hideoffnpc "Guia#DS";
  455.             close;
  456.         }
  457.     }
  458.     end;
  459. }
  460.  
  461. //===== Guia e Saída ======================================
  462. ordeal_1-1,148,159,5    script  Saída#DS   JP_RUFAKU,{
  463.     mes "[Saída]";
  464.     mes "Muito obrigado pela ajuda. Entretanto, logo ele voltará e sua ajuda será necessária novamente.";
  465.     mes "Já quer sair daqui?";
  466.     next;
  467.     if(select("Vamos embora.:Ainda não.") == 2) close;
  468.     warp "SavePoint",0,0;
  469.     close;
  470. }
  471.  
  472. ordeal_1-1,148,159,5    script  Guia#DS JP_RUFAKU,{
  473.     set .DS_Treasure,getvariableofnpc(.DS_Treasure,"Controle#DS");
  474.     if (getgmlevel() >= .DS_GroupId) {
  475.         switch(select("Ir para menu comum.:^777777-GM-^000000Fechar portal e começar Devil Square.")) {
  476.         case 1:
  477.             break;
  478.         case 2:
  479.             mes "[Guia]";
  480.             mes "Farei isso imediatamente!";
  481.             close2;
  482.             donpcevent "Controle#DS::OnGMClose";
  483.             end;
  484.         }
  485.     }
  486.     mes "[Guia]";
  487.     mes "Serão várias ordas de monstros.";
  488.     mes "A cada orda os monstros ficarão mais fortes.";
  489.     mes "Se você conseguir vencer até o final, você terá a oportunidade que abrir " + .DS_Treasure + " Báus do Tesouro, talvez até consiga algum item valioso dentro.";
  490.     next;
  491.     mes "[Guia]";
  492.     mes "Boa sorte.";
  493.     npcskill "AL_HEAL",11,99,60;
  494.     close;
  495. }
  496.  
  497. morocc,145,86,7 duplicate(Guardião do Portal#DS)   Guardião do Portal#DS2 JP_RUFAKU
  498. geffen,128,70,3 duplicate(Guardião do Portal#DS)   Guardião do Portal#DS3 JP_RUFAKU
  499. payon,165,101,5 duplicate(Guardião do Portal#DS)   Guardião do Portal#DS4 JP_RUFAKU
  500. alberta,37,241,3    duplicate(Guardião do Portal#DS)   Guardião do Portal#DS5 JP_RUFAKU
  501. izlude,104,150,5    duplicate(Guardião do Portal#DS)   Guardião do Portal#DS6 JP_RUFAKU
  502. aldebaran,132,108,5 duplicate(Guardião do Portal#DS)   Guardião do Portal#DS7 JP_RUFAKU
  503. lighthalzen,145,93,5    duplicate(Guardião do Portal#DS)   Guardião do Portal#DS8 JP_RUFAKU
  504. rachel,112,112,5    duplicate(Guardião do Portal#DS)   Guardião do Portal#DS9 JP_RUFAKU
  505.  
  506. //===== Mapflags ======================================
  507. ordeal_1-1  mapflag nowarp
  508. ordeal_1-1  mapflag nowarpto
  509. ordeal_1-1  mapflag noteleport
  510. ordeal_1-1  mapflag monster_noteleport
  511. ordeal_1-1  mapflag nosave
  512. ordeal_1-1  mapflag nomemo
  513. ordeal_1-1  mapflag nobranch
  514. ordeal_1-1  mapflag nopenalty
Tags: ragnarok AdobeRO
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!