;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   Allows the player to go upside-down.
;
;   - MarioE
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

!RAM = $58              ;       Change this

org $00DC45
        autoclean JSL y_speed
        NOP

org $00ED37
        autoclean JSL on_ceiling
        NOP #15

org $00EF65
        NOP #3
        autoclean JSL on_ground
        NOP #13

org $00F44D
        autoclean JML interact_mod

freecode

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

check_ceiling:
        LDA !RAM
        BNE .ud

        LDA $77
        AND #$08
        RTL

    .ud
        LDA $77
        AND #$04
        RTL

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

check_ground:
        LDA !RAM
        BNE .ud

        LDA $77
        AND #$04
        RTL

    .ud
        LDA $77
        AND #$08
        RTL

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

y_interact:
        dw $0008

        dw $0018,$001A,$0016,$0010,$0020,$0020
        dw $0018,$001A,$0016,$0010,$0020,$0020
        dw $0012,$001A,$000F,$0008,$0020,$0020
        dw $0012,$001A,$000F,$0008,$0020,$0020
        dw $001D,$0028,$0019,$0013,$0030,$0030
        dw $001D,$0028,$0019,$0013,$0030,$0030
        dw $001A,$0028,$0016,$0010,$0030,$0030
        dw $001A,$0028,$0016,$0010,$0030,$0030
        dw $0018,$0018,$0018,$0018,$0018,$0018

interact_mod:
        INX
        INX
        LDA !RAM
        REP #$20
        BNE .ud
        JML $00F451

.ud
        LDA $94
        CLC
        ADC $E830,x
        STA $9A

        LDA $96
        CLC
        ADC.l y_interact,x
        STA $98
        SEP #$20
        JML $00F461

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

on_ceiling:
        LDA !RAM
        BNE .ud

        LDA #$08
        TSB $77

        LDA $1DF9
        BNE +
        INC $1DF9

    +
        RTL

.ud
        LDA #$04
        TSB $77

        LDA $7D
        BPL +
        INC $13EF

    +
        STZ $72
        STZ $74
        STZ $1406
        STZ $140D
        STZ $1697
        STZ $18B5
        RTL

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

on_ground:
        LDA !RAM
        BNE .ud

        LDA #$04
        TSB $77

        LDA $7D
        BPL +
        INC $13EF

    +
        STZ $72
        STZ $74
        STZ $1406
        STZ $140D
        STZ $1697
        STZ $18B5
        RTL

    .ud
        LDA #$08
        TSB $77

        LDA $1DF9
        BNE +
        INC $1DF9

    +
        RTL

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

y_speed:
        LDA $18
        AND #$10
        BEQ +

        LDA #$0B
        STA $1DF9
        STZ $7D

        LDA !RAM
        EOR #$01
        STA !RAM

    +
        LDA !RAM
        REP #$20
        PHP
        BNE .ud
        LDA $7D
        BRA +

    .ud
        LDA $7D
        EOR #$FFFF
        INC

    +
        LSR
        LSR
        LSR
        LSR
        AND #$000F
        CMP #$0008
        BCC +
        ORA #$FFF0

    +
        PLP
        ADC $96
        STA $96
        SEP #$20
        RTL