Neper_e_all_base.jl

# calculates Neper's constant e=2.71828.. in different bases
# approximation for m!,increasing m from on an
# Stirling: ln(n!) = 0.5*ln(2πn) + n(ln(n)-1)
# initial value of 4 until m! > 10^(n+1)
# ln(10) = 2.302585092994046, ln(2pi)=ln(6.283185307179586)
# Eulerin luvun e desimaalit ( n kpl)
# Juhani Kaukoranta 13.2.2022
function neper(n,b)
    # n digits, b base
    nro="0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
    cunei =["𒑲", "𒁹", "𒈫", "𒐈", "𒐉", "𒐊", "𒐋", "𒑂", "𒐍", "𒑆", "𒌋", "𒌋𒁹", "𒌋𒈫", "𒌋𒐈", "𒌋𒐉", "𒌋𒐊", "𒌋𒐋", "𒌋𒑂", "𒌋𒐍", "𒌋𒑆", "𒌋𒌋", "𒌋𒌋𒁹", "𒌋𒌋𒈫", "𒌋𒌋𒐈", "𒌋𒌋𒐉", "𒌋𒌋𒐊", "𒌋𒌋𒐋", "𒌋𒌋𒑂", "𒌋𒌋𒐍", "𒌋𒌋𒑆", "𒌍", "𒌍𒁹", "𒌍𒈫", "𒌍𒐈", "𒌍𒐉", "𒌍𒐊", "𒌍𒐋", "𒌍𒑂", "𒌍𒐍", "𒌍𒑆", "𒐏", "𒐏𒁹", "𒐏𒈫", "𒐏𒐈", "𒐏𒐉", "𒐏𒐊", "𒐏𒐋", "𒐏𒑂", "𒐏𒐍", "𒐏𒑆", "𒐐", "𒐐𒁹", "𒐐𒈫", "𒐐𒐈", "𒐐𒐉", "𒐐𒐊", "𒐐𒐋", "𒐐𒑂", "𒐐𒐍", "𒐐𒑆"]
    number = "" # numerot 10-järjestelmässä
    print("base ",b," : ",)
    m = 5 # laskentatermien määrä
    test = (n+1)*2.302585092994046
    while m*(log(m)-1.0) + 0.5*log(6.283185307179586*m) <= test
        m += 1
    end
    if b == 2
        print("10.",) # eka e:n numero, kokonaisosa
    elseif b == 20
        println("Maya :")
        println(Char(119522)," (kokonaisosa)")
    elseif b == 60
        print("Babylonian :")
        print(cunei[3],". ") # eka e:n numero, kokonaisosa
    else
        print("2.",) # eka e:n numero, kokonaisosa
    end

    coef = fill(1,m) # array coef contains only 1
    for i in 1:n
        carry = 0
        for j in reverse(2:m)
            temp = coef[j]*b + carry # in base:bin 2,oct 8,dec 10,hex 16
            carry = div(temp,j)
            coef[j] = temp - carry*j
        end # of digit generation
        number = number*string(carry)*" "
        if b==20 # MAYA numeral symbols
            println(Char(119520+carry)) # symbolit alekkain
        elseif b == 60 # Babylonian
            print(cunei[carry+1]," ",) # symbolit peräkkäin
        else
            print(nro[carry+1],) # symbolit peräkkäin
        end
    end
    println()
    if !(b==10)
         println(b,"-järjestelmän e:n numerot esitettynä 10-järjestelmässä:")
         println("2. ",number)
    end
end