lib32-opencl-nvidia

# Maintainer: Peace4all <markspost at rocketmail dot com>
# Contributor: Thomas Baechler <[email protected]>
# Contributor: James Rayner <[email protected]>

pkgname=lib32-opencl-nvidia
pkgdesc="OpenCL implemention for NVIDIA (32-bit)"
pkgver=313.18
pkgrel=1
arch=('x86_64')
url="http://www.nvidia.com/"
license=('custom')
depends=('zlib' 'opencl-nvidia' 'lib32-nvidia-utils')
optdepends=('opencl-headers: headers necessary for OpenCL development')
options=('!strip')

_arch='x86'
_pkg="NVIDIA-Linux-${_arch}-${pkgver}"
source=("ftp://download.nvidia.com/XFree86/Linux-${_arch}/${pkgver}/${_pkg}.run")
md5sums=('780c37c28a6e06e9571cafe348b7da64')

create_links() {
    # create soname links
    while read -d '' _lib; do
        _soname="$(dirname "${_lib}")/$(LC_ALL=C readelf -d "${_lib}" | sed -nr 's/.*Library soname: \[(.*)\].*/\1/p')"
        [[ -e "${_soname}" ]] || ln -s "$(basename "${_lib}")" "${_soname}"
        [[ -e "${_soname/.[0-9]*/}" ]] || ln -s "$(basename "${_soname}")" "${_soname/.[0-9]*/}"
    done < <(find "${pkgdir}" -type f -name '*.so*' -print0)
}

build() {
    cd "${srcdir}"
    sh "${_pkg}.run" --extract-only
}

package() {

    cd "${srcdir}/${_pkg}"

    install -D -m755 "libnvidia-opencl.so.${pkgver}" \
	"${pkgdir}/usr/lib32/libnvidia-opencl.so.${pkgver}"

    create_links

    # create a link to 'libnvidia-compiler.so'
    # which is included in the official 'lib32-nvidia-utils' package
    # but with no link of its own included in that package ?
    # maybe that package should be queried about this.
    ln -s "/usr/lib32/libnvidia-compiler.so.${pkgver}" \
    "$pkgdir/usr/lib32/libnvidia-compiler.so"
}