nslookup_loop_domains_inside_text_file.bat

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS
COLOR 0A
TITLE LOOP NSLOOKUP USING DOMAINS STORED INSIDE A TEXT FILE

:----------------------------------------------------------------------------------

REM CREATED BY: SLYFOX1186
REM WEB: https://pastebin.com/u/slyfox1186

REM LOOP NSLOOKUP USING A LIST OF DOMAIN ADDRESSES STORED INSIDE A TEXT FILE.
REM A TEMP .PS1 SCRIPT WILL REMOVE USELESS STRINGS IN THE OUTPUT FILE.

:----------------------------------------------------------------------------------

REM CHANGE THE WORKING DIRECTORY TO THE SCRIPT'S DIRECTORY
PUSHD "%~dp0"
IF NOT "%1"=="MAX" START /MAX CMD /D /C %0 MAX & GOTO :EOF

:----------------------------------------------------------------------------------

REM SET THE WAN (EXTERNAL) AND LAN (INTERNAL) DNS SERVER ADDRESSES
REM THE WAN ADDRESS BELOW USES OPENDNS.. CHANGE AS NEEDED.
REM THE LAN ADDRESS IS USUALLY THE SAME AS YOUR ROUTER'S.. CHANGE AS NEEDED.
SET WAN=208.67.222.222
SET LAN=192.168.1.1

:-------------------------------------------------------------------

REM DELETE ANY FILES FROM PREVIOUS RUNS
IF EXIST "%TMP%\output.txt" DEL /Q "%TMP%\output.txt" >NUL

:----------------------------------------------------------------------------------

REM USE THE FOR COMMAND TO FIND A TXT FILE IN THE
REM CURRENT SCRIPT DIRECTORY (i.e list.txt) THAT CONTAINS THE LIST OF DOMAINS.
REM EACH DOMAIN MUST BE LISTED ONE PER LINE INSIDE THE TXT FILE.
FOR %%G IN (*.txt) DO FOR /F "USEBACKQ TOKENS=* DELIMS=" %%H IN ("%%G") DO NSLOOKUP %%H %WAN%>>"%TMP%\dnslookup.txt"

:----------------------------------------------------------------------------------

REM CREATES A TEMP PS1 FILE TO REMOVE USELESS STRINGS IN THE OUTPUT FILE.
REM IF YOU GET ERRORS RUNNING THE PS1 FILE UNCOMMENT THE LINE BELOW THAT STARTS
REM WITH powershell.exe. IT WILL ADD THE BYPASS PARAMETER WHEN EXECUTING POWERSHELL.
(
ECHO $OutFile = '%TMP%\output.txt'
ECHO ^(Get-Content '%TMP%\dnslookup.txt'^) ^| ForEach-Object {$_ -Replace "^Address:\s*(%WAN%|%LAN%)",""} ^| Out-File $OutFile
ECHO ^(Get-Content $OutFile^) ^| ForEach-Object {$_ -Replace "^Server:.*",""} ^| Out-File $OutFile
ECHO ^(Get-Content $OutFile^) ^| ForEach-Object {$_ -Replace "^\s","`t`t"} ^| Out-File $OutFile
ECHO ^(Get-Content $OutFile^) ^| ForEach-Object {$_ -Replace " +","`t"} ^| Out-File $OutFile
ECHO ^(^(Get-Content $OutFile -Raw^) -Replace "(?m)^\s*`r`n",""^).trim^(^) ^| Out-File $OutFile
ECHO ^(Get-Content $OutFile^) ^| ForEach-Object {$_ -Replace "^Name:\s*","======================================================`r`nName:`t`t"} ^| Out-File $OutFile
ECHO $RemoveEOFBlank = [System.IO.File]::ReadAllText^($OutFile^)
ECHO $RemoveEOFBlank = $RemoveEOFBlank.Trim^(^)
ECHO [System.IO.File]::WriteAllText^($OutFile, $RemoveEOFBlank^)
)>"%TMP%\trim.ps1"
powershell.exe -NoP -W Hidden -File "%TMP%\trim.ps1"
REM powershell.exe -NoP -W Hidden -Exe Bypass -File "%TMP%\trim.ps1"

:----------------------------------------------------------------------------------

REM CLEANUP TEMP FILES
DEL /Q "%TMP%\dnslookup.txt" "%TMP%\trim.ps1" >NUL

:----------------------------------------------------------------------------------

REM OPEN TEXT FILE WITH THE RESULTS
START "" /MAX NOTEPAD++ "%TMP%\output.txt"