Toon/lit Emision

Shader "Toon/Self-Illumin Lighted" {
    Properties {
        _Color ("Main Color", Color) = (0.5,0.5,0.5,1)
        _ColorE ("Main Emision", Color) = (0.5,0.5,0.5,1)
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _Ramp ("Toon Ramp (RGB)", 2D) = "gray" {}
        _Illum ("Illumin (A)", 2D) = "white" {}
        _EmissionLM ("Emission (Lightmapper)", Float) = 0
    }

    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200

CGPROGRAM
#pragma surface surf ToonRamp

sampler2D _Ramp;

// custom lighting function that uses a texture ramp based
// on angle between light direction and normal
#pragma lighting ToonRamp exclude_path:prepass
inline half4 LightingToonRamp (SurfaceOutput s, half3 lightDir, half atten)
{
    #ifndef USING_DIRECTIONAL_LIGHT
    lightDir = normalize(lightDir);
    #endif

    half d = dot (s.Normal, lightDir)*0.5 + 0.5;
    half3 ramp = tex2D (_Ramp, float2(d,d)).rgb;

    half4 c;
    c.rgb = s.Albedo * _LightColor0.rgb * ramp * (atten * 2);
    c.a = 1;
    return c;
}


sampler2D _MainTex;
sampler2D _Illum;
float4 _Color;
float4 _ColorE;

struct Input {
    float2 uv_MainTex : TEXCOORD0;
    float2 uv_Illum;
};

void surf (Input IN, inout SurfaceOutput o) {
    half4 tex = tex2D(_MainTex, IN.uv_MainTex);
    half4 c = tex * _Color;
    half4 e = tex * _ColorE;
    o.Albedo = c.rgb;
    o.Emission = e.rgb * tex2D(_Illum, IN.uv_Illum).rgb;
    o.Alpha = c.a;
}
ENDCG

    }

    Fallback "Self-Illumin/VertexLit"
}