;Skrypt bY SabiK
;leczenie_mag
;Wersja 1.8
;Skrypt leczy bandazami, jesli ustawiono %lecz_bandazami na 1
;czaruje blesa, prota i reactiva
;Gdy masz wiecej niz 65hp ponizej maxhp lub mniej niz 25hp skrypt odtwarza dzwiek
;Jezeli %lecz_in_vas_mani jest ustawione na 1 to gdy mamy wiecej niz 40hp ponizej maxhp lub ponizej 30hp skrypt leczy In Vas Mani
;oraz medytuje jesli mamy mniej niz 10 many od max
;Jesli wpiszesz '.myj' skrypt zacznie myc bandaze
;Jesli ustawisz %skill na 1 skrypt bedzie robil evala, jesli na 2 - wiedze o zwierzetach, na atakowanym mobie
;Skrypt mozna wylaczyc wciskajac (ew. przytrzymujac przez chwile) klawisz '%key'

;U W A G A !!! USTAW PONIZSZE ZMIENNE PRZED WLACZENIEM SKRYPTU !!!
set %key insert                    ;Tu ustaw klawisz pod ktorym bedziesz mogl wylaczyc skrypt
set %sciezka D:\xxx.wav       ;Tu ustaw sciezke do dzwieku
set %skill 1                  ;Tu ustaw jaki skill ma robic [0-zaden, 1 - madrosc, 2 - wiedza o zwierzetach]
set %bles 1                   ;Tu ustaw czy skrypt ma czarowac blesa [1 - tak, 0 - nie]
set %prot 1                   ;Tu ustaw czy skrypt ma czarowac prota [1 - tak, 0 - nie]
set %reactiv 0                ;Tu ustaw czy skrypt ma czarowac reactiv armor [1 - tak, 0 - nie]
set %str 70                   ;Tu ustaw ponizej ilu sily skrypt ma zarzucac blesa
set %lecz_bandazami 0         ;Tu ustaw czy skrypt ma leczyc bandazami [1 - tak, 0 - nie]
set %lecz_in_vas_mani 1       ;Tu ustaw czy skrypt ma leczyc In Vas Mani gdy masz wiecej niz 40hp ponizej maxhp [1 - tak, 0 - nie]
;-------------------------------------------------------------------------------------

if %skill = 1
set %skillname madrosc
if %skill = 2
set %skillname wiedza , #spc , o , #spc , zwierzetach
set #sysmsgcol 63
event sysmessage Skrypt [leczenie_mag] odpalony (bY SabiK)
wait 1

start:
while #clilogged = 1 && #charghost <> yes
{
   gosub sprawdz_wylacz
   if H in #charstatus
      goto start
   gosub sprawdz_dzwiek
   if %bles = 1
      gosub sprawdz_bles
   if #sysmsg = unknown_command:_.myj
      gosub myj_bandaze
   if %skill = 1 || %skill = 2
      gosub skill
   if #hits < #maxhits && %lecz_bandazami = 1
      gosub leczenie
}
goto start

;---- Sub sprawdz_wylacz ----
sub sprawdz_wylacz
if #charghost = YES
{
   set #sysmsgcol 1080
   event sysmessage Jestes martwy. Wylaczono skrypt [leczenie]
   halt
}
onhotkey %key
{
   set #sysmsgcol 1080
   event sysmessage Wylaczono skrypt [leczenie]
   halt
}
return

;---- Sub sprawdz_dzwiek ----
sub sprawdz_dzwiek
if %sound = 1
{
   if %sound1 < #scnt2
      set %sound 0
}
if %sound <> 1
{
   if #hits < ( #maxhits - 65 ) || #hits <= 25
      gosub dzwiek
}
if %biegnie = 1
   gosub sprawdz_czy_biegnie
if %lecz_in_vas_mani = 1 && %biegnie <> 1
{
   if #hits < ( #maxhits - 45 ) || #hits <= 35
      gosub lecz_in_vas_mani
}
return

;---- Sub sprawdz_bles ----
sub sprawdz_bles
if #str = 0 || %bles <> 1
   return
if #str <= %str
   gosub bles
return

;---- Sub sprawdz_czy_biegnie ----
sub sprawdz_czy_biegnie
set %x #charposx
set %y #charposy
set %z #charposz
set %ch #chardir
wait 20
gosub sprawdz_wylacz
if #charposx = %x
{
   if #charposy = %y
   {
      if #charposz = %z
      {
         if #chardir = %ch
         set %biegnie 0
         return
      }
   }
}
return biegnie

;---- Sub dzwiek ----
sub dzwiek
sound %sciezka
if #hits < 45
{
   set #sysmsgcol 1080
   event sysmessage Masz #hits , hp!
}
set %sound 1
set %sound1 #scnt2 + 40
return

;---- Sub lecz_in_vas_mani ----
sub lecz_in_vas_mani
lecz_invas:
gosub sprawdz_wylacz
if #hits > ( #maxhits - 40 ) || #mana < 11
{
   if #mana < 11
   {
      set #sysmsgcol 1080
      event sysmessage Brakuje many! Skrypt nie bedzie leczyl In Vas Mani!
      set %lecz_in_vas_mani 0
   }
   return
}
gosub sprawdz_czy_biegnie
if #result = biegnie
{
   set %biegnie 1
   return
}
event macro 15 28
set %jrnl #jindex
set %licz #scnt2 + 60
repeat
gosub sprawdz_wylacz
if #jindex > %jrnl
{
   set %jrnl %jrnl + 1
   scanjournal %jrnl
   if s_koncentracje in #journal
      return
   if #journal = You_are_already_doing_something_else.
   {
      if #targcurs = 1
         key esc
      wait 20
      goto lecz_invas
   }
   if brakuje in #journal
   {
      sound %sciezka
      set #sysmsgcol 1080
      if #mana < 11
      event sysmessage Brakuje many! Skrypt nie bedzie leczyl In Vas Mani!
      else
      event sysmessage Brakuje Ci skladnikow! Skrypt nie bedzie leczyl In Vas Mani!
      set %lecz_in_vas_mani 0
      return
   }
}
if %licz < #scnt2
   goto lecz_invas
until #targcurs = 1
klik_lecz:
gosub sprawdz_wylacz
set %hpp #hits
event macro 23
set %licz #scnt2 + 30
repeat
gosub sprawdz_wylacz
if %licz < #scnt2
   goto klik_lecz
until #targcurs = 0
set %licz #scnt2 + 30
repeat
gosub sprawdz_wylacz
if %licz < #scnt2
   return
until #hits > %hpp
gosub medyt
return

;---- Sub leczenie ----
sub leczenie
leczenie:
finditem zlf C
if #findkind = -1
{
   sound %sciezka
   set #sysmsgcol 1080
   event sysmessage Nie znaleziono bandazy!
   set %nie_ma_bandazy %nie_ma_bandazy + 1
   set %nie_ma_bandazy_czas #scnt2 + 150
   if %nie_ma_bandazy >= 3
   {
      event sysmessage Trzy razy nie znaleziono bandazy! Wylaczono skrypt [leczenie]
      halt
   }
   wait 50
   return
}
if %nie_ma_bandazy_czas < #scnt2
   set %nie_ma_bandazy 0
set #lobjectid #findid
event macro 17
set %jrnl #jindex
set %licz #scnt2 + 15
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_bles
if #jindex > %jrnl
{
   set %jrnl %jrnl + 1
   scanjournal %jrnl
   if #journal = You_are_already_doing_something_else.
   {
      if #targcurs = 1
         key esc
      wait 30
      goto leczenie
   }
   if I_am_frozen in #journal || stoisz_za in #journal || nie_mozesz in #journal
      return
}
if %licz < #scnt2
   return
until #targcurs = 1
kliknij:
event macro 23
set %hp #hits + 3
set %jrnl #jindex
set %licz #scnt2 + 150
repeat
if ( %licz - 130 ) > #scnt2
{
   if #targcurs = 1
      goto kliknij
}
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_bles
if #jindex > %jrnl
{
   set %jrnl %jrnl + 1
   scanjournal %jrnl
}
until #journal = Wyleczyles_sie. || #journal = Przestales_sie_leczyc. || #journal = Wyleczylas_sie. || #journal = Przestalas_sie_leczyc. || #journal = Nie_udalo_ci_sie_wyleczyc_tej_osoby. || #journal = Anulowano. || Your_skill_in_Healing in #journal || Your_skill_in_Uzdrawian in #journal || #hits > %hp || %licz < #scnt2 || I_am_frozen in #journal || stoisz_za in #journal || nie_mozesz in #journal
if %skill = 1 || %skill = 2
   gosub skill
return

;---- Sub bles ----
sub bles
if #str = 0
   return
if %bles = 0
   goto prot
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_czy_biegnie
if #result = biegnie
{
   set %biegnie 1
   return
}
event macro 15 16
set %licz #scnt2 + 40
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
if %licz < #scnt2
   return
until #targcurs = 1
klik_bles:
event macro 23
set %licz #scnt2 + 3
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
if %licz < #scnt2
   goto klik_bles
until #targcurs = 0
wait 5
prot:
if %prot = 0
   goto reactiv
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_czy_biegnie
if #result = biegnie
{
   set %biegnie 1
   return
}
event macro 15 14
wait 45
reactiv:
if %reactiv = 0
   return
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_czy_biegnie
if #result = biegnie
{
   set %biegnie 1
   return
}
event macro 15 6
wait 50
return

;---- Sub myj_bandaze ----
sub myj_bandaze
set %Myl_bandaze 0
bandaze:
finditem amf C
if #findkind = -1
{
   set #sysmsgcol 88
   event sysmessage Skonczono myc bandaze!
   return
}
set #lobjectid #findid
event macro 17
set %licz #scnt2 + 5
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_bles
if %licz < #scnt2
  goto bandaze
until #targcurs = 1
klik_bandaze:
if %Myl_bandaze = 1
{
  event macro 22
  goto czekaj_bandaze
}
set #sysmsgcol 63
event sysmessage Wskaz gdzie maja byc myte bandaze.
set %licz #scnt2 + 50
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_bles
onhotkey ESC || #sysmsg =  Anulowano.
{
  if #targcurs = 0
  {
      set #sysmsgcol 1080
      event sysmessage Anulowano mycie bandazy!
      return
  }
}
if %licz < #scnt2
  goto klik_bandaze
until #targcurs = 0
set %Myl_bandaze 1
czekaj_bandaze:
set %Timer #scnt2 + 45
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_bles
if %Timer < #scnt2
  break
scanjournal 1
if Stoisz_za_daleko in #journal || W_tym_nie_umyjesz_bandaza in #journal || Musisz_wskazac_miejsce in #journal || Nie_widzisz_tego in #journal || Oddalil in #journal
{
   set %Myl_bandaze 0
   break
}
until Umyl in #journal
goto bandaze

;---- Sub skill ----
sub skill
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
finditem #enemyid
if #hits < #maxhits || #findkind <> 1 || #findid <> #enemyid || #targcurs = 1 || #enemyid = n/a || #enemyhits < 300 || #enemyhits = n/a || #finddist > 2 || #finddist = n/a || #findid = n/a
   return
set #ltargetkind 1
set #ltargetid #findid
event macro 1 0 .um %skillname
set %licz #scnt2 + 19
repeat
if %licz <= #scnt2
   return
until #targcurs = 1
wait 3
finditem #enemyid
if #findkind <> 1 || #findid <> #enemyid || #enemyid = n/a || #enemyhits < 300 || #enemyhits = n/a || #finddist > 2 || #finddist = n/a || #findid = n/a
{
   key esc
   return
}
event macro 22
return

;---- Sub medyt ----
sub medyt
medyt:
if #hits < ( #maxhits - 10 ) || #str <= %str || #mana > ( #maxmana - 10 )
   return
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
gosub sprawdz_czy_biegnie
if #result = biegnie
{
   set %biegnie 1
   return
}
event macro 13 46
set %licz #scnt2 + 20
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
if %licz < #scnt2
   goto medyt
until Rozpoczynasz_medytacje in #sysmsg
repeat
gosub sprawdz_wylacz
gosub sprawdz_dzwiek
if #sysmsg = Juz_medytujesz...
   goto koniec
until #mana = #maxmana || Konczysz_medytacje in #sysmsg || s_koncentracje in #sysmsg || Nie_mozesz_sie_skoncentrowac in #sysmsg || Nie_brakuje_Ci_many in #sysmsg || Juz_cos_robisz in #sysmsg || You_are_already_doing_something_else in #sysmsg || You_must_wait_to_perform_another_action in #sysmsg
return