python2-urllib3 PKGBUILD

# Maintainer:  Marcell Meszaros < marcell.meszaros AT runbox.eu >
# Contributor: Felix Yan <[email protected]>
# Contributor: Patrice Peterson <runiq at archlinux dot us>
# Contributor: Chris Brannon <[email protected]>
# Contributor: BorgHunter <borghunter at gmail dot com>
# Contributor: Drommer <[email protected]>

_pkgname=urllib3
pkgname=python2-urllib3
pkgver=1.26.12
pkgrel=1
pkgdesc='HTTP library with thread-safe connection pooling and file post support'
arch=('any')
url="https://pypi.org/project/urllib3"
license=('MIT')
depends=('python2')
makedepends=('python2-setuptools')
optdepends=('python2-pyopenssl: secure connection support'
            'python2-pysocks: SOCKS proxy support (deprecated)'
            'python-urllib3-doc: urllib3 documentation')
source=("https://github.com/${_pkgname}/${_pkgname}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('c7356205ca6c14df2f35d1d9cf18cd8a1981185b7dca13e1c3af91a214037c9d')

prepare() {
  cd ${_pkgname}-${pkgver}

  printf "Changing hashbangs in *.py files to refer to 'python2'... "
  sed -e '1s|#![ ]*/[a-zA-Z0-9./_ ]*python.*|#!/usr/bin/env python2|' \
      -i $(find . -name '*.py')
  echo 'done'

  printf "Changing 'setup.cfg': setting 'xfail_strict' from true to false... "
  sed -e '/^xfail_strict/c\xfail_strict = false' \
      -i 'setup.cfg'
  echo 'done'
}

build() {
  cd ${_pkgname}-${pkgver}
  python2 setup.py build
}

package() {
  cd ${_pkgname}-${pkgver}
  python2 setup.py install --root="${pkgdir}" --prefix='/usr' --optimize=1 --skip-build
  install -Dm 644 'LICENSE.txt' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}