gc-golf-export.jq

# v3 (2021-03-20)

# CSV Header
[
    "Start Time",
    "Start Time (UTC)",
    "Scorecard URL",
    "Course",
    "Score",
    "Handicap",
    "Strokes",
    "Handicapped Strokes",

    ([range(1;19)] | map(tostring |
        "Hole \(.) - Time (UTC)",
        "Hole \(.) - Par",
        "Hole \(.) - Strokes",
        "Hole \(.) - Handicap Score",
        "Hole \(.) - Lat",
        "Hole \(.) - Lon"
    ) | .[])
],

# CSV Data
(
    .details[] |
        .scorecardDetails[0].scorecard as $scorecard |
        .courseSnapshots[0] as $course |
        [
            $scorecard.formattedStartTime,
            $scorecard.startTime,
            .scorecardURL,
            $course.name,
            $scorecard.score,
            $scorecard.playerHandicap,
            $scorecard.strokes,
            $scorecard.handicappedStrokes,

            ($scorecard.holes | map(
                .lastModifiedDt,
                $course.holePars[.number-1:.number],
                .strokes,
                .handicapScore,
                .pinPositionLat,
                .pinPositionLon
            ) | .[])
        ]
)

| @csv