RegCheck (Updated)

//Вставь эти проверки выше, чем энуменатор для массива игрока
#if !defined MAX_PLAYER_PASSWORD
    const MAX_PLAYER_PASSWORD = 31; // заменм на свое значение и в энуменаторе замени значение на эту константу.
#endif
#if !defined MAX_PLAYER_EMAIL
    const MAX_PLAYER_EMAIL = 50; //Проделай тоже самое, что делал выше
#endif
#if !defined MAX_REFER_NAME
    const MAX_REFER_NAME = 24; //Проделай тоже самое, что делал выше
#endif


stock CheckRegistration(playerid)
{
    #if !defined COLOR_WHITE
        #define _C_WHITE_DEFINED
        #define COLOR_WHITE "{FFFFFF}"
    #endif
    #if !defined COLOR_BLUE
        #define _C_BLUE_DEFINED
        #define COLOR_BLUE "{4582A1}"
    #endif
    #if !defined COLOR_RED
        #define _C_RED_DEFINED
        #define COLOR_RED "{AA3333}"
    #endif

    new
        password[MAX_PLAYER_PASSWORD],
        email[MAX_PLAYER_EMAIL],
        refer[MAX_REFER_NAME];

    strcat(password, PlayerRegInfo[playerid][Password], MAX_PLAYER_PASSWORD);
    strcat(email, PlayerRegInfo[playerid][Email], MAX_PLAYER_PASSWORD);
    strcat(refer, PlayerRegInfo[playerid][Ref], MAX_PLAYER_PASSWORD);

    new
        race            = PlayerRegInfo[playerid][Rassa],
        skin            = PlayerRegInfo[playerid][Skin],
        gender          = PlayerRegInfo[playerid][Gender],
        password_length = strlen(PlayerRegInfo[playerid][Password]),
        email_length    = strlen(PlayerRegInfo[playerid][Email]),
        refer_length    = strlen(PlayerRegInfo[playerid][Ref]);

    static const gender_info[][] =
    {
        COLOR_RED   "Не выбран",
        COLOR_BLUE  "Мужской",
        COLOR_BLUE  "Женский"
    };

    static const race_info[][] =
    {
        COLOR_RED   "Не выбрана",
        COLOR_BLUE  "Афроамереканец",
        COLOR_BLUE  "Европеец",
        COLOR_BLUE  "Азиат"
    };

    static const string_content[] =
        COLOR_WHITE     "Пароль: %s%s\n\
        "COLOR_WHITE    "Почта: %s%s\n\
        "COLOR_WHITE    "Реферал: %s%s\n\
        "COLOR_WHITE    "Пол: %s\n\
        "COLOR_WHITE    "Национальность: %s\n\
                        %sПродолжить регистрацию\n";

    new string[sizeof(string_content)
        - 4 + MAX_PLAYER_PASSWORD + 8
        - 4 + MAX_PLAYER_EMAIL + 8
        - 4 + MAX_REFER_NAME + 8
        - 2 + 10 + 8
        - 2 + 16 + 8
        - 2 + 8];

    if(!(0 < gender < sizeof(gender_info)))
    {
        gender = 0;
    }

    if(!(0 < race < sizeof(race_info)))
    {
        race = 0;
    }

    new isok = (password_length && email_length && gender && race && skin);

    format(string, sizeof(string), string_content,
        ((password_length) ? (COLOR_BLUE) : (COLOR_RED)),
        ((password_length) ? (password) : ("Не задан")),
        ((email_length) ? (COLOR_BLUE) : (COLOR_RED)),
        ((email_length) ? (email) : ("Не задан")),
        ((refer_length) ? (COLOR_BLUE) : (COLOR_RED)),
        ((refer_length) ? (refer) : ("Не задан")),
        gender_info[gender],
        race_info[race],
        ((isok) ? (COLOR_BLUE) : (COLOR_RED)));

    ShowPlayerDialog(playerid, DIALOG_REGISTER, DIALOG_STYLE_LIST,
        "{FFFFFF}Регистрация на {AA3333}"NAME_SERVER,
        string,
        "Далее", "Отмена");

    print(string);

    #if defined _C_WHITE_DEFINED
        #undef _C_WHITE_DEFINED
        #undef COLOR_WHITE
    #endif
    #if defined _C_BLUE_DEFINED
        #undef _C_BLUE_DEFINED
        #undef COLOR_BLUE
    #endif
    #if defined _C_RED_DEFINED
        #undef _C_RED_DEFINED
        #undef COLOR_RED
    #endif

    return 1;
}