@echo off
setlocal enabledelayedexpansion
md "%~dp0out1_png" >nul 2>nul
md "%~dp0out2_png_crop" >nul 2>nul
md "%~dp0out3_png_double" >nul 2>nul
del /q "%~dp0out1_png\*.*" >nul 2>nul
del /q "%~dp0out2_png_crop\*.*" >nul 2>nul
del /q "%~dp0out3_png_double\*.*" >nul 2>nul
cd ImageMagick-7.0.8-11-portable-Q16-x64
::преобразуем pdf в png
FOR %%a IN (%~dp0in_pdf\*.pdf) DO (
 echo %%~na
 convert -density 600 -antialias "%%a" -resize 2048x "%~dp0out1_png\%%~na.png"
)
::обрезаем края
FOR %%a IN (%~dp0out1_png\*.png) DO (
 convert -crop 1462x1878+0+0 "%%a" "%~dp0out2_png_crop\%%~nxa"
)
::объединяем по две картинки
set le=0
FOR %%a IN (%~dp0out2_png_crop\*.png) DO (
 if "!le!"=="0" (
  set fr1=%%~na
  set le=1
 ) else (
  set le=0
  set fr2=%%~na
  convert "%~dp0out2_png_crop\!fr1!.png" "%~dp0out2_png_crop\!fr2!.png" +append "%~dp0out3_png_double\!fr1!_!fr2!.png"
  mogrify -extent 2924x1878 "%~dp0out3_png_double\!fr1!_!fr2!.png"
 )
)
if "!le!"=="1" (
 copy /Y "%~dp0out2_png_crop\!fr1!.png" "%~dp0out3_png_double\!fr1!.png" >nul 2>nul
 mogrify -extent 2924x1878 "%~dp0out3_png_double\!fr1!.png"
)
md f:\%date:~6,4%%date:~3,2%%date:~0,2% >nul 2>nul
xcopy /Y "%~dp0out3_png_double\*.png" "f:\%date:~6,4%%date:~3,2%%date:~0,2%\" >nul 2>nul