DEFINE TEMP-TABLE ttOrder NO-UNDO LIKE-SEQUENTIAL Order
    FIELD OrderTotal AS DECIMAL
    FIELD CustName LIKE Customer.Name
    FIELD RepName LIKE SalesRep.RepName.

DEFINE TEMP-TABLE ttOline NO-UNDO LIKE-SEQUENTIAL OrderLine.

DEFINE TEMP-TABLE ttItem NO-UNDO
    FIELD ItemNum LIKE ITEM.ItemNum
    FIELD ItemName LIKE ITEM.ItemName
    FIELD Price LIKE ITEM.Price
    FIELD Weight LIKE ITEM.Weight
    FIELD OnHand LIKE ITEM.OnHand
    FIELD OnOrder LIKE ITEM.OnOrder
    INDEX ItemNum IS UNIQUE ItemNum.

/* dsOrder.i -- include file definition of DATASET dsOrder. */
DEFINE DATASET dsOrder FOR ttOrder, ttOline, ttItem
    DATA-RELATION OrderLine FOR ttOrder, ttOline
        RELATION-FIELDS (OrderNum, OrderNum)
    DATA-RELATION LineItem FOR ttOline, ttItem
        RELATION-FIELDS (ItemNum, ItemNum).

DEFINE VARIABLE hDSOrder AS HANDLE NO-UNDO.
hDSOrder = DATASET dsOrder:HANDLE.

/* fillDSOrder.p -- Test procedure for an Order Dataset */

DEFINE QUERY qOrder FOR Order, Customer, SalesRep.
DEFINE QUERY qItem FOR Item.
DEFINE DATA-SOURCE srcOrder FOR QUERY qOrder Order KEYS (OrderNum),
Customer KEYS (CustNum), SalesRep KEYS (SalesRep).
DEFINE DATA-SOURCE srcOline FOR OrderLine KEYS (OrderNum).
DEFINE DATA-SOURCE srcItem FOR Item KEYS (ItemNum).
QUERY qOrder:QUERY-PREPARE("FOR EACH Order WHERE Order.OrderNum < 10, " +
"FIRST Customer OF Order, FIRST SalesRep OF Order").

BUFFER ttOrder:ATTACH-DATA-SOURCE(DATA-SOURCE srcOrder:HANDLE,
"Customer.Name,CustName").
BUFFER ttOline:ATTACH-DATA-SOURCE(DATA-SOURCE srcOline:HANDLE).
BUFFER ttItem:ATTACH-DATA-SOURCE(DATA-SOURCE srcItem:HANDLE).
DATASET dsOrder:FILL().
BUFFER ttOrder:DETACH-DATA-SOURCE().
BUFFER ttOline:DETACH-DATA-SOURCE().
BUFFER ttItem:DETACH-DATA-SOURCE().

FOR EACH ttOrder:
DISPLAY
ttOrder.OrderNum
ttOrder.OrderDate
ttOrder.CustName FORMAT "X(15)"
ttOrder.RepName FORMAT "X(15)".
END.
FOR EACH ttOline:
DISPLAY
ttOline.OrderNum
ttOline.LineNum.
END.
FOR EACH ttItem:
DISPLAY ttItem.ItemNum ttItem.ItemName.
END.


FOR EACH ttOrder:
    DISPLAY
        ttOrder.OrderNum
        ttOrder.OrderDate
        ttOrder.CustName FORMAT "X(15)"
        ttOrder.RepName FORMAT "X(15)".
END.