bosses(Bs) :-
    length(Bs,5),
    Bs = [_,_,_,_,b(julian,_,_,_,_,_)],
    member(b(_,red,june,_,_,_),Bs),
    inbetween(b(_,_,_,_,3000,_),b(_,black,_,_,_,_),b(adam,_,_,_,_,_),Bs),
    member(b(_,_,_,51,2000,_),Bs),
    Bs = [b(michael,_,_,_,_,_),_,_,_,_],
    end(b(_,_,march,_,_,_),Bs),
    next(b(adam,_,_,_,_,_),b(_,_,_,_,4000,_),Bs),
    Bs = [_,_,_,b(_,_,august,_,_,_),_],
    member(b(_,black,_,_,4000,_),Bs),
    end(b(_,_,_,_,5000,_),Bs),
    left(b(_,_,_,46,_,_),b(_,_,_,_,_,hr),Bs),
    inbetween(b(_,_,_,40,_,_),b(_,_,_,_,_,hr),b(thomas,_,_,_,_,_),Bs),
    member(b(nathan,_,december,_,_,_),Bs),
    adjacentright(b(_,_,_,46,_,_),b(_,_,_,_,_,sales),Bs),
    left(b(_,red,_,_,_,_),b(_,yellow,_,_,_,_),Bs),
    Bs = [b(_,_,_,_,_,rd),_,_,_,_],
    member(b(_,blue,_,55,_,_),Bs),
    end(b(_,yellow,_,_,_,_),Bs),
    Bs = [_,_,_,_,b(_,_,_,34,_,_)],
    member(b(_,_,_,51,_,marketing),Bs),
    member(b(_,green,_,_,_,_),Bs),
    member(b(_,_,january,_,_,_),Bs),
    member(b(_,_,_,_,6000,_),Bs),
    member(b(_,_,_,_,_,it),Bs).


adjacentright(A, B, Bs) :- append(_, [A,B|_], Bs).
inbetween(A,B,C,Bs) :-
    append(_,[A|T1],Bs),
    append(_,[B|T2],T1),
    append(_,[C|_],T2).
left(A,B,Bs) :-
    append(_,[A|T], Bs),
    append(_,[B|_],T).
end(A,Bs) :- append(_,[A],Bs).
end(A,Bs) :- append([A],_,Bs).
next(A, B, Bs) :- append(_, [A,B|_],Bs).
next(A, B, Bs) :- append(_, [B,A|_], Bs).