prt_fild12,0,0,0,0	monster	Lunatic	1063,8,5000,0,0
prt_fild12,0,0,0,0	monster	Poring	1002,8,5000,0,0
prt_fild12,0,0,0,0	monster	Fabre	1007,8,5000,0,0


prt_fild12	mapflag	nocommand	20
prt_fild12	mapflag	nomemo


-	script	Freebies#main	-1,{
function getWeapon;

OnPCJobLvUpEvent:
if( JobLevel == 10 ){
	if( Class == Job_Swordman ) getitem 13874,1;
	else if( Class == Job_Mage ) getitem 13871,1;
	else if( Class == Job_Archer || Class == 24 ) getitem 13873,1;
	else if( Class == Job_Acolyte ) getitem 13872,1;
	else if( Class == Job_Merchant ) getitem 13876,1;
	else if( Class == Job_Thief ) getitem 13875,1;
	else if( Class == Job_SuperNovice ) getitem 13880,1;
}
end;

OnPCBaseLvUpEvent:
if( BaseLevel == 12 ) setarray .@eden_equips[0],2456,5583,2560,15009;
else if( BaseLevel == 26 ) setarray .@eden_equips[0],2457,15010;
else if( BaseLevel == 40 ) setarray .@eden_equips[0],2458,15011;
else if( BaseLevel == 60 ) setarray .@eden_equips[0],2473,18514,2571;
else if( BaseLevel == 100 ){
	setarray .@eden_equips[0],2795;
	if( BaseJob == Job_Knight ) setarray .@eden_equips[1],5746;
	else if( BaseJob == Job_Priest ) setarray .@eden_equips[1],5747;
	else if( BaseJob == Job_Hunter ) setarray .@eden_equips[1],5748,6124;
	else if( BaseJob == Job_Blacksmith ) setarray .@eden_equips[1],5749;
	else if( BaseJob == Job_Rogue ) setarray .@eden_equips[1],5750,6121,6122;
	else if( BaseJob == Job_Bard ) setarray .@eden_equips[1],5751;
	else if( BaseJob == Job_Alchemist ) setarray .@eden_equips[1],5752;
	else if( BaseJob == Job_Wizard ) setarray .@eden_equips[1],5753;
	else if( BaseJob == Job_Monk ) setarray .@eden_equips[1],5754;
	else if( BaseJob == Job_Assassin ) setarray .@eden_equips[1],5755;
	else if( BaseJob == Job_Sage ) setarray .@eden_equips[1],5756;
	else if( BaseJob == Job_Crusader ) setarray .@eden_equips[1],5757;
	else if( BaseJob == Job_Dancer ) setarray .@eden_equips[1],5758;

}else if( BaseLevel == 150 ){
	announce "Congratulation for '"+strcharinfo(0)+"' has reaching Level 150.",bc_blue;
	// getitem 6320,1;
}

.@eden_size = getarraysize( .@eden_equips );
if( .@eden_size ){
	mes "^FF0000Granted new equipments^000000.";
	for( .@i = 0; .@i < .@eden_size; .@i++ )
		if( !countitem( .@eden_equips[.@i] ) ){
			getitem .@eden_equips[.@i],1;
			if( getiteminfo( .@eden_equips[.@i],2 ) == 4 || getiteminfo( .@eden_equips[.@i],2 ) == 5 )
				equip .@eden_equips[.@i];
		}

	if( BaseLevel == 26 ) getWeapon( 1747,13050,16004,13112,13423,1192,1650 );
	else if( BaseLevel == 40 ) getWeapon( 1748,13051,16005,13113,13424,1193,1651 );
	else if( BaseLevel == 60 ) getWeapon( 1583,18106,13066,1931,1289,1831,16014,13114,13434,1197,1434,1658,1986,1391 );
}
close;

function	getWeapon	{
.@count = getargcount();
for( .@menu$ = ""; .@i < .@count; .@i++ )
	.@menu$ = .@menu$ + "^0055FF ~ "+getitemname( getarg(.@i) )+"^000000" +":";
mes "You may select a weapon for your choices.";
.@i = select( .@menu$ ) - 1;
getitem getarg( .@i ),1;
equip getarg( .@i );
close;
}

}