; Cryptodealy v2.5b by Shiny (noobforces)
alias genkey {
  var %n = 1
  var %n2 = 1
  var %c = 1
  var %m = $len($alphabet)
  while (%c <= $len($1)) {
    %n = $calc(( %n * $genasc($mid($1,%c,1)) + 97 ) % (%m * %m * %m))
    %n2 = $calc(( %n2 + ( %n % %m )) % %m)
    inc %c
  }
  return %n %n2
}
alias alphabet {
  return ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyzÿ1234567890!@#$%^&*()`~=-+_[]{}'";:/?¿.,<>°\|àáâãäåæèéëìíîïðñòóôõöøùúûüýþ¯µ»
}
alias genasc {
  var %s = $alphabet
  return $calc($poscs(%s,$left($1,1),1) - 1)
}
alias genchr {
  var %s = $alphabet
  return $mid(%s,$calc($1 + 1),1)
}
alias encrypt {
  var %key = $genkey($1)
  var %k = $gettok(%key,1,32)
  var %k2 = $gettok(%key,2,32)
  var %p = $replace($2-,$chr(32),$chr(255),$chr(3),$chr(160),$chr(15),$chr(161))
  var %m = $len($alphabet)
  var %c = 1
  var %output = $null
  while (%c <= $len(%p)) {
    %k = $calc( ( ( %k * %k + %k + %k2 ) ) % ( %m * %m * %m ) )
    var %t = $xor($genasc($mid(%p,%c,1)),$calc(%k % %m))
    %output = %output $+ $genchr(%t)
    inc %c
  }
  return %output
}
alias decrypt {
  var %key = $genkey($1)
  var %k = $gettok(%key,1,32)
  var %k2 = $gettok(%key,2,32)
  var %p = $2-
  var %m = $len($alphabet)
  var %c = 1
  var %output = $null
  while (%c <= $len(%p)) {
    %k = $calc( ( ( %k * %k + %k + %k2 ) ) % ( %m * %m * %m ) )
    var %t = $xor($genasc($mid(%p,%c,1)),$calc(%k % %m))
    %output = %output $+ $genchr(%t)
    inc %c
  }
  return $replace(%output,$chr(255),$chr(32),$chr(160),$chr(3),$chr(161),$chr(15))
}
alias setkey {
  set %cryptodealy.key $1
}
on ^1:HOTLINK:Crypt//*:*:{
  if ($len($1) > 7) return
  halt
}
on 1:HOTLINK:*:*:{
  echo -a Decrypt: $decrypt(%cryptodealy.key,$right($gettok($hotline,$findtok($hotline,$1,32),32),-7))
}
alias csay {
  say Crypt// $+ $encrypt(%cryptodealy.key,$1-)
  editbox -p /csay
}
alias cecho {
  echo -a Crypt// $encrypt(%cryptodealy.key,$1-)
}
on *:TEXT:Crypt//*:*:{ echo -tmi2 $iif($target == $me,$nick,$chan) $+($chr(123),$chr(3),$nick(#,$nick).color,$nick,$chr(3),$chr(125)) Decrypt: $decrypt(%cryptodealy.key,$right($1-,-7)) }