Hidonim [Unofficial]

#include <amxmodx>
#include <dhudmessage>

// Tasks
#define HidonimGamesCount 6
#define task_vote 1
#define task_start_hidon 2
#define task_hud 3

// Paths
#define AnimeDefaultPath "sound/TopDeathrun/Anime/"
#define NostalgiaDefaultPath "sound/TopDeathrun/Nostalgia/"
#define LogoQuizHost "http://top-clan.000webhostapp.com/LogoQuiz/"

// Config Files
#define MissingLetterCfgFile "addons/amxmodx/configs/Hidonim/missingletter.txt"
#define LogoQuizCfgFile "addons/amxmodx/configs/Hidonim/logoquiz.txt"
#define TriviaCfgFile "addons/amxmodx/configs/Hidonim/trivia.txt"
#define AnimeCfgFile "addons/amxmodx/configs/Hidonim/anime.txt"
#define NostalgiaCfgFile "addons/amxmodx/configs/Hidonim/nostalgia.txt"

// Constants
#define MAX_QUESTIONS 64
#define MAX_QUESTIONS_LENGTH 64
#define MAX_ANSWER_LENGTH 32
#define MAX_SONG_NAME 32
#define MAX_PATH_SIZE 64
#define MAX_ML_WORD_SIZE 32

//#define USE_NATIVES

#if defined USE_NATIVES
native add_user_xp(id, amount);
native add_user_points(id, amount);
#endif

enum _:HidonProperties
{
	name[16],
	points,
	xp
}

enum _:SongProperties
{
	name[MAX_SONG_NAME],
	file_name[MAX_PATH_SIZE]
}

enum _:QuestionProperties
{
	Quest[MAX_QUESTIONS_LENGTH],
	Answr[MAX_ANSWER_LENGTH]
}

new const Hidon[HidonimGamesCount][HidonProperties] =
{
	{ "Math", 50, 20 },
	{ "Nostalgia", 80, 40 },
	{ "Anime", 100, 60 },
	{ "Trivia", 110, 65 },
	{ "LogoQuiz", 130, 70 },
	{ "Missing Letter", 135, 75 }
}

new bool:HidonIsRunning = false;
new GameCount = 0;
new bool:isVoted[33];
new VoteTimer = 100;
new Votes[HidonimGamesCount];
new ChoosenHidonId = -1;
new StartHidonCD = 5;
new WinnerId = -1;
new WinnerName[33];
new bool:ShowMsgOnce = false;
new num1, num2;
new HidonTimer = 60;
new RndId = -1;
new Answer[32];
new MLWord[MAX_ML_WORD_SIZE];
new ML_UpdateAmount = 0;
new ML_LastIds[8] = { -1, -1, -1, -1, -1, -1 , -1 , -1 };
new Float:ML_timer;
new Array:MLWords_indexes;
new HidonWaitingTime = 600;
new sound[64];

new NostalgiaSongsLoaded = 0;
new AnimeSongsLoaded = 0;
new TriviaQuestionsLoaded = 0;
new LogoQuizQuestionsLoaded = 0;
new MLQuestionsLoaded = 0;

new MLQuestions[MAX_QUESTIONS][MAX_ML_WORD_SIZE];
new LogoQuizQuestions[MAX_QUESTIONS][QuestionProperties];
new TriviaQuestions[MAX_QUESTIONS][QuestionProperties];
new AnimeSongs[MAX_QUESTIONS][SongProperties];
new NostalgiaSongs[MAX_QUESTIONS][SongProperties];


public plugin_init()
{
	register_plugin("Hidonim", "v4", "JuSTaR (Original Idea by Ariel aka xBosh)");

	register_clcmd("say /start_hidon", "AdminMenu", ADMIN_RCON); // Opens Hidonim start menu
	register_clcmd("say /stop_hidon", "ResetHidon", ADMIN_RCON); // Stop Hidon
	register_clcmd("say /answer", "ShowAnswer", ADMIN_RCON); // ch3ater huh?

	register_clcmd("say /printAllSongsNames", "printAllSongsNames");
	register_clcmd("say /hidon", "NextHidon");
	register_clcmd("say /logo", "LogoQuiz_ShowLogo");
	register_clcmd("say /s", "StopMusic");
	register_clcmd("say /r", "ReplayMusic");
	register_clcmd("say", "CheckAnswer");

	set_task(1.0, "HidonCD", _, _, _, "b");

	LoadNostalgia();
	LoadAnime();
	LoadTriviaQuestions();
	LoadLogoQuiz();
	LoadMissingLetter();
}

public printAllSongsNames(id)
{
	new path[128];

	for (new i = 0; i < NostalgiaSongsLoaded; i++)
	{
		formatex(path, charsmax(path), "^"%s%s^"", NostalgiaDefaultPath, NostalgiaSongs[i][file_name]);
		ColorChat(id, "%s", path);
	}

	for (new i = 0; i < AnimeSongsLoaded; i++)
	{
		formatex(path, charsmax(path), "^"%s%s^"", AnimeDefaultPath, AnimeSongs[i][file_name]);
		ColorChat(id, "%s", path);
	}

	return PLUGIN_HANDLED;
}

public AdminMenu(id)
{
	new mAdmin = menu_create("\r[\y Top Deathrun \r] \yChoose a hidon to start:", "AdminMenu_Handler");

	menu_additem(mAdmin, "\yStart Hidon Vote");

	for (new i = 0; i < HidonimGamesCount; i++)
		menu_additem(mAdmin, Hidon[i][name]);

	menu_display(id, mAdmin, 0);

	return PLUGIN_HANDLED;
}

public AdminMenu_Handler(id, mAdmin, item)
{
	if (item != MENU_EXIT)
	{
		ResetHidon();
		HidonIsRunning = true;

		if (item == 0)
		{
			HidonVote();
			ColorChat(0, "^4%s ^1has started ^3Hidon Vote^1.", get_player_name(id));
		}
		else
		{
			ChoosenHidonId = item-1;
			StartHidon();
			ColorChat(0, "^4%s ^1has started ^3Hidon %s^1.", get_player_name(id), Hidon[item-1][name]);
		}

		return PLUGIN_HANDLED;
	}

	menu_destroy(mAdmin);
	return PLUGIN_HANDLED;
}

public HidonCD()
{
	if (HidonWaitingTime == 0)
	{
		HidonIsRunning = true;
		HidonVote();
	}

	HidonWaitingTime--;
}

public NextHidon(id)
{
	if (HidonIsRunning)
		ColorChat(id, "A ^3Hidon ^1is already in progress.");
	else
		ColorChat(id, "^3Next Hidon ^1in: ^4%d ^1minutes and ^4%d ^1seconds.", HidonWaitingTime/60, HidonWaitingTime%60);

	return PLUGIN_HANDLED;
}

public ShowAnswer(id)
{
	ColorChat(id, "Answer is: %s", Answer);
	return PLUGIN_HANDLED;
}

public StopMusic(id)
{
	client_cmd(id, "mp3 stop");
}

public ReplayMusic(id)
{
	if (sound[0])
		client_cmd(id, "mp3 play ^"%s^"", sound);
}

public LogoQuiz_ShowLogo(id)
{
	if (ChoosenHidonId != 4)
		return;

	new path[128];
	formatex(path, charsmax(path), "%s%s", LogoQuizHost, LogoQuizQuestions[RndId][Quest]);
	show_motd(id, path, ".: [ Top Deathrun ] LogoQuiz :.");
}

public plugin_precache()
{
	precache_generic("sound/TopDeathrun/Nostalgia/pokemon_fix.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/marko.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/A_Pigamot.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/artur.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/asfor.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/beyblade.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/Bilbi.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/BobABanai.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/code_lyoko.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/digimon.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/gur_ve_oah.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/HaMuminim.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/hshminia.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/kirbi.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/kobikobi.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/miflezetBeTaot.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/MoadonWinx.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/nils.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/SamiACabai.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/sedrik.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/Shemesh.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/spongebob.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/tomy_ve_oskar.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/tzave_aninja.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/wunschpunsch.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/yladimgivatnapolion.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/yu-gi-oh1.mp3");
	precache_generic("sound/TopDeathrun/Nostalgia/yu-gi-oh-gx.mp3");

	precache_generic("sound/TopDeathrun/Anime/Bleach_1_Fix.mp3");
	precache_generic("sound/TopDeathrun/Anime/dragonballgt.mp3");
	precache_generic("sound/TopDeathrun/Anime/dragonballz_fix.mp3");
	precache_generic("sound/TopDeathrun/Anime/dragonballz2_fix.mp3");
	precache_generic("sound/TopDeathrun/Anime/Inuyasha.mp3");
	precache_generic("sound/TopDeathrun/Anime/one_piece.mp3");
	precache_generic("sound/TopDeathrun/Anime/Sakura.mp3");
	precache_generic("sound/TopDeathrun/Anime/ShamanKing.mp3");
	precache_generic("sound/TopDeathrun/Anime/sword_art_online.mp3");
	precache_generic("sound/TopDeathrun/TokyoMewMew.mp3");

	precache_generic("sound/TopDeathrun/CD/one.wav");
	precache_generic("sound/TopDeathrun/CD/two.wav");
	precache_generic("sound/TopDeathrun/CD/three.wav");
	precache_generic("sound/TopDeathrun/CD/four.wav");
	precache_generic("sound/TopDeathrun/CD/five.wav");
}

public HidonVote()
{
	if (GameCount == 3)
	{
		ResetHidon();
		return;
	}

	if (VoteTimer < 0)
	{
		ColorChat(0, "Vote was ended");
		GameCount++;
		show_menu(0, 0, "^n", 1);
		ChooseHidon();
		return;
	}

	new players[32], pnum;
	get_players(players, pnum, "ch");

	new buffer[128];

	for (new i = 0; i < pnum; i++)
	{
		new id = players[i]

		formatex(buffer, charsmax(buffer), "\r[\y Top Deathrun \r] \yHidon Vote:^n\r// \wStatus: %s^n\r// \wTime to choose: \y%0.1f", (isVoted[id] ? "\yVoted" : "\rNot Voted"), float(VoteTimer)/10.0);
		new VoteMenu = menu_create(buffer, "ShowVoteMenu_Handler");

		for (new i = 0; i < HidonimGamesCount; i++)
		{
			#if defined USE_NATIVES
			format(buffer, charsmax(buffer), "\w%s \r(\w%d \dPts \y& \w%d \dXp \r)\w \r[\w%d Votes\r]", Hidon[i][name], Hidon[i][points], Hidon[i][xp], Votes[i]);
			#else
			format(buffer, charsmax(buffer), "\w%s \r[\w%d Votes\r]", Hidon[i][name], Votes[i]);
			#endif
			menu_additem(VoteMenu, buffer);
		}

		menu_setprop(VoteMenu, MPROP_EXIT, MEXIT_NEVER);
		menu_display(id, VoteMenu, 0);
	}

	VoteTimer--;
	set_task(0.1, "HidonVote", task_vote);

	return;
}

public ShowVoteMenu_Handler(id, VoteMenu, item)
{
	if (item == MENU_EXIT)
	{
		menu_destroy(VoteMenu);
		return PLUGIN_HANDLED;
	}

	if (isVoted[id] || VoteTimer < 0)
		return PLUGIN_HANDLED;

	Votes[item]++;
	isVoted[id] = true;

	return PLUGIN_HANDLED;
}

public ChooseHidon()
{
	new biggestNum = Votes[0], Results = 0, Array:VotesArr;
	VotesArr = ArrayCreate(HidonimGamesCount);

	// Find Biggest
	for (new i = 1; i < HidonimGamesCount; i++)
		if (biggestNum < Votes[i])
			biggestNum= Votes[i];

	// Check if three is more same results
	for (new i = 0; i < HidonimGamesCount; i++)
	{
		if (Votes[i] == biggestNum)
		{
			ArrayPushCell(VotesArr, i);
			Results++;
		}
	}

	if (Results > 1)
	{
		ChoosenHidonId = ArrayGetCell(VotesArr, random_num(0, ArraySize(VotesArr)-1));
		ColorChat(0, "Hidon ^4%s ^1was randomly choosen!", Hidon[ChoosenHidonId][name]);
	}
	else
	{
		ChoosenHidonId = ArrayGetCell(VotesArr, 0);
		ColorChat(0, "Hidon ^4%s ^1was choosen.", Hidon[ChoosenHidonId][name]);
	}

	StartHidon();
}

public StartHidon()
{
	if (StartHidonCD == 0)
	{
		switch (ChoosenHidonId)
		{
			case 0: StartHidonMath();
			case 1: StartHidonNostalgia();
			case 2: StartHidonAnime();
			case 3: StartHidonTrivia();
			case 4: StartHidonLogoQuiz();
			case 5: StartHidonMissingLetter();
		}
		return;
	}

	set_dhudmessage(random_num(1, 255), random_num(1, 255), random_num(1, 255), -1.0, 0.3, 0, 1.0, 1.0, 0.5, 0.0);
	show_dhudmessage(0, "%s Will be start in %d seconds.", Hidon[ChoosenHidonId][name], StartHidonCD);

	num_to_word(StartHidonCD, sound, charsmax(sound));
	format(sound, charsmax(sound), "%s%s", "spk sound/TopDeathrun/CD/", sound);
	client_cmd(0, sound);
	StartHidonCD--;

	set_task(1.0, "StartHidon", task_start_hidon);
}

public StartHidonMath()
{
	num1 = random_num(100, 999);
	num2 = random_num(100, 999);

	new temp[4];
	num_to_str(num1+num2, temp, sizeof(temp));
	copy(Answer, sizeof(temp), temp);
	ColorChat(0, "How much is ^4%d ^3+ ^4%d ^1?", num1, num2);

	set_task(0.0, "ShowHud", task_hud);
}

public StartHidonNostalgia()
{
	RndId = random_num(0, NostalgiaSongsLoaded-1);
	copy(Answer, sizeof(Answer), NostalgiaSongs[RndId][name]);

	formatex(sound, charsmax(sound), "%s%s", NostalgiaDefaultPath, NostalgiaSongs[RndId][file_name]);
	client_cmd(0, "mp3 play ^"%s^"", sound);

	set_task(0.0, "ShowHud", task_hud);
}

public StartHidonAnime()
{
	RndId = random_num(0, AnimeSongsLoaded-1);
	copy(Answer, sizeof(Answer), AnimeSongs[RndId][name]);

	formatex(sound, charsmax(sound), "%s%s", AnimeDefaultPath, AnimeSongs[RndId][file_name]);
	client_cmd(0, "mp3 play ^"%s^"", sound);

	set_task(0.0, "ShowHud", task_hud);
}

public StartHidonTrivia()
{
	RndId = random_num(0, TriviaQuestionsLoaded-1);
	copy(Answer, charsmax(Answer), TriviaQuestions[RndId][Answr]);

	set_task(0.0, "ShowHud", task_hud);
}

public StartHidonLogoQuiz()
{
	RndId = random_num(0, LogoQuizQuestionsLoaded-1);
	copy(Answer, charsmax(Answer), LogoQuizQuestions[RndId][Answr]);

	set_task(0.0, "ShowHud", task_hud);
}

public StartHidonMissingLetter()
{
	RndId = random_num(0, MLQuestionsLoaded-1);
	copy(Answer, sizeof(Answer), MLQuestions[RndId]);

	MLWords_indexes = ArrayCreate(MAX_ML_WORD_SIZE);

	for (new i = 0; i < strlen(Answer); i++)
	{
		ArrayPushCell(MLWords_indexes, i);
		format(MLWord, sizeof(MLWord), "%s%c", MLWord, "_");
	}

	ML_UpdateAmount = strlen(MLWord)/4;
	ML_LastIds = { -1, -1, -1, -1, -1, -1 , -1 , -1 };

	for (new i = 0; i < 3; i++)
		ML_AddLetter();

	set_task(0.0, "ShowHud", task_hud);
}

public ShowHud()
{
	if (HidonTimer < 0)
	{
		if (WinnerId == -1)
			ColorChat(0, "Nobody answered right... [^4Answer ^1was:^3 %s^1]", Answer);

		ResetHidon();
		HidonVote();
		return;
	}

	set_dhudmessage(random_num(1, 255), random_num(1, 255), random_num(1, 255), -1.0, 0.30, 0, 1.0, 1.0);

	if (WinnerId != -1)
	{
		#if defined USE_NATIVES
		show_dhudmessage(0, "The Winner is %s!!!!!!!^nAnd he wins %d Points & %d Xp", get_player_name(WinnerId), Hidon[ChoosenHidonId][points], Hidon[ChoosenHidonId][xp]);
		#else
		show_dhudmessage(0, "The Winner is %s!!!!!!!", get_player_name(WinnerId));
		#endif

		if (ShowMsgOnce)
		{
			#if defined USE_NATIVES
			//add_user_xp(WinnerId, Hidon[ChoosenHidonId][xp]);
			add_user_points(WinnerId, Hidon[ChoosenHidonId][points]);
			ColorChat(0, "^1The Winner Is ^4%s ^1and he wins ^3%d ^4Points ^1& ^3%d ^4Xp ^1! [^4Answer ^1was:^3 %s^1]", WinnerName, Hidon[ChoosenHidonId][points], Hidon[ChoosenHidonId][xp], Answer);
			#else
			ColorChat(0, "^1The Winner Is ^4%s^1! [^4Answer ^1was:^3 %s^1]", WinnerName, Answer);
			#endif
			ShowMsgOnce = false;
		}
	}
	else
	{
		switch (ChoosenHidonId)
		{
			case 0: show_dhudmessage(0, "How much is %d + %d ?", num1, num2);
			case 1: show_dhudmessage(0, "The Name Of This Nosalgic Series Is???");
			case 2: show_dhudmessage(0, "The Name Of This Anime Series Is???");
			case 3: show_dhudmessage(0, "%s", TriviaQuestions[RndId][Quest]);
			case 4: show_dhudmessage(0, "Do you know where this logo belongs?^nType /logo in chat to view the logo.", LogoQuizQuestions[RndId][Quest]);
			case 5:
			{
				ML_timer = float(HidonTimer%10);
				show_dhudmessage(0, "(%d Letters | Next help in: %1.f)^nWhat is that Word ?^n%s", strlen(Answer), (ArraySize(MLWords_indexes) >= ML_UpdateAmount) ? ML_timer : 0.0, MLWord);
				ProccessMLWord();
			}
		}
	}

	HidonTimer--;
	set_task(1.0, "ShowHud", task_hud);
}

public ML_AddLetter()
{
	new rnd_num = random_num(0, ArraySize(MLWords_indexes)-1);
	new rnd_location = ArrayGetCell(MLWords_indexes, rnd_num);
	MLWord[rnd_location] = Answer[rnd_location];
	ArrayDeleteItem(MLWords_indexes, rnd_num);

	return rnd_location;
}

public ProccessMLWord()
{
	if (ML_timer == 0.0 && HidonTimer <= 50 && ArraySize(MLWords_indexes) > -1 && ArraySize(MLWords_indexes) >= ML_UpdateAmount)
	{
		for (new i = 0; i < ML_UpdateAmount; i++)
			ML_LastIds[i] = ML_AddLetter();

	}
	else
	{
		if (floatround(ML_timer) >= 6 && ArraySize(MLWords_indexes) >= ML_UpdateAmount)
		{
			for (new i = 0; i < ML_UpdateAmount; i++)
			{
				if (ML_LastIds[i] == -1) continue;

				if (floatround(ML_timer)%2 == 1)
					MLWord[ML_LastIds[i]] = '_';
				else
					MLWord[ML_LastIds[i]] = Answer[ML_LastIds[i]];
			}
		}
	}
}

public CheckAnswer(id)
{
	if (ChoosenHidonId == -1)
		return PLUGIN_CONTINUE;

	new Msg[192];
	read_argv(1, Msg, charsmax(Msg));

	if (equali(Msg, Answer) && WinnerId == -1)
	{
		WinnerId = id;
		get_user_name(WinnerId, WinnerName, charsmax(WinnerName));
		ShowMsgOnce = true;
		remove_task(task_hud);
		set_task(0.0, "ShowHud");
	}
	else if (ChoosenHidonId == 0 && WinnerId == -1)
		ColorChat(id, "^3Wrong Answer.");

	return PLUGIN_CONTINUE;
}

public ResetHidon()
{
	if (GameCount > 3)
		GameCount = 0;

	HidonWaitingTime = 600;
	HidonIsRunning = false;
	VoteTimer = 100;
	ChoosenHidonId = -1;
	StartHidonCD = 5;
	WinnerId = -1;
	WinnerName = "";
	ShowMsgOnce = false;
	HidonTimer = 60;
	RndId = -1;
	MLWord = "";
	sound[0] = '^0';
	remove_task(task_vote);
	remove_task(task_start_hidon);
	remove_task(task_hud);

	for (new i = 0; i < HidonimGamesCount; i++)
		Votes[i] = 0;

	for (new i = 0; i < get_maxplayers(); i++)
		isVoted[i] = false;
}

public LoadNostalgia()
{
	if (file_exists(NostalgiaCfgFile))
	{
		new text[128];
		new file = fopen(NostalgiaCfgFile, "rt");

		while (!feof(file))
		{
			fgets(file, text, charsmax(text));
			trim(text);
			if (text[0] == ';' || !text[0]) continue;

			parse(text, NostalgiaSongs[NostalgiaSongsLoaded][name], MAX_SONG_NAME-1, NostalgiaSongs[NostalgiaSongsLoaded][file_name], MAX_PATH_SIZE-1);
			replace_all(NostalgiaSongs[NostalgiaSongsLoaded][name], MAX_SONG_NAME-1, "_", " ");

			NostalgiaSongsLoaded++;
		}

		fclose(file)
	}
	else
		log_message("[ Hidonim ] (Error) Failed to load file nostalgia.txt.");
}

public LoadAnime()
{
	if (file_exists(AnimeCfgFile))
	{
		new text[128];
		new file = fopen(AnimeCfgFile, "rt");

		while (!feof(file))
		{
			fgets(file, text, charsmax(text));
			trim(text);
			if (text[0] == ';' || !text[0]) continue;

			parse(text, AnimeSongs[AnimeSongsLoaded][name], MAX_SONG_NAME-1, AnimeSongs[AnimeSongsLoaded][file_name], MAX_PATH_SIZE-1);
			replace_all(AnimeSongs[AnimeSongsLoaded][name], MAX_SONG_NAME-1, "_", " ");

			AnimeSongsLoaded++;
		}

		fclose(file)
	}
	else
		log_message("[ Hidonim ] (Error) Failed to load file anime.txt.");
}

public LoadTriviaQuestions()
{
	if (file_exists(TriviaCfgFile))
	{
		new text[128];
		new file = fopen(TriviaCfgFile, "rt");

		while (!feof(file))
		{
			fgets(file, text, charsmax(text));
			trim(text);
			remove_quotes(text);
			if (text[0] == ';' || !text[0]) continue;

			parse(text, TriviaQuestions[TriviaQuestionsLoaded][Quest], MAX_QUESTIONS_LENGTH-1, TriviaQuestions[TriviaQuestionsLoaded][Answr], MAX_ANSWER_LENGTH-1);
			replace_all(TriviaQuestions[TriviaQuestionsLoaded][Quest], MAX_QUESTIONS_LENGTH-1, "_", " ");
			replace_all(TriviaQuestions[TriviaQuestionsLoaded][Answr], MAX_ANSWER_LENGTH-1, "_", " ");

			TriviaQuestionsLoaded++;
		}

		fclose(file)
	}
	else
		log_message("[ Hidonim ] (Error) Failed to load file trivia.txt.");
}

public LoadLogoQuiz()
{
	if (file_exists(LogoQuizCfgFile))
	{
		new text[128];
		new file = fopen(LogoQuizCfgFile, "rt");

		while (!feof(file))
		{
			fgets(file, text, charsmax(text));
			trim(text);
			remove_quotes(text);
			if (text[0] == ';' || !text[0]) continue;

			parse(text, LogoQuizQuestions[LogoQuizQuestionsLoaded][Quest], MAX_QUESTIONS_LENGTH-1, LogoQuizQuestions[LogoQuizQuestionsLoaded][Answr], MAX_ANSWER_LENGTH-1);
			replace_all(LogoQuizQuestions[LogoQuizQuestionsLoaded][Answr], MAX_ANSWER_LENGTH-1, "_", " ");

			LogoQuizQuestionsLoaded++;
		}

		fclose(file)
	}
	else
		log_message("[ Hidonim ] (Error) Failed to load file logoquiz.txt.");
}

public LoadMissingLetter()
{
	if (file_exists(MissingLetterCfgFile))
	{
		new text[128];
		new file = fopen(MissingLetterCfgFile, "rt");

		while (!feof(file))
		{
			fgets(file, text, charsmax(text));
			trim(text);
			remove_quotes(text);
			if (text[0] == ';' || !text[0]) continue;

			copy(MLQuestions[MLQuestionsLoaded], MAX_ML_WORD_SIZE, text);

			MLQuestionsLoaded++;
		}

		fclose(file)
	}
	else
		log_message("[ Hidonim ] (Error) Failed to load file missingletter.txt.");
}

get_player_name(id)
{
	new szName[32];
	get_user_name(id, szName, charsmax(szName));

	return szName;
}

stock ColorChat( const client, const string[], any:... )
{
	new msg[ 191 ], players[ 32 ], count = 1;
	static len; len = formatex( msg, charsmax( msg ), "^4[^1 Top Deathrun ^4]^1 " );
	vformat( msg[ len ], charsmax( msg ) - len, string, 3 );

	if( client )  players[ 0 ] = client;
	else    get_players( players,count,"ch" );

	for ( new i = 0; i < count; i++ )
	{
		if( is_user_connected( players[ i ] ) )
		{
			message_begin( MSG_ONE_UNRELIABLE, get_user_msgid( "SayText" ), _, players[ i ] );
			write_byte( players[ i ] );
			write_string( msg );
			message_end( );
		}
	}
	return PLUGIN_HANDLED;
}