Advertisement
Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- #define FILTERSCRIPT
- #include <a_samp>
- #include <streamer>
- #include <izcmd>
- // VIP Settings
- #define VIP_REQUIRED (1000000) // money required for becoming VIP (default: 1000000)
- #define VIP_RANGE (10.0) // range of VIP area (default: 10.0)
- #define BODYGUARD_LIMIT (5) // a VIP can hire up to x bodyguards (default: 5)
- // Bodyguard Settings
- #define STARTING_SALARY (5000) // how much money a bodyguard gets paid for being near their VIP for a certain amount of time (default: 5000)
- #define MIN_SALARY (500) // min. amount of bodyguard salary (default: 500)
- #define SALARY_PENALTY (250) // how much money will be taken from the salary if the VIP dies (default: 250)
- #define SALARY_TIME (300) // a bodyguard must be near their VIP for x seconds to get his payment (default: 300)
- // Dialog IDs
- enum
- {
- DIALOG_HIRE_BODYGUARD = 16200,
- DIALOG_FIRE_BODYGUARD,
- DIALOG_LABEL_COLOR
- }
- // Variables for the VIP
- new
- bool: IsVIP[MAX_PLAYERS],
- VIPArea[MAX_PLAYERS] = {-1, ...},
- VIPVicinityTimer[MAX_PLAYERS] = {-1, ...},
- VIPColor[MAX_PLAYERS] = {0xD78E10FF, ...},
- Text3D: VIPLabel[MAX_PLAYERS] = {Text3D: INVALID_3DTEXT_ID, ...};
- // Variables for the bodyguard
- new
- bool: LookingForJob[MAX_PLAYERS],
- ProtectingID[MAX_PLAYERS] = {INVALID_PLAYER_ID, ...},
- Salary[MAX_PLAYERS] = {STARTING_SALARY, ...},
- SecondsNearVIP[MAX_PLAYERS];
- new
- LabelColors[256] = {
- 0x000000FF, 0xF5F5F5FF, 0x2A77A1FF, 0x840410FF, 0x263739FF, 0x86446EFF, 0xD78E10FF, 0x4C75B7FF, 0xBDBEC6FF, 0x5E7072FF,
- 0x46597AFF, 0x656A79FF, 0x5D7E8DFF, 0x58595AFF, 0xD6DAD6FF, 0x9CA1A3FF, 0x335F3FFF, 0x730E1AFF, 0x7B0A2AFF, 0x9F9D94FF,
- 0x3B4E78FF, 0x732E3EFF, 0x691E3BFF, 0x96918CFF, 0x515459FF, 0x3F3E45FF, 0xA5A9A7FF, 0x635C5AFF, 0x3D4A68FF, 0x979592FF,
- 0x421F21FF, 0x5F272BFF, 0x8494ABFF, 0x767B7CFF, 0x646464FF, 0x5A5752FF, 0x252527FF, 0x2D3A35FF, 0x93A396FF, 0x6D7A88FF,
- 0x221918FF, 0x6F675FFF, 0x7C1C2AFF, 0x5F0A15FF, 0x193826FF, 0x5D1B20FF, 0x9D9872FF, 0x7A7560FF, 0x989586FF, 0xADB0B0FF,
- 0x848988FF, 0x304F45FF, 0x4D6268FF, 0x162248FF, 0x272F4BFF, 0x7D6256FF, 0x9EA4ABFF, 0x9C8D71FF, 0x6D1822FF, 0x4E6881FF,
- 0x9C9C98FF, 0x917347FF, 0x661C26FF, 0x949D9FFF, 0xA4A7A5FF, 0x8E8C46FF, 0x341A1EFF, 0x6A7A8CFF, 0xAAAD8EFF, 0xAB988FFF,
- 0x851F2EFF, 0x6F8297FF, 0x585853FF, 0x9AA790FF, 0x601A23FF, 0x20202CFF, 0xA4A096FF, 0xAA9D84FF, 0x78222BFF, 0x0E316DFF,
- 0x722A3FFF, 0x7B715EFF, 0x741D28FF, 0x1E2E32FF, 0x4D322FFF, 0x7C1B44FF, 0x2E5B20FF, 0x395A83FF, 0x6D2837FF, 0xA7A28FFF,
- 0xAFB1B1FF, 0x364155FF, 0x6D6C6EFF, 0x0F6A89FF, 0x204B6BFF, 0x2B3E57FF, 0x9B9F9DFF, 0x6C8495FF, 0x4D8495FF, 0xAE9B7FFF,
- 0x406C8FFF, 0x1F253BFF, 0xAB9276FF, 0x134573FF, 0x96816CFF, 0x64686AFF, 0x105082FF, 0xA19983FF, 0x385694FF, 0x525661FF,
- 0x7F6956FF, 0x8C929AFF, 0x596E87FF, 0x473532FF, 0x44624FFF, 0x730A27FF, 0x223457FF, 0x640D1BFF, 0xA3ADC6FF, 0x695853FF,
- 0x9B8B80FF, 0x620B1CFF, 0x5B5D5EFF, 0x624428FF, 0x731827FF, 0x1B376DFF, 0xEC6AAEFF, 0x000000FF, 0x177517FF, 0x210606FF,
- 0x125478FF, 0x452A0DFF, 0x571E1EFF, 0x010701FF, 0x25225AFF, 0x2C89AAFF, 0x8A4DBDFF, 0x35963AFF, 0xB7B7B7FF, 0x464C8DFF,
- 0x84888CFF, 0x817867FF, 0x817A26FF, 0x6A506FFF, 0x583E6FFF, 0x8CB972FF, 0x824F78FF, 0x6D276AFF, 0x1E1D13FF, 0x1E1306FF,
- 0x1F2518FF, 0x2C4531FF, 0x1E4C99FF, 0x2E5F43FF, 0x1E9948FF, 0x1E9999FF, 0x999976FF, 0x7C8499FF, 0x992E1EFF, 0x2C1E08FF,
- 0x142407FF, 0x993E4DFF, 0x1E4C99FF, 0x198181FF, 0x1A292AFF, 0x16616FFF, 0x1B6687FF, 0x6C3F99FF, 0x481A0EFF, 0x7A7399FF,
- 0x746D99FF, 0x53387EFF, 0x222407FF, 0x3E190CFF, 0x46210EFF, 0x991E1EFF, 0x8D4C8DFF, 0x805B80FF, 0x7B3E7EFF, 0x3C1737FF,
- 0x733517FF, 0x781818FF, 0x83341AFF, 0x8E2F1CFF, 0x7E3E53FF, 0x7C6D7CFF, 0x020C02FF, 0x072407FF, 0x163012FF, 0x16301BFF,
- 0x642B4FFF, 0x368452FF, 0x999590FF, 0x818D96FF, 0x99991EFF, 0x7F994CFF, 0x839292FF, 0x788222FF, 0x2B3C99FF, 0x3A3A0BFF,
- 0x8A794EFF, 0x0E1F49FF, 0x15371CFF, 0x15273AFF, 0x375775FF, 0x060820FF, 0x071326FF, 0x20394BFF, 0x2C5089FF, 0x15426CFF,
- 0x103250FF, 0x241663FF, 0x692015FF, 0x8C8D94FF, 0x516013FF, 0x090F02FF, 0x8C573AFF, 0x52888EFF, 0x995C52FF, 0x99581EFF,
- 0x993A63FF, 0x998F4EFF, 0x99311EFF, 0x0D1842FF, 0x521E1EFF, 0x42420DFF, 0x4C991EFF, 0x082A1DFF, 0x96821DFF, 0x197F19FF,
- 0x3B141FFF, 0x745217FF, 0x893F8DFF, 0x7E1A6CFF, 0x0B370BFF, 0x27450DFF, 0x071F24FF, 0x784573FF, 0x8A653AFF, 0x732617FF,
- 0x319490FF, 0x56941DFF, 0x59163DFF, 0x1B8A2FFF, 0x38160BFF, 0x041804FF, 0x355D8EFF, 0x2E3F5BFF, 0x561A28FF, 0x4E0E27FF,
- 0x706C67FF, 0x3B3E42FF, 0x2E2D33FF, 0x7B7E7DFF, 0x4A4442FF, 0x28344EFF
- };
- // Functions
- VIP_Activate(playerid)
- {
- IsVIP[playerid] = true;
- VIPArea[playerid] = CreateDynamicSphere(0.0, 0.0, 0.0, VIP_RANGE);
- AttachDynamicAreaToPlayer(VIPArea[playerid], playerid);
- VIPVicinityTimer[playerid] = SetTimerEx("BodyguardSecondUpdate", 1000, true, "i", playerid);
- VIPLabel[playerid] = CreateDynamic3DTextLabel("VIP", VIPColor[playerid], 0.0, 0.0, 0.0, VIP_RANGE, playerid, _, 1);
- return 1;
- }
- VIP_SendMessage(playerid, msg[])
- {
- SendClientMessage(playerid, 0x3498DBFF, msg);
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] == playerid) SendClientMessage(i, 0x3498DBFF, msg);
- }
- return 1;
- }
- VIP_BodyguardCount(playerid)
- {
- new count = 0;
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] == playerid) count++;
- }
- return count;
- }
- VIP_CleanUp(playerid, resignguards = 0)
- {
- if(IsValidDynamicArea(VIPArea[playerid])) DestroyDynamicArea(VIPArea[playerid]);
- if(IsValidDynamic3DTextLabel(VIPLabel[playerid])) DestroyDynamic3DTextLabel(VIPLabel[playerid]);
- if(VIPVicinityTimer[playerid] != -1) VIPVicinityTimer[playerid] = -1;
- IsVIP[playerid] = false;
- VIPArea[playerid] = -1;
- VIPVicinityTimer[playerid] = -1;
- VIPColor[playerid] = 0xD78E10FF;
- VIPLabel[playerid] = Text3D: INVALID_3DTEXT_ID;
- if(resignguards)
- {
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] == playerid)
- {
- SendClientMessage(i, 0x3498DBFF, "BODYGUARD: {FFFFFF}The VIP you were assigned to left the game.");
- SendClientMessage(i, 0x3498DBFF, "BODYGUARD: {FFFFFF}You can look for an another job if you want to.");
- Bodyguard_CleanUp(i);
- }
- }
- }
- return 1;
- }
- Bodyguard_CleanUp(playerid)
- {
- if(IsValidDynamic3DTextLabel(VIPLabel[playerid])) DestroyDynamic3DTextLabel(VIPLabel[playerid]);
- LookingForJob[playerid] = false;
- ProtectingID[playerid] = INVALID_PLAYER_ID;
- Salary[playerid] = STARTING_SALARY;
- SecondsNearVIP[playerid] = 0;
- VIPLabel[playerid] = Text3D: INVALID_3DTEXT_ID;
- return 1;
- }
- GetIDFromName(name[])
- {
- new p_name[MAX_PLAYER_NAME];
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- GetPlayerName(i, p_name, MAX_PLAYER_NAME);
- if(!strcmp(p_name, name)) return i;
- }
- return INVALID_PLAYER_ID;
- }
- // Callbacks
- public OnFilterScriptInit()
- {
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- Bodyguard_CleanUp(i);
- VIP_CleanUp(i);
- }
- return 1;
- }
- public OnPlayerConnect(playerid)
- {
- Bodyguard_CleanUp(playerid);
- VIP_CleanUp(playerid);
- return 1;
- }
- public OnPlayerDisconnect(playerid, reason)
- {
- Bodyguard_CleanUp(playerid);
- VIP_CleanUp(playerid, 1);
- return 1;
- }
- public OnPlayerDeath(playerid, killerid, reason)
- {
- if(IsPlayerConnected(killerid) && IsVIP[playerid])
- {
- new string[96];
- format(string, sizeof(string), "BODYGUARD: {FFFFFF}Your VIP died. {2ECC71}$%d {FFFFFF}has been cut from your salary.", SALARY_PENALTY);
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] != playerid) continue;
- SendClientMessage(i, 0x3498DBFF, string);
- Salary[i] -= SALARY_PENALTY;
- if(Salary[i] < MIN_SALARY) Salary[i] = MIN_SALARY;
- format(string, sizeof(string), "BODYGUARD: {FFFFFF}New salary: {2ECC71}$%d.", Salary[i]);
- SendClientMessage(i, 0x3498DBFF, string);
- }
- }
- return 1;
- }
- public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
- {
- switch(dialogid)
- {
- case DIALOG_HIRE_BODYGUARD:
- {
- if(response)
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- new id = GetIDFromName(inputtext);
- if(!IsPlayerConnected(id)) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Player is offline.");
- if(!LookingForJob[id]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Player isn't looking for a job.");
- if(IsVIP[id] || IsPlayerConnected(ProtectingID[id])) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Player isn't available.");
- Bodyguard_CleanUp(id);
- ProtectingID[id] = playerid;
- new string[128], name[MAX_PLAYER_NAME];
- GetPlayerName(playerid, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "BODYGUARD: {FFFFFF}You got hired by %s(%d).", name, playerid);
- SendClientMessage(id, 0x3498DBFF, string);
- SendClientMessage(id, 0x3498DBFF, "BODYGUARD: {FFFFFF}You can use /resign to resign.");
- format(string, sizeof(string), "%s's Bodyguard", name);
- VIPLabel[id] = CreateDynamic3DTextLabel(string, VIPColor[playerid], 0.0, 0.0, 0.0, VIP_RANGE, id, _, 1);
- GetPlayerName(id, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "VIP: {FFFFFF}You hired %s(%d).", name, id);
- SendClientMessage(playerid, 0x3498DBFF, string);
- }
- return 1;
- }
- case DIALOG_FIRE_BODYGUARD:
- {
- if(response)
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- new id = GetIDFromName(inputtext);
- if(!IsPlayerConnected(id)) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Player is offline.");
- if(ProtectingID[id] != playerid) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Player isn't your bodyguard.");
- Bodyguard_CleanUp(id);
- new string[128], name[MAX_PLAYER_NAME];
- GetPlayerName(playerid, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "BODYGUARD: {FFFFFF}You got fired by %s(%d).", name, playerid);
- SendClientMessage(id, 0x3498DBFF, string);
- SendClientMessage(id, 0x3498DBFF, "BODYGUARD: {FFFFFF}You can use /lookforjob to become available again.");
- GetPlayerName(id, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "VIP: {FFFFFF}You fired %s(%d).", name, id);
- SendClientMessage(playerid, 0x3498DBFF, string);
- }
- return 1;
- }
- case DIALOG_LABEL_COLOR:
- {
- if(response)
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- if(!strlen(inputtext)) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Choose a color ID.");
- new color = strval(inputtext);
- if(!(0 <= color <= sizeof(LabelColors)-1)) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}Invalid color ID.");
- VIPColor[playerid] = LabelColors[color];
- Streamer_SetIntData(STREAMER_TYPE_3D_TEXT_LABEL, VIPLabel[playerid], E_STREAMER_COLOR, VIPColor[playerid]);
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] != playerid) continue;
- Streamer_SetIntData(STREAMER_TYPE_3D_TEXT_LABEL, VIPLabel[i], E_STREAMER_COLOR, VIPColor[playerid]);
- }
- }
- return 1;
- }
- }
- return 0;
- }
- public OnPlayerWeaponShot(playerid, weaponid, hittype, hitid, Float:fX, Float:fY, Float:fZ)
- {
- if(hittype == BULLET_HIT_TYPE_PLAYER && IsPlayerConnected(hitid))
- {
- // a VIP can't shoot their bodyguard
- if(IsVIP[playerid] && ProtectingID[hitid] == playerid) return 0;
- // a bodyguard can't shoot their VIP
- if(IsVIP[hitid] && ProtectingID[playerid] == hitid) return 0;
- }
- return 1;
- }
- forward BodyguardSecondUpdate(playerid);
- public BodyguardSecondUpdate(playerid)
- {
- new string[64];
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] != playerid) continue;
- if(!IsPlayerInDynamicArea(i, VIPArea[playerid])) continue;
- SecondsNearVIP[i]++;
- if(SecondsNearVIP[i] >= SALARY_TIME)
- {
- format(string, sizeof(string), "BODYGUARD: {FFFFFF}VIP protection payment: {2ECC71}$%d.", Salary[i]);
- SendClientMessage(i, 0x3498DBFF, string);
- GivePlayerMoney(i, Salary[i]);
- SecondsNearVIP[i] = 0;
- }
- }
- return 1;
- }
- // VIP Commands
- CMD:becomevip(playerid, params[])
- {
- if(IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're already a VIP.");
- if(LookingForJob[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You can't be a VIP while looking for a job.");
- if(IsPlayerConnected(ProtectingID[playerid])) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You can't become a VIP while protecting someone.");
- if(VIP_REQUIRED > GetPlayerMoney(playerid)) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You don't have enough money to be a VIP.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You're a VIP now.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You can hire bodyguards using /hire.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You can fire your bodyguards using /bodyguards.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You can use /vmsg to send a message to your bodyguards.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You can use /vcol to change the label color of your bodyguards and yourself.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You can cancel your VIP by using /cancelvip.");
- VIP_Activate(playerid);
- return 1;
- }
- CMD:hire(playerid, params[])
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- if(VIP_BodyguardCount(playerid) >= BODYGUARD_LIMIT) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You can't hire any more bodyguards.");
- new string[1024], name[MAX_PLAYER_NAME], count;
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(!LookingForJob[i]) continue;
- count++;
- GetPlayerName(i, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "%s%s\n", string, name);
- }
- if(count > 0) {
- ShowPlayerDialog(playerid, DIALOG_HIRE_BODYGUARD, DIALOG_STYLE_LIST, "Available Bodyguards", string, "Hire", "Cancel");
- }else{
- SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}No bodyguards available.");
- }
- return 1;
- }
- CMD:bodyguards(playerid, params[])
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- new string[256], name[MAX_PLAYER_NAME], count;
- for(new i, p = GetPlayerPoolSize(); i <= p; i++)
- {
- if(!IsPlayerConnected(i)) continue;
- if(ProtectingID[i] != playerid) continue;
- count++;
- GetPlayerName(i, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "%s%s\n", string, name);
- }
- if(count > 0) {
- ShowPlayerDialog(playerid, DIALOG_FIRE_BODYGUARD, DIALOG_STYLE_LIST, "My Bodyguards", string, "Fire", "Cancel");
- }else{
- SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You haven't hired any bodyguards.");
- }
- return 1;
- }
- CMD:vmsg(playerid, params[])
- {
- if(!IsVIP[playerid] && !IsPlayerConnected(ProtectingID[playerid])) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You can't use this command.");
- new string[144], name[MAX_PLAYER_NAME];
- GetPlayerName(playerid, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "[VIP MESSAGE] %s(%d): {FFFFFF}%s", name, playerid, params[0]);
- VIP_SendMessage((IsVIP[playerid]) ? playerid : ProtectingID[playerid], string);
- return 1;
- }
- CMD:vcol(playerid, params[])
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- new color_string[3128];
- for(new i; i < sizeof(LabelColors); i++) format(color_string, sizeof(color_string), "%s{%06x}%03d %s", color_string, LabelColors[i] >>> 8, i, ((i+1) % 10 == 0) ? ("\n") : (""));
- ShowPlayerDialog(playerid, DIALOG_LABEL_COLOR, DIALOG_STYLE_INPUT, "Label Color", color_string, "Set", "Cancel");
- return 1;
- }
- CMD:cancelvip(playerid, params[])
- {
- if(!IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not a VIP.");
- SendClientMessage(playerid, 0x3498DBFF, "VIP: {FFFFFF}You're no longer VIP.");
- VIP_CleanUp(playerid, 1);
- return 1;
- }
- // Bodyguard Commands
- CMD:lookforjob(playerid, params[])
- {
- if(IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}VIP players can't look for a job.");
- if(IsPlayerConnected(ProtectingID[playerid])) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're already hired.");
- LookingForJob[playerid] = !LookingForJob[playerid];
- if(LookingForJob[playerid]) {
- SendClientMessage(playerid, 0x3498DBFF, "BODYGUARD: {FFFFFF}You're looking for a job now, wait until a VIP hires you.");
- }else{
- SendClientMessage(playerid, 0x3498DBFF, "BODYGUARD: {FFFFFF}You're no longer looking for a job.");
- }
- return 1;
- }
- CMD:resign(playerid, params[])
- {
- if(IsVIP[playerid]) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}VIP players can't resign from being a bodyguard.");
- if(!IsPlayerConnected(ProtectingID[playerid])) return SendClientMessage(playerid, 0xE74C3CFF, "ERROR: {FFFFFF}You're not protecting any VIP.");
- new string[64], name[MAX_PLAYER_NAME];
- GetPlayerName(playerid, name, MAX_PLAYER_NAME);
- format(string, sizeof(string), "VIP: {FFFFFF}Bodyguard %s(%d) resigned.", name, playerid);
- VIP_SendMessage(ProtectingID[playerid], string);
- Bodyguard_CleanUp(playerid);
- return 1;
- }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement