sub1

Sub Charts1()
    ' This sub illustrates some of the properties of a chart. The chart already
    ' exists (was built with Excel's chart tools) on the Sales sheet.
    Dim message As String
    Dim chtObj As ChartObject
    Dim cht As Chart
    Dim ser As Series, serCount As Integer
    Dim axH As Axis, axV As Axis

    Set chtObj = wsDistrict12.ChartObjects("District 12")
    Set cht = chtObj.Chart
    Set axH = cht.Axes(xlCategory)
    Set axV = cht.Axes(xlValue)

    message = "Here are some properties of the chartobject." & vbCrLf
    With chtObj
        message = message & vbCrLf & "Left: " & .Left
        message = message & vbCrLf & "Top: " & .Top
        message = message & vbCrLf & "Height: " & .Height
        message = message & vbCrLf & "Width property: " & .Width
        message = message & vbCrLf & "Name: " & .Name
    End With
    MsgBox message, vbInformation

    message = "Here are some properties of the chart." & vbCrLf
    With cht
        message = message & vbCrLf & "ChartType: " & .ChartType
        message = message & vbCrLf & "HasLegend: " & .HasLegend
        message = message & vbCrLf & "HasTitle: " & .HasTitle
        If .HasTitle Then _
            message = message & vbCrLf & "Title: " & .ChartTitle.Text
        message = message & vbCrLf & "Number of series plotted: " _
            & .SeriesCollection.Count
    End With
    MsgBox message, vbInformation

    message = "Here are some properties of the series in the chart." & vbCrLf
    For Each ser In cht.SeriesCollection
        serCount = serCount + 1
        With ser
            message = message & vbCrLf & "Name of series " _
                & serCount & ": " & .Name
            message = message & vbCrLf & "MarkerSize for series " _
                & serCount & ": " & .MarkerSize
            message = message & vbCrLf & "MarkerBackgroundColor for series " _
                & serCount & ": " & .MarkerBackgroundColor
            message = message & vbCrLf & "MarkerForegroundColor for series " _
                & serCount & ": " & .MarkerForegroundColor
            message = message & vbCrLf & "MarkerStyle for series " _
                & serCount & ": " & .MarkerStyle
            message = message & vbCrLf
        End With
    Next
    MsgBox message

    message = "Some properties of the horizontal axis:" & vbCrLf
    With axH
        message = message & vbCrLf & "Format of tick labels: " _
            & .TickLabels.NumberFormat
        If .HasTitle Then
            message = message & vbCrLf & "Title: " & .AxisTitle.Text
            message = message & vbCrLf & "Font size of title: " _
                & .AxisTitle.Font.Size
        Else
            message = message & vbCrLf & "Horizontal axis has no title."
        End If
    End With
    MsgBox message

    message = "Some properties of the vertical axis:" & vbCrLf
    With axV
        If .HasTitle Then
            message = message & vbCrLf & "Title: " & .AxisTitle.Text
            message = message & vbCrLf & "Font size of title: " _
                & .AxisTitle.Font.Size
        Else
            message = message & vbCrLf & "Vertical axis has no title."
        End If
        message = message & vbCrLf & "Minimum scale: " & .MinimumScale
        message = message & vbCrLf & "Maximum scale: " & .MaximumScale
    End With
    MsgBox message
End Sub