@echo off
echo Usage: unzip Masterwork zip to Masterwork folder, and Meph tileset zip to Meph Tileset folder, put this script next to them and run it!
pause

cd /D "%~dp0"
if NOT exist Masterwork (
    echo "Masterwork" directory not found!
    goto fail_exit
)
if NOT exist "Meph Tileset" (
    echo "Meph Tileset" directory not found!
    goto fail_exit
)

PUSHD "Masterwork"
echo Updating Dwarf Fortress version...
ren "Dwarf Fortress" "_Dwarf Fortress"
move /Y "..\Meph Tileset\Dwarf Fortress" "Dwarf Fortress"
PUSHD "Dwarf Fortress"

echo Updating \raws...
ren "raw" "_raw"
mkdir "raw"
xcopy /Y/R/E "..\_Dwarf Fortress\raw\*.*" "raw\"

echo Updating \data...
PUSHD "data"
ren "index" "_index"
ren "shader.fs" "_shader.fs"
ren "shader.vs" "_shader.vs"
PUSHD "init"
ren "interface.txt" "_interface.txt"
POPD
xcopy /Y/R/E "..\..\_Dwarf Fortress\data\*.*" "."
del /F/Q "index"
ren "_index" "index"
del /F/Q "shader.fs"
ren "_shader.fs" "shader.fs"
del /F/Q "shader.vs"
ren "_shader.vs" "shader.vs"
PUSHD "init"
del /F/Q "interface.txt"
ren "_interface.txt" "interface.txt"
POPD
POPD

echo Updating various settings files...
ren "dfhack.init" "_dfhack.init"
xcopy /Y/R "..\_Dwarf Fortress\dfhack.init" .
ren "Masterwork.settings" "_Masterwork.settings"
xcopy /Y/R "..\_Dwarf Fortress\Masterwork.settings" .
REM extra df hack init doesn't exist in meph tileset version?
REM ren "extra_dfhack_init.init" "_extra_dfhack_init.init"
xcopy /Y/R "..\_Dwarf Fortress\extra_dfhack_init.init" .
REM stocksettings doesn't exist in meph tileset version?
REM ren "stocksettings" "_stocksettings"
mkdir "stocksettings"
xcopy /Y/R/E "..\_Dwarf Fortress\stocksettings\*.*" "stocksettings\."
mkdir "hack\scripts\masterwork"
xcopy /Y/R/E "..\_Dwarf Fortress\hack\scripts\masterwork" "hack\scripts\masterwork"
PUSHD "hack\plugins"
mkdir "twbt"
mkdir "original"
xcopy /Y/R "automaterial.plug.dll" "twbt\."
xcopy /Y/R "mousequery.plug.dll" "twbt\."
xcopy /Y/R "resume.plug.dll" "twbt\."
xcopy /Y/R "twbt.plug.dll" "twbt\."
POPD
POPD

echo Updating Utilities...
ren "MasterworkDwarfFortress" "_MasterworkDwarfFortress"
mkdir "MasterworkDwarfFortress"
xcopy /Y/R/E "_MasterworkDwarfFortress\*.*" "MasterworkDwarfFortress\*.*"
xcopy /Y/R/E "..\Meph Tileset\TilesetExtras\*.*" "MasterworkDwarfFortress\*.*"

exit /b 0
:fail_exit
echo Merge failed!
exit /b 1