startserver.bat

@echo off
set FORGE_VERSION=43.2.11

:: README:

:: These files were authored by The All The Mods team - https://www.akliz.net/allthemods
:: They have been edited for use by this modpack. Please support the original authors.

:: To use a specific Java runtime, use the following variable named CWITCH_JAVA by setting it
:: to the full path of java.exe and deleting the :: in front of the word "set".
:: If you don't know what this means, leave it alone.
:: set CWITCH_JAVA = YourFullPathTo/Java.exe

:: To disable automatic restarts, delete the :: before the following line:
:: set CWITCH_RESTART = false

:: To install the pack without starting the server, delete the :: before the following line:
set CWITCH_INSTALL_ONLY = true

set INSTALLER="%~dp0forge-1.19.2-%FORGE_VERSION%-installer.jar"
set FORGE_URL="http://files.minecraftforge.net/maven/net/minecraftforge/forge/1.19.2-%FORGE_VERSION%/forge-1.19.2-%FORGE_VERSION%-installer.jar"

:JAVA
if not defined CWITCH_JAVA (
    set CWITCH_JAVA=java
)

"%CWITCH_JAVA%" -version 1>nul 2>nul || (
   echo Minecraft 1.19 requires Java 17 - Java not found
   pause
   exit /b 1
)

:FORGE
setlocal
cd /D "%~dp0"
if not exist "libraries" (
    echo Forge not installed, installing now.
    if not exist %INSTALLER% (
        echo No Forge installer found, downloading from %FORGE_URL%
        bitsadmin.exe /rawreturn /nowrap /transfer forgeinstaller /download /priority FOREGROUND %FORGE_URL% %INSTALLER%
    )

    echo Running Forge installer.
    "%CWITCH_JAVA%" -jar %INSTALLER% -installServer
)

if not exist "server.properties" (
    (
        echo allow-flight=true
        echo motd=\u00A7f\u263D\u263E\u00A72 Cottage Witch\u00A7f\u263D\u263E\u00A7r\n\u00A74Wh\u00A76at\u00A7e's\u00A72 bu\u00A79bb\u00A75lin'\u00A7r, \u00A77\u00A7oMoon Babes\u00A7r?
        echo max-tick-time=-1
	  echo pvp=false
    )> "server.properties"
)

if "%CWITCH_INSTALL_ONLY%" == "true" (
    echo INSTALL_ONLY: complete
    goto:EOF
)

for /f tokens^=2-5^ delims^=.-_^" %%j in ('"%CWITCH_JAVA%" -fullversion 2^>^&1') do set "jver=%%j"
if not %jver% geq 17  (
    echo Minecraft 1.19 requires Java 17 - found Java %jver%
    pause
    exit /b 1
)

:START
"%CWITCH_JAVA%" @libraries/net/minecraftforge/forge/1.19.2-%FORGE_VERSION%/win_args.txt nogui

if "%CWITCH_RESTART%" == "false" (
    goto:EOF
)

echo Restarting automatically in 10 seconds (press Ctrl + C to cancel)
timeout /t 10 /nobreak > NUL
goto:START