GearSet.mac

#warning

Sub Main(string Param0, string Param1)
    /declare SlotNames[23] string outer
    /varset SlotNames[1] charm
    /varset SlotNames[2] leftear
    /varset SlotNames[3] head
    /varset SlotNames[4] face
    /varset SlotNames[5] rightear
    /varset SlotNames[6] neck
    /varset SlotNames[7] shoulder
    /varset SlotNames[8] arms
    /varset SlotNames[9] back
    /varset SlotNames[10] leftwrist
    /varset SlotNames[11] rightwrist
    /varset SlotNames[12] ranged
    /varset SlotNames[13] hands
    /varset SlotNames[14] mainhand
    /varset SlotNames[15] offhand
    /varset SlotNames[16] leftfinger
    /varset SlotNames[17] rightfinger
    /varset SlotNames[18] chest
    /varset SlotNames[19] legs
    /varset SlotNames[20] feet
    /varset SlotNames[21] waist
    /varset SlotNames[22] powersource
    /varset SlotNames[23] ammo
    /if (!${Plugin[MQ2Cecho].Name.Length}) {
        /squelch /plugin MQ2Cecho noauto
    }
    /if (!${Plugin[MQ2Cecho].Name.Length}) {
        /echo Need the MQ2CEcho plugin!
        /return
    }
    /if (!${Plugin[MQ2Exchange].Name.Length}) {
        /squelch /plugin MQ2Exchange noauto
    }
    /if (!${Plugin[MQ2Exchange].Name.Length}) {
        /cecho \arNeed the MQ2Exchange plugin!
        /return
    }
    /if (!${Defined[Param0]} || !${Defined[Param1]}) {
        /cecho \arUsage:  \ag/mac ${Macro.Name.Arg[1,.]} [load|save] SetName
        /return
    }
    /if (${Param0.Equal[save]} && ${Param1.Length}) {
        /call SaveGearSet ${Param1}
        /return
    }
    /if (${Param0.Equal[load]} && ${Param1.Length}) {
        /call LoadGearSet ${Param1}
        /return
    }
    /cecho \arUsage:  \ag/mac ${Macro.Name.Arg[1,.]} [load|save] SetName
    /return

Sub SaveGearSet(string GearSetName)
    /if (!${Defined[GearSetName]}) {
        /cecho \arNeed to provide a name for SaveGearSet!
        /return
    }
    /declare i int local
    /declare j int local
    /for i 1 to 23
        /varcalc j ${i}-1
        /mmoini "${Macro.Name.Arg[1,.]}_${EverQuest.Server}_${Me.CleanName}" "${GearSetName}" ${SlotNames[${i}]} "${Me.Inventory[${j}].Name}"
    /next i
    /cecho \atGear set \ag${GearSetName} \atsaved.
    /return

Sub LoadGearSet(string GearSetName)
    /if (!${Defined[GearSetName]}) {
        /cecho \arNeed to provide a name for LoadGearSet!
        /return
    }
    /declare s string local
    /declare i int local
    /declare j int local
    /varset s ${Ini[${Macro.Name.Arg[1,.]}_${EverQuest.Server}_${Me.CleanName},${GearSetName}]}
    /if (${s.Equal[NULL]}) {
        /cecho \ayNo gear set named \ar${GearSetName} \ayfound in \ag ${Macro.Name.Arg[1,.]}_${EverQuest.Server}_${Me.CleanName}.ini
        /return
    }
    /for i 1 to 23
        /varcalc j ${i}-1
        /varset s ${Ini[${Macro.Name.Arg[1,.]}_${EverQuest.Server}_${Me.CleanName},${GearSetName},${SlotNames[${i}]}]}
        /if (${s.NotEqual[NULL]} && (!${Me.Inventory[${j}].Name.Length} || ${Me.Inventory[${j}].Name.NotEqual[${s}]})) {
            /cecho \amSwapping in \au${s} \amto slot \ag${SlotNames[${i}]}
            /exchange "${s}" ${SlotNames[${i}]}
            /delay 1
        }
    /next i
    /cecho \atGear set \ag${GearSetName} \atactivated.
    /return