[AHK Lib] ToolTip() ver.200221

/*
【タイトル】ToolTip
【  概要  】ツールチップ表示
【  Type  】Lib(関数)
【  返値  】なし
【  Site  】http://pastebin.com/uHuBttNb
【 更新日 】2020/02/21

ToolTip()
ToolTip_GUI()

マウスカーソル位置│ToolTip(Text)    │ToolTip(Text,,, "Wait")  │ToolTip(Text,,,, Sound)  │
    キャレット位置│ToolTip(Text,, 1)│ToolTip(Text,, 1, "Wait")│ToolTip(Text,, 1,, Sound)│

Θ関連
サウンド再生…SoundPlay
    画像表示…Image()
 ﾂｰﾙﾁｯﾌﾟ表示…ToolTip()/ToolTip_GUI()

┌----┐
│関数│
└----┘
ToolTip(Text[, ms, Pos, "mode", Sound])
ToolTip_GUI(Text[, ms, "FontName", "FontSize", "FontColor", "WindowColor", "Margin", Pos, "mode", Sound])

■引数(Parameters)                     　■引数(Parameters)
 Text│     : テキスト                 　       Text│      : テキスト
   ms│n    : ms                       　         ms│n     : ms
     │無   : 1000ms(1秒)              　           │無    : 1000ms(1秒)
  Pos│0    : マウスカーソル位置       　   FontName│      : フォント名
     │1    : キャレット位置 (e.g. IME)　   FontSize│n opt : n:サイズ opt:bold italic strike underline
 mode│Wait : 表示終了待ち             　  FontColor│      : 文字色
Sound│1    : 情報音                   　WindowColor│      : 背景色
     │-1   : エラー音                 　     Margin│X|Y   : X:ヨコ Y:タテ
                                       　        Pos│0     : マウスカーソル位置
                                       　           │1     : キャレット位置 (e.g. IME)
                                       　       mode│Wait  : 表示終了待ち
                                       　      Sound│1     : 情報音
                                       　           │-1    : エラー音
┌----------┐
│How to Use│
└----------┘
■使用例
ToolTip("真", 3000)    ToolTip("真", 3000,,, 1)
ToolTip("偽", 3000)    ToolTip("偽", 3000,,, -1)

ToolTip("文字列", ms)
ToolTip(変数, ms)

ToolTip("文字列", ms,, "Wait")
ToolTip(変数, ms,, "Wait")

1 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Black")    ;000000
2 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Red")      ;FF0000
3 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Lime")     ;00FF00
4 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Blue")     ;0000FF
5 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Aqua")     ;00FFFF Cyan
6 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Fuchsia")  ;FF00FF Magenta
7 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "Yellow")   ;FFFF00
8 Up::ToolTip_GUI("AutoHotkey",,, "9 bold italic", "White", "FF4F00")   ;FF4F00 インターナショナルオレンジ

FontName│メイリオ     ※Default
        │MS UI Gothic
FontSize│n opt
     opt│bold italic strike underline ※太字/斜体/取り消し線/下線
   Color│

;Suspend
^+S Up::
    Suspend, Toggle
    A_IsSuspended ? ToolTip_GUI("Suspend On" ,,, "9 bold italic", "White", "Red")
                  : ToolTip_GUI("Suspend Off",,, "9 bold italic", "White", "Lime")
return
*/
;【ToolTip()】

ToolTip(Text, ms:=1000, Pos:=0, mode:=0, Sound:=0) {
    IfEqual, ms,, SetEnv, ms, 1000
    IfEqual, Sound, 1, SoundPlay, *64   ;情報音
    IfEqual, Sound,-1, SoundPlay, *16   ;エラー音
    ;ツールチップ表示
    if (Pos = 1 && A_CaretX)
        ToolTip, %Text%, A_CaretX, A_CaretY
    else
        ToolTip, %Text%
    ;ツールチップ非表示
    Switch mode {
    Case "Wait", "W":
        Sleep, %ms%
        ToolTip
    Default:
        SetTimer, RemoveToolTip, -%ms%
    }
return
}

;ラベル
RemoveToolTip:
    ToolTip ;ツールチップ非表示
    return
;-
;【ToolTip_GUI()】

ToolTip_GUI(Text, ms:=1000, FN:="メイリオ", FS:=9, FC:="Default", BC:="Default", Margin:="7|3", Pos:=0, mode:=0, Sound:=0) {
    IfEqual, ms,, SetEnv, ms, 1000
    IfEqual, Sound, 1, SoundPlay, *64   ;情報音
    IfEqual, Sound,-1, SoundPlay, *16   ;エラー音
    CoordMode, Mouse, Screen                        ;絶対座標
    MouseGetPos, X, Y                               ;マウスカーソル下の座標取得
    Gui, +AlwaysOnTop -Border -Caption +ToolWindow  ;オプション
    Gui, Font, c%FC% s%FS%, %FN%                    ;フォント
    Gui, Color, %BC%                                ;背景色
    StringSplit, M, Margin, |                       ;hoge
    Gui, Margin, %M1%, %M2%                         ;余白 ※M1:ヨコ M2:タテ
    Gui, Add, Text,, %Text%                         ;テキストセット
    ;GUI表示
    if (Pos = 1 && A_CaretX)
        Gui, Show, X%A_CaretX% Y%A_CaretY%
    else
        Gui, Show, X%X% Y%Y%
    ;GUI非表示
    Switch mode {
    Case "Wait", "W":
        Sleep, %ms%
        Gui, Destroy
    Default:
        SetTimer, RemoveGUI, -%ms%
    }
return
}

;ラベル
RemoveGUI:
    Gui, Destroy    ;GUI非表示
    return