//////////////////////////////////////////////////////////////////
// Pin SHT21 SDA = D1                                          //
// Pin SHT21 SCL = D2                                         //
// Pin relay = D6                                            //
// Température = V6                                         //
// Humidité = V5                                           //
// LED d'indication d'état du relay = V7                  //
// Slider pour choisir la température de consigne = V15  //
// Bouton de chauffage = V12                            //
// Bouton de régulation = V17                          //
////////////////////////////////////////////////////////

//On défini les librairies utilisées
#define BLYNK_PRINT Serial
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <Wire.h>  // ajout de librairie de gestion I2C
#include <sht21.h>  // ajout de la librairie de gestion du capteur SHT21

// on récupére le "Auth Token" à partir de l'application BLYNK
char auth[] = "";

// On saisit les informations de connexion pour se connecter en WIFI
char ssid[] = "";
char pass[] = "";

//On initialise la valeur de consigne
float x ;
//On initialise
int y;
//On initialise la fonction d'état du bouton "ON / OFF"
int v12;
//On initialise la fonction d'état du bouton "REGULATION / NON REGULE"
int v17;

sht21 SHT21;  // création d'une instance

// déclaration des broches utilisées sur NodeMCU Lolin
int sda = D1;  // GPIO5
int scl = D2;  // GPIO4

//on initialise le timer BLYNK
BlynkTimer timer;

//On initialise la LED d'indicateur d'état du thermostat
WidgetLED led1(V7);

//On créer la boucle qui permet de lire la température et l'humidité du SHT21
void sendSensor()
{
  //On définit les variable qui contiendront les données du SHT21 (t pour la température et h pour l'humidité)
  float t = SHT21.lecture_temperature();  // récupère la température
  float h = SHT21.lecture_humidite();  // récupère l'humidité relative

  //On envoie les donnés des variables à des boutons virtuels
  Blynk.virtualWrite(V5, h);
  Blynk.virtualWrite(V6, t);
}

//On créer la boucle qui permet de thermostater
void thermostat()
{
  //On récupère à nouveau la valeur de la température que l'on transmet à la nouvelle variable t
  float t = SHT21.lecture_temperature();

//Si les boutons sont "ON" et "REGULATION"
  if (v12 ==1 && v17 == 1) {
    //Si la température est inférieur à la valeur de consigne
    if ( t < x) {
      //On allume la LED qui donne l'info sur l'état du chauffage
      led1.on();
      //On allume le relay
      digitalWrite(12,LOW);
    }
    else{
      //On éteind la LED qui donne l'info sur l'état du chauffage
      led1.off();
      //On éteind le relay
      digitalWrite(12,HIGH);
    }
  }
//Si les boutons sont "ON" et "NON REGULE"
    else if (v12 == 1 && v17 ==0){
      //On allume la LED qui donne l'info sur l'état du chauffage
      led1.on();
      //On allume le relay
      digitalWrite(12,LOW);
    }
//Si le bouton est OFF
    else {
      //On éteind la LED qui donne l'info sur l'état du chauffage
      led1.off();
    //On éteind le relay
      digitalWrite(12,HIGH);
    }
}

//On définit la valeur de consigne
BLYNK_WRITE(V15)
{
  //On stock la valeur de consigne dans une variable après le calcul de conversion de l'échelle du slider
  float valeurconsigne = (param.asInt() * 0.0097751710654 + 15.0 );
  //On stock la valeur de consigne dans une variable utilisable partout
  x = valeurconsigne;
}

//On définit l'état du bouton "ON / OFF"
BLYNK_WRITE(V12)//chauffage
{
  //Si le bouton est sur "ON"
  if (param.asInt() == 1) {
    v12=1;
  }
  //Si le bouton est sur "OFF"
  else {
    v12=0;
  }
}

//On définit l'état du bouton "REGULATION / NON REGULE"
BLYNK_WRITE(V17)
{
  //Si le bouton de régulation est sur "REGULATION"
  if (param.asInt() == 1) {
    v17=1;
  }
  //Si le bouton de régulation est sur "NON REGULE"
  else {
    v17=0;
  }
}

//On initialise le NodeMCU
void setup()
{
  //On définit la commande du relay en sortie
  pinMode(12, OUTPUT);
  //On définit le premier état du relay
  digitalWrite(12, HIGH);
  //On patiente 1 seconde
  delay(1000);
  // On allume le moniteur série
  Serial.begin(9600);
  //On se connect à BLYNK à travers notre WIFI
  Blynk.begin(auth, ssid, pass);
  // initialise la librairie SHT21 pour une utilisation NodeMCU Lolin
  SHT21.begin(sda, scl);

  //On définit le temps de répétition de la boucle de récupération de données du SHT21 à 1 seconde
  timer.setInterval(1000L, sendSensor);
  //On définit le temps de répétition de la boucle thermostat
  timer.setInterval(500L, thermostat);
}

//La boucle se répète indéfiniment
void loop()
{
  //On démarre BLYNK
  Blynk.run();
  //On démarre le timer
  timer.run();
}