Minecraft client launcher for Windows

@ECHO OFF
REM ***
REM *** Minecraft launcher by Tero
REM ***

SET PLAYER=ThePlayerName
SET COMPUTER_CPUS=2
SET MEMORY_ALLOCATION=1024M
SET PROCESS_PRIORITY=high
SET JAVA_EXE=java.exe
REM          ^ Put full path here if needed (e.g. SET JAVA_EXE=C:\Program Files\Java\jre7\bin\java.exe)

REM Updating has to be done manually. Download links for the relevant files are:
REM
REM .minecraft/bin/minecraft.jar
REM         http://assets.minecraft.net/1_4_6/minecraft.jar (<= replace version number)
REM
REM .minecraft/bin/jinput.jar
REM .minecraft/bin/lwjgl.jar
REM .minecraft/bin/lwjgl_util.jar
REM .minecraft/bin/natives/*
REM         http://sourceforge.net/projects/java-game-lib/files/Official%20Releases/
REM
REM After updating, add the OptiFine Light Mod to the .minecraft/bin/minecraft.jar:
REM
REM 1. Download "OptiFine Light" from:
REM     http://optifine.net/downloads.php
REM 2. Backup minecraft.jar by copying it to minecraft_unpatched.jar
REM 3. Open minecraft.jar in an archive editor (WinRar/7-Zip/etc)
REM 4. Inside minecraft.jar, delete the META-INF folder.
REM 5. Copy (drag and drop) the .class files from the OptiFine_1.4.6_L_A3.zip file
REM    into the root of the minecraft.jar file, possibly replacing previous files.
REM 6. Run Minecraft and test!

REM *** Done testing, launch Minecraft
IF "%LAUNCH_MINECRAFT%"=="true" GOTO :LAUNCH_MINECRAFT

REM *** Test if java.exe is available
"%JAVA_EXE%" -version > NUL 2>&1
IF NOT ERRORLEVEL 0 ECHO %JAVA_EXE% not found & PAUSE & GOTO :EOF

REM *** Test if .minecraft dir is found
IF NOT EXIST "%~dp0\.minecraft" ECHO No ".minecraft" directory found at "%~dp0" & PAUSE & GOTO :EOF

REM *** Open this same bat file as minimized window
ECHO Launching Minecraft for %PLAYER%...
SET LAUNCH_MINECRAFT=true
START /min CMD /C "%~f0"
SET LAUNCH_MINECRAFT=
GOTO :EOF

REM ***************************************************************************
:LAUNCH_MINECRAFT

REM *** Totally unnecessary decoration
TITLE Minecraft Info
COLOR 87
MODE CON COLS=132 LINES=500
CLS
ECHO Ü   Ü Ü Ü   Ü ÜÜÜ ÜÜÜ ÜÜÜ ÜÜÜ ÜÜÜ ÜÜÜ
ECHO ÛßÜßÛ Û ÛßÜ Û ÛÜ  Û   ÛÜß ÛÜÛ ÛÜ   Û
ECHO Û   Û Û Û  ßÛ ÛÜÜ ÛÜÜ Û Û Û Û Û    Û  for %PLAYER%
ECHO.

REM *** Set paths and launch Java
CD "%~dp0"
SET APPDATA=%CD%
START /b /%PROCESS_PRIORITY% "Launching Minecraft..." "%JAVA_EXE%" ^
    -Xmx%MEMORY_ALLOCATION% ^
    -Xms%MEMORY_ALLOCATION% ^
    -XX:+UseFastAccessorMethods ^
    -XX:+AggressiveOpts ^
    -XX:+DisableExplicitGC ^
    -XX:+UseAdaptiveGCBoundary ^
    -XX:MaxGCPauseMillis=500 ^
    -XX:SurvivorRatio=16 ^
    -XX:+UseParallelGC ^
    -XX:UseSSE=4 ^
    -XX:ParallelGCThreads=%COMPUTER_CPUS% ^
    -cp .minecraft\bin\minecraft.jar;.minecraft\bin\lwjgl.jar;.minecraft\bin\lwjgl_util.jar;.minecraft\bin\jinput.jar ^
    -Djava.library.path=.minecraft\bin\natives ^
    net.minecraft.client.Minecraft "%PLAYER%"
EXIT
REM ***************************************************************************