data table1;
  length context $32 name $100 value text $2000;
  keep context name value;
    length sitename uri $200;

  text="omsobj:LogicalServer?@PublicType='LogicalServer.StoredProcess'";
  rc=1;
  do while(0<metadata_getnobj(text,rc,uri));
    rc3=metadata_getattr(uri, "Name", context);
    rc1=1;rc2=1;
    do while(rc1>0);
      rc1=metadata_getnprp(uri,rc2,name,value);
      if rc1>0 then output;
      rc2+1;
    end;
    rc+1;
  end;
  text="omsobj:ServerComponent?@PublicType='Server.StoredProcess'";
  rc=1;
  do while(0<metadata_getnobj(text,rc,uri));
    rc3=metadata_getattr(uri, "Name", context);
    rc1=1;rc2=1;
    do while(rc1>0);
      rc1=metadata_getnprp(uri,rc2,name,value);
      if rc1>0 then output;
      rc2+1;
    end;
    rc+1;
  end;

  context='global';

  userid="&sysuserid";
  siteid=&syssite;
  sysvlong="&sysvlong";

  rc=metadata_getattr("omsobj:TextStore?@Name='Setinit text'", "StoredText", text);
  text=subpad(text,index(text,'SITEINFO NAME=')+15);
  sitename=substr(text,1,index(text,"'")-1);

  /* server props */
  if "&sysprocessmode"="SAS Stored Process Server" then do;
    maxconreqs=stpsrvgetn('maximum concurrent requests');
    session=stpsrvgetn('session timeout');
    sessmaxtimeout=stpsrvgetn('maximum session timeout');
    dsesstimeout=stpsrvgetn('default session timeout');
  end;

  array _Nums _numeric_;
  do over _Nums;
    name=upcase(vname(_nums));
    value=put(_nums,8.);
    if not (name =:'RC') then output;
  end;
  array _Chars _character_;
  do over _Chars;
    name=upcase(vname(_chars));
    value=_chars;
    if name not in ('TEXT','NAME','VALUE','CONTEXT') then output;
  end;
run;