Cursive charset

.pc = $0801 "Basic UpStart"
basic:
:BasicUpstart2(start)

.pc = * "Entrypoint"
start:
                sei

                lda $01
                and #%11111011
                sta $01

                lda #$00
                sta $fb
                sta $fd
                lda #$d0
                sta $fc
                lda #$20
                sta $fe

copyslide:
                ldy #$00
                lda ($fb),y
                lsr
                sta ($fd),y
                iny
                lda ($fb),y
                lsr
                sta ($fd),y
                iny
                lda ($fb),y
                sta ($fd),y
                iny
                lda ($fb),y
                sta ($fd),y
                iny
                lda ($fb),y
                sta ($fd),y
                iny
                lda ($fb),y
                asl
                sta ($fd),y
                iny
                lda ($fb),y
                asl
                sta ($fd),y
                iny
                lda ($fb),y
                asl
                sta ($fd),y

                lda $fb
                clc
                adc #$08
                sta $fb
                bcc !+
                inc $fc
!:
                lda $fd
                clc
                adc #$08
                sta $fd
                bcc !+
                inc $fe
!:              lda $fc
                cmp #$d8
                bne copyslide

                lda $01
                ora #%00000100
                sta $01

                lda #%00011000
                sta $d018

                lda #%00000011
                sta $dd00

                cli

                rts