updated qt4-fsarchiver PKGBUILD

# qt4-fsarchiver by Francois Dupoux, Hihin Ruslan and Dieter Baum
# PKGBUILD by hasufell, updated by DaarkWel

pkgname=qt4-fsarchiver
pkgver=0.6.17_3
pkgrel=1
pkgdesc='GUI for fsarchiver'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/qt4-fsarchiver/'
license=('GPL')
depends=('fsarchiver' 'gksu')
makedepends=('qt4')
source=("http://sourceforge.net/projects/${pkgname}/files/source/${pkgname}-${pkgver//_/-}.tar.gz")

sha1sums=('8b474af6fd81d604f357348567608f450dbe83e7')

prepare() {
	# patch installer to use 'usr/bin'
	cd "${srcdir}/${pkgname}"
	sed -i -e "s|target.path = /usr/sbin|target.path = /usr/bin|" \
	$(find . -name 'qt4-fsarchiver.pro')
}

build() {
	cd "${srcdir}/${pkgname}"
	qmake-qt4
	make
}

package() {
	cd "${srcdir}/${pkgname}"
	make INSTALL_ROOT="${pkgdir}" install
	mkdir -p ${pkgdir}/usr/share/qt/translations
	rm -R ${pkgdir}/usr/share/qt4
	install -D -m644 ${srcdir}/${pkgname}/translations/*.qm ${pkgdir}/usr/share/qt/translations
	sed s/Terminal=true/Terminal=false/ -i ${pkgdir}/usr/share/applications/qt4-fsarchiver.desktop
	sed s/sudo/gksu/ -i ${pkgdir}/usr/share/applications/qt4-fsarchiver.desktop
}