EurenikZ

Batch Video Cutter & Encoder

Jul 14th, 2025 (edited)
288
0
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Batch 10.10 KB | None | 0 0
  1. :: Dieses Skript verarbeitet alle .mp4-Dateien im aktuellen Verzeichnis, entfernt die angegebenen Sekunden vom Anfang und Ende und komprimiert sie optional per FFmpeg mit einem wählbaren CRF-Wert. Nur Videos mit ausreichender Länge (Videolänge + 3 > Schnittbereich) werden bearbeitet. Der ursprüngliche Zeitstempel (Änderungsdatum) der Datei wird im Nachhinein neu gesetzt, und die Ausgabedateien erhalten angepasste Namen (_cut.mp4 oder _crfXX.mp4).
  2. :: Für Videos von Action-Cams, die kein GPS besitzen und daher keine Zeitzone in den Metadaten speichern, erfolgt eine extra Abfrage zur Angabe einer Zeitzone. Häufig ist auch das Aufnahmedatum in den Metadaten falsch, während nur das Änderungsdatum der Datei die korrekte Zeit enthält. Um ein korrektes Aufnahmedatum in Galerie-Programmen (z. B. Google Fotos, Immich) zu erhalten, wird das Änderungsdatum als Aufnahmedatum in die Metadaten geschrieben. Wichtig: In der Kamera muss stets die lokale Uhrzeit des Aufnahmeortes eingestellt sein. Das Skript kann auch für andere Videos genutzt werden.
  3. :: Bei Videos, die von einer DJI Action Kamera oder der DJI Mimo App stammen, wird automatisch das Datum aus dem Dateinamen verwendet, unabhängig von der Eingabe in der Script-Abfrage. Zusätzlich wird die Zeitzone aus der Abfrage berücksichtigt.
  4. :: Das Script verarbeitet alle .mp4-Dateien im aktuellen Verzeichnis, entfernt die angegebenen Sekunden vom Anfang und Ende und komprimiert sie optional per FFmpeg mit einem wählbaren CRF-Wert. Nur Videos mit ausreichender Länge (Videolänge + 3 > Schnittbereich) werden bearbeitet. Kodiert werden kann als H.265 und AV1. Die Ausgabedateien erhalten angepasste Namen.
  5. ::
  6. :: Verwendung des Scripts:
  7. ::
  8. :: Script als z. B. "encode.bat" mit Kodierung "UTF-8" anlegen.
  9. :: "ffmpeg-release-essentials.zip" hier herunterladen, entpacken und aus dem Ordner "bin" die ffmpeg.exe und ffprobe.exe in das Verzeichnis kopieren: https://www.gyan.dev/ffmpeg/builds/
  10. :: "exiftool-XXX.zip" hier herunterladen, entpacken, in das Verzeichnis kopieren und die .exe-Datei umbenennen in "exiftool.exe": https://exiftool.org/
  11. :: Version 2.3.2-pub - 06.09.2025
  12.  
  13. @echo off
  14. setlocal enabledelayedexpansion
  15.  
  16. :: Benutzerabfrage: Codec-Auswahl
  17. echo Waehle Codec:
  18. echo 1 - H.265 - Gute Kompression, schnellere Kodierung, breite Unterstuetzung (Standard)
  19. echo 2 - AV1 - Beste Kompression, aber sehr langsam, fuer neuere Geraete
  20. set /p CODECWAHL="Eingabe (1 oder 2): "
  21.  
  22. if not "%CODECWAHL%"=="1" if not "%CODECWAHL%"=="2" (
  23.     echo Ungueltige Eingabe. Standard: H.265 wird verwendet.
  24.     set CODECWAHL=1
  25. )
  26.  
  27. :: Benutzerabfrage: Start-Sekunden schneiden
  28. :ASK_CUT_START
  29. set CUT_START=
  30. set /p CUT_START="Wie viele Sekunden vom ANFANG sollen entfernt werden? "
  31. if "%CUT_START%"=="" set CUT_START=0
  32. if not "%CUT_START%"=="0" (
  33.     echo %CUT_START%| findstr /r "^[0-9][0-9]*$" >nul
  34.     if errorlevel 1 (
  35.         echo Ungueltige Eingabe bei Startzeit^^!
  36.         goto ASK_CUT_START
  37.     )
  38. )
  39.  
  40. :: Benutzerabfrage: End-Sekunden schneiden
  41. :ASK_CUT_END
  42. set CUT_END=
  43. set /p CUT_END="Wie viele Sekunden vom ENDE sollen entfernt werden? "
  44. if "%CUT_END%"=="" set CUT_END=0
  45. if not "%CUT_END%"=="0" (
  46.     echo %CUT_END%| findstr /r "^[0-9][0-9]*$" >nul
  47.     if errorlevel 1 (
  48.         echo Ungueltige Eingabe bei Endzeit^^!
  49.         goto ASK_CUT_END
  50.     )
  51. )
  52.  
  53. :: Benutzerabfrage: CRF-Wert
  54. :ASK_CRF
  55. set CRF_WERT=
  56. if "%CODECWAHL%"=="1" (
  57.     echo H.265 CRF-Wert ^(18=hoch, 25=normal, 30=niedrig, 35=sehr niedrig^) - Leer lassen = nur schneiden
  58. ) else (
  59.     echo AV1 CRF-Wert ^(20=hoch, 30=normal, 38=niedrig, 45=sehr niedrig^) - Leer lassen = nur schneiden
  60. )
  61. set /p CRF_WERT="Welcher CRF-Wert soll verwendet werden? "
  62.  
  63. if not "%CRF_WERT%"=="" (
  64.     echo %CRF_WERT%| findstr /r "^[0-9][0-9]*$" >nul
  65.     if errorlevel 1 (
  66.         echo Ungueltige Eingabe bei CRF-Wert^^!
  67.         goto ASK_CRF
  68.     )
  69. )
  70.  
  71. :: Benutzerabfrage: Zeitzone
  72. :: Automatisch Sommer-/Winterzeit erkennen für Deutschland
  73. for /f "usebackq delims=" %%i in (`powershell -NoProfile -Command "$tz = [System.TimeZoneInfo]::FindSystemTimeZoneById('W. Europe Standard Time'); $now = Get-Date; if($tz.IsDaylightSavingTime($now)) {'+02:00'} else {'+01:00'}"`) do set "SYSTEM_TZ=%%i"
  74.  
  75. set /p "TIMEZONE_NECESSARY=Muss Zeitzone in Datei geschrieben werden? Notwendig bei Videos ohne GPS-Daten (y/n): "
  76. if /i "!TIMEZONE_NECESSARY!"=="y" (
  77.     set /p "TIMEZONE=Zeitzone fuer Metadaten (Format: +/-XX:00, leer fuer Standard: !SYSTEM_TZ!): "
  78.     if "!TIMEZONE!"=="" (
  79.         echo Leere Eingabe. Standard: !SYSTEM_TZ! wird verwendet
  80.         set "TIMEZONE=!SYSTEM_TZ!"
  81.     )
  82. ) else (
  83.     set "TIMEZONE="
  84. )
  85.  
  86. :: Benutzerabfrage: Welches Datum als Aufnahmedatum verwenden?
  87. echo Welches Datum soll als Aufnahmedatum verwendet werden? Bei Videos von DJI und DJI Mimo wird automatisch das Datum aus dem Dateinamen verwendet.
  88. echo 1 - Aenderungsdatum der Datei
  89. echo 2 - Aufnahmedatum aus Metadaten (Standard)
  90. set /p DATETOUSE="Eingabe (1 oder 2): "
  91.  
  92. if not "%DATETOUSE%"=="1" if not "%DATETOUSE%"=="2" (
  93.     echo Ungueltige Eingabe. Standard: "Aufnahmedatum aus Metadaten" wird verwendet
  94.     set DATETOUSE=2
  95. )
  96.  
  97. :: Benutzerabfrage: Audio entfernen?
  98. set /p REMOVE_AUDIO="Ton entfernen? (y/n): "
  99. if /i "%REMOVE_AUDIO%"=="y" (
  100.     set "AUDIO_PARAM=-an"
  101.     echo Audio wird entfernt
  102. ) else (
  103.     set "AUDIO_PARAM=-c:a aac -b:a 160k"
  104. )
  105.  
  106. :: Schleife durch alle MP4-Dateien
  107. for %%F in (*.mp4) do (
  108.     :: Prüfen ob "_crf" im Dateinamen enthalten ist
  109.     echo %%F | findstr /i "_crf" >nul
  110.     if !errorlevel! == 0 (
  111.         echo [OK] Ignoriert: %%F - bereits verarbeitetes Video
  112.     ) else (
  113.         echo Bearbeite: %%F
  114.  
  115.         :: Prüfen ob DJI Action Video, falls ja, Datum aus Dateinamen verwenden
  116.         echo %%~nF | findstr /r /i "^DJI_[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]_" >nul
  117.         if !errorlevel! == 0 (
  118.             :: Dateiname ohne Extension
  119.             set "FNAME=%%~nF"
  120.  
  121.             :: 14-stellige Zeitkette nach "DJI_"
  122.             for /f "tokens=2 delims=_" %%A in ("!FNAME!") do (
  123.                 set "DATETIME=%%A"
  124.             )
  125.  
  126.             set "YYYY=!DATETIME:~0,4!"
  127.             set "MM=!DATETIME:~4,2!"
  128.             set "DD=!DATETIME:~6,2!"
  129.             set "hh=!DATETIME:~8,2!"
  130.             set "nn=!DATETIME:~10,2!"
  131.             set "ss=!DATETIME:~12,2!"
  132.  
  133.             :: Aufnahmedatum mit Offset festlegen
  134.             set "TIMESTAMP=!YYYY!:!MM!:!DD! !hh!:!nn!:!ss!!TIMEZONE!"
  135.  
  136.             echo [INFO] DJI Action Video erkannt, verwende Aufnahmedatum aus Dateinamen...
  137.        
  138.         ) else (
  139.             :: Prüfen ob DJI Mimo Datei, falls ja, Datum aus Dateinamen verwenden
  140.             echo %%~nF | findstr /b /i "dji_mimo_" >nul
  141.             if !errorlevel! == 0 (
  142.                 :: Dateiname ohne Extension
  143.                 set "FNAME=%%~nF"
  144.  
  145.                 :: tokens=3,4: überspringe "dji_mimo"
  146.                 for /f "tokens=3,4 delims=_" %%A in ("!FNAME!") do (
  147.                     set "FILEDATE=%%A"
  148.                     set "FILETIME=%%B"
  149.                 )
  150.  
  151.                 set "YYYY=!FILEDATE:~0,4!"
  152.                 set "MM=!FILEDATE:~4,2!"
  153.                 set "DD=!FILEDATE:~6,2!"
  154.                 set "hh=!FILETIME:~0,2!"
  155.                 set "nn=!FILETIME:~2,2!"
  156.                 set "ss=!FILETIME:~4,2!"
  157.  
  158.                 :: Aufnahmedatum mit Offset festlegen
  159.                 set "TIMESTAMP=!YYYY!:!MM!:!DD! !hh!:!nn!:!ss!!TIMEZONE!"
  160.  
  161.                 echo [INFO] DJI Mimo Datei erkannt, verwende Aufnahmedatum aus Dateinamen...
  162.             ) else (
  163.                 :: Datum entsprechend der Benutzerwahl auslesen
  164.                 if "!DATETOUSE!"=="2" (
  165.                     :: Aufnahmedatum aus Video-Metadaten (Create Date)
  166.                     for /f "usebackq delims=" %%T in (`exiftool.exe -s3 -CreateDate "%%F"`) do (
  167.                         set "TIMESTAMP=%%T"
  168.                     )
  169.                     if not defined TIMESTAMP (
  170.                         echo Warnung: Kein Aufnahmedatum gefunden fuer %%F, verwende Aenderungsdatum
  171.                         for /f "usebackq delims=" %%T in (`powershell -NoLogo -NoProfile -Command "(Get-Item '%%F').LastWriteTime.ToString('yyyy:MM:dd HH:mm:ss')"`) do (
  172.                             set "TIMESTAMP=%%T"
  173.                         )
  174.                     )
  175.                 ) else (
  176.                     :: Änderungsdatum der Datei (Standard)
  177.                     for /f "usebackq delims=" %%T in (`powershell -NoLogo -NoProfile -Command "(Get-Item '%%F').LastWriteTime.ToString('yyyy:MM:dd HH:mm:ss')"`) do (
  178.                         set "TIMESTAMP=%%T"
  179.                     )
  180.                 )
  181.             )
  182.         )
  183.  
  184.         for /f "usebackq delims=" %%D in (`ffprobe -v error -select_streams v:0 -show_entries format^=duration -of default^=nokey^=1:noprint_wrappers^=1 "%%F"`) do (
  185.             set "DURATION=%%D"
  186.         )
  187.         for /f "tokens=1 delims=." %%T in ("!DURATION!") do set /a INTDURATION=%%T
  188.         set /a CUTS_TOTAL=!CUT_START!+!CUT_END!
  189.         set /a VIDEO_PLUS_3=!INTDURATION!+3
  190.         if !VIDEO_PLUS_3! GTR !CUTS_TOTAL! (
  191.             set /a REMAINING=!INTDURATION!-!CUTS_TOTAL!
  192.             if !REMAINING! GEQ 1 (
  193.                 set "OUTFILE=%%~nF"
  194.                 if "%CRF_WERT%"=="" (
  195.                     set "OUTFILE=!OUTFILE!_cut.mp4"
  196.                     ffmpeg -y -i "%%F" -ss !CUT_START! -t !REMAINING! -c copy !AUDIO_PARAM! "!OUTFILE!"
  197.                 ) else (
  198.                     if "%CODECWAHL%"=="1" (
  199.                         set "OUTFILE=!OUTFILE!_crf!CRF_WERT!.mp4"
  200.                         ffmpeg -y -ss !CUT_START! -i "%%F" -t !REMAINING! -c:v libx265 -crf !CRF_WERT! -preset slow -movflags +faststart !AUDIO_PARAM! "!OUTFILE!"
  201.                     ) else (
  202.                         :: AV1 - CPU-Used dynamisch bestimmen
  203.                         if !CRF_WERT! LEQ 20 (
  204.                             set "CPU_USED=2"
  205.                         ) else if !CRF_WERT! LEQ 28 (
  206.                             set "CPU_USED=4"
  207.                         ) else if !CRF_WERT! LEQ 35 (
  208.                             set "CPU_USED=6"
  209.                         ) else (
  210.                             set "CPU_USED=8"
  211.                         )
  212.                         set "OUTFILE=!OUTFILE!_AV1_crf!CRF_WERT!.mp4"
  213.                         ffmpeg -y -ss !CUT_START! -i "%%F" -t !REMAINING! -c:v libaom-av1 -crf !CRF_WERT! -cpu-used !CPU_USED! -movflags +faststart !AUDIO_PARAM! "!OUTFILE!"
  214.                     )
  215.                 )
  216.  
  217.                 :: ExifTool: UTC in MP4/QuickTime-Felder, lokale Zeit + Offset in EXIF
  218.                 if defined TIMEZONE (
  219.                     exiftool.exe -overwrite_original ^
  220.                         "-DateTimeOriginal=!TIMESTAMP!!TIMEZONE!" ^
  221.                         "-OffsetTimeOriginal=!TIMEZONE!" ^
  222.                         "-FileModifyDate=!TIMESTAMP!" ^
  223.                         "!OUTFILE!"
  224.                 ) else (
  225.                     :: Bei GPS-Videos: Zeit-Metadaten vom Original kopieren
  226.                     exiftool.exe -overwrite_original -TagsFromFile "%%F" ^
  227.                         "-DateTimeOriginal" ^
  228.                         "-CreateDate" ^
  229.                         "-ModifyDate" ^
  230.                         "-OffsetTimeOriginal" ^
  231.                         "-OffsetTime" ^
  232.                         "-OffsetTimeDigitized" ^
  233.                         "-FileModifyDate" ^
  234.                         "!OUTFILE!"
  235.                 )
  236.  
  237.                 echo [OK] Verarbeitet: !OUTFILE!
  238.             ) else (
  239.                 echo [OK] Uebersprungen: %%F - nur !REMAINING!s wuerden uebrig bleiben
  240.             )
  241.         ) else (
  242.             echo [OK] Uebersprungen: %%F - !VIDEO_PLUS_3! nicht > !CUTS_TOTAL!
  243.         )
  244.     )
  245. )
  246.  
  247. echo.
  248. powershell -c [console]::beep(500,200)
  249. echo Alle Videos wurden verarbeitet.
  250. pause
  251.  
Advertisement
Add Comment
Please, Sign In to add comment