;Player bullet handlers
;
;PBT located at $8D00
;First 64 bytes is PBT's FBT, all are filled with values indicating player
;bullet's LSB base location (multiples of 3 starting at $8D40
;Last 64*3 bytes is PBT's actual bullet data entries, described below, but
;is up to called routine's interpretation.
;
;FBT's location is in (pbtfreebullet). If bit 6 is ever set, then the FBT
;is full.
;
;Important note: Character's X and Y positions are not stored as normal. There
;are two bits of accuracy at the start so you're going to have to right-shift
;twice to get the actual X,Y positions.
;
;Y = YYYY YYSS , where S is subpixel data
;X = XXXX XXSS , where S is subpixel data
;

;Player bullet structure (3 bytes)
;+0 : YTTTTTTT, T=Timer 0-127, Y=1 if focused shot
;+1 : Y position if applicable
;+2 : X position if applicable

;The routine that is being called must be able to distinguish between
;unfocused and focused modes, since there won't be seperation at
;this stage of the routine call.
;
;Several things to edit.
;(1) PBTPlayerRoutineTables : How bullets are created. Below it are links.
;(2) PBTPlayerTypeTables : Types of bullets and how they move
;
;You can make creative use of the game timers to tell bullets apart
;(gametimer1) by creating only certain ones on certain slices of masked time.
;A good mask might be like %00000111 so you get 8 different time slices on
;each processing. Also pay attention to firing delays or you might not ever
;get a single bullet out.
;
;Other than that, good luck. You're gonna need it.


#DEFINE PBTSHOT(xofs,yofs,count) call PBTCreate \ .db xofs,yofs,count



PlayerShoot:
 ld a,(characterID)
 add a,a
 ld e,a
 ld d,0
 ld hl,PBTPlayerRoutineTables
 add hl,de
 ld e,(hl)
 inc hl
 ld d,(hl)
 ld hl,charweapon1
 bit isfocused,(iy+danmakuflags)
 jr z,_
 inc hl
 inc de
 inc de  ;if focused, charweapon2, and inc pointer to a focused standpoint
_:
 ld a,(hl)
 add a,a
 add a,a  ;x4 for weapon power thing
 ld L,a
 ld h,0
 add hl,de
 ld a,(hl)
 inc hl
 ld h,(hl)
 ld L,a
 jp (hl)

PBTMainDraw:
 xor a
 call PBTFillBulletDetails
 ld (itemp1),sp
 ld sp,$8D40
 ld a,64
PBTMainDrawLoop:
 ex af,af'
 dec sp
 pop af
 pop de
 cp $FF
 jp z,PBTMainDrawRet
 ld hl,(itemp2) ;unfocused
 bit 7,a
 jr z,_
 ld hl,(itemp3) ;focused
_:
 jp (hl)        ;routine being jumped to MUST keep B intact
PBTMainDrawRet:
 ex af,af'
 dec a
 jr nz,PBTMainDrawLoop
 ld sp,(itemp1)
 ret

PBTMainMove:
 ld a,4
 call PBTFillBulletDetails
 ld (itemp1),sp
 ld sp,$8D40
 ld a,64
PBTMainMoveLoop:
 ex af,af'
 dec sp
 pop af   ;A=tCCCCCCC, where t=type, C=counter
 pop de   ;E=Ypos ; D=Xpos (no accuracy bits, negative values may be used)
 cp $FF
 jp z,PBTMainMoveRet
 ld hl,(itemp2) ;unfocused
 bit 7,a
 jr z,_
 ld hl,(itemp3) ;focused
_:
 jp (hl)        ;routine being jumped to MUST keep B intact
PBTMainMoveRet:
 ex af,af'
 dec a
 jr nz,PBTMainMoveLoop
 ld sp,(itemp1)
 ret
PBTNoCreate:
 pop hl
 inc hl
 inc hl
 inc hl
 jp (hl)
PBTCreate: ;in: macro'd. Xofs,Yofs,Count
 ld hl,pbtfreebullet
 bit 6,(hl)
 jp nz,PBTNoCreate     ;stop routine if over 64 bullets
 ld a,(hl) ;1.read
 inc (hl)  ;2.increment
 ld L,a
 ld h,$8D
 ld L,(hl) ;got bullet position
 push hl
 pop ix
 ld de,(chary)
 srl e \ srl e ;y
 srl d \ srl d ;x
 pop hl
 ld a,d
 add a,(hl)
 inc hl
 ld (ix+2),a
 ld a,e
 add a,(hl)
 inc hl
 ld (ix+1),a
 ld a,(mdanmaku)  ;isfocused == bit 1. Need to shift to bit 7.
 rrca
 rrca
 and $80
 or (hl) ;combining new counter with focused mask
 inc hl
 ld (ix+0),a
 jp (hl)

PBTCreate2: ;D=Xofs,E=Yofs,A=Count
 push af
  ld hl,pbtfreebullet
  bit 6,(hl)
  jr z,_        ;stop routine if over 64 bullets. Jump past if no stop.
 pop af
 ret
_:
  ld a,(hl) ;1.read
  inc (hl)  ;2.increment
  ld L,a
  ld h,$8D
  ld L,(hl) ;got bullet position
  push hl
  pop ix
  ld a,(charx)
  srl a \ srl a
  add a,d
  ld (ix+2),a
  ld a,(chary)
  srl a \ srl a
  add a,e
  ld (ix+1),a
  ld a,(mdanmaku)
  rrca
  rrca
  and $80
 pop bc
 or b    ;combining masks for b7=focused, b0-b6=counter
 ld (ix+0),a
 ret



PBTDestroy: ;must be called in MOVE routine b4 SP is changed to save values
 ld hl,-3
 add hl,sp
 ld (hl),$FF
 ex de,hl
 ld hl,pbtfreebullet
 dec (hl)
 ld L,(hl)
 ld h,$8D
 ld (hl),e
 jp PBTMainMoveRet

PBTFillBulletDetails:
 ld c,a
 ld b,0   ;offset (0 if render cycle, 4 if move/collide cycle)
 ld a,(characterID)
 add a,a
 ld hl,PBTPlayerTypeTables
 add a,L
 ld L,a
 jr nc,$+3
 inc h
 ld e,(hl)
 inc hl
 ld d,(hl) ;got address to character's bullet table in DE
 ld a,(charweapon1)  ;unfocused weapon type
 add a,a  ;x2
 add a,a  ;x4
 add a,a  ;x8  ;weapon power type now available.
 add a,e
 ld L,a
 ld h,d
 jr nc,_
 inc h
_:
 add hl,bc
 ld a,(hl)
 inc hl
 ld h,(hl)
 ld L,a
 ld (itemp2),hl  ;unfocused weapon type in itemp2 variable
 ld a,(charweapon2)  ;focused weapon type
 add a,a  ;x2
 add a,a  ;x4
 add a,a  ;x8
 add a,2  ;+more offset for focused type
 add a,e
 ld L,a
 ld h,d
 jr nc,_
 inc h
_:
 add hl,bc
 ld a,(hl)
 inc hl
 ld h,(hl)
 ld L,a
 ld (itemp3),hl  ;focused weapon type in itemp3 variable
 ret

;-----------------------------------------------------------------------------
;PLAYER BULLET CREATION TABLES
;


PBTPlayerRoutineTables:
.dw PBTPRT00  ;Devblock  (ChID0) DO NOT CHANGE THESE ENTRIES
.dw PBTPRT01  ;Iambian   (ChID1)
.dw PBTPRT02  ;Netham45  (ChID2)
.dw PBTPRT03  ;???       (ChID3)
.dw PBTPRT04  ;???       (ChID4)
.dw PBTPRT05  ;???       (ChID5)
.dw PBTPRT06  ;Netham45L (ChID6)
.dw PBTPRT07  ;???       (ChID7)

PBTPRT00:  ;Devblock  (ChID0)
.dw DevBlockUnfPwr1   ;direct links to the routines that is about to be used
.dw DevBlockFocPwr1
.dw DevBlockUnfPwr2   ;direct links to the routines that is about to be used
.dw DevBlockFocPwr2
PBTPRT01:  ;Iambian   (ChID1)
.dw TestRoutineUnFocPwr1
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2
PBTPRT02:  ;Netham45  (ChID2)
.dw TestRoutineUnFocPwr1
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2
PBTPRT03:  ;???       (ChID3)
.dw TestRoutineUnFocPwr1
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2
PBTPRT04:  ;???       (ChID4)
.dw TestRoutineUnFocPwr1
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2
PBTPRT05:  ;Nanami    (ChID5)
.dw TestRoutineUnFocPwr1
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2
PBTPRT06:  ;Netham45L (ChID6)
.dw ShotHyperdrive
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2
PBTPRT07:  ;???       (ChID7)
.dw TestRoutineUnFocPwr1
.dw TestRoutineFocusPwr1
.dw TestRoutineUnFocPwr2
.dw TestRoutineFocusPwr2


;-----------------------------------------------------------------------------
;PLAYER BULLET RENDER/MOVE/COLLISION TABLES
;

PBTPlayerTypeTables:
.dw PBTPTT00  ;Devblock  (ChID0) DO NOT CHANGE THESE ENTRIES
.dw PBTPTT01  ;Iambian   (ChID1)
.dw PBTPTT02  ;Netham45  (ChID2)
.dw PBTPTT03  ;???       (ChID3)
.dw PBTPTT04  ;???       (ChID4)
.dw PBTPTT05  ;Nanami    (ChID5)
.dw PBTPTT06  ;Netham45L (ChID6)
.dw PBTPTT07  ;???       (ChID7)

;SO FAR EVERY ENTRY IN THIS TABLE IS DUMMY ENTRIES. FILL IN WITH ACTUAL
;DATA CONNECTED TO ASSEMBLY ROUTINES WHENEVER YOU ARE READY TO CODE THIS
;HORRIBLE MESS.
PBTPTT00:         ;Devblock  (ChID0)
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT01:         ;Iambian   (ChID1)
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT02:         ;Netham45  (ChID2)
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT03:         ;???       (ChID3)
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT04:         ;???       (ChID4)
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT05:         ;Nanami    (ChID5)PB00MoveCollide: ;dummy routine
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT06:         ;Netham45L (ChID6)
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove
PBTPTT07:         ;???       (ChID7)PB00Draw         ;dummy routine
.dw PBTShot00Draw ;-Unfocused shot power 1 render
.dw PBTShot00Draw ;-Focused   shot power 1 render
.dw PBTShot00Move ;-Unfocused shot power 1 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 1 move/collide/remove
.dw PBTShot00Draw ;-Unfocused shot power 2 render
.dw PBTShot00Draw ;-Focused   shot power 2 render
.dw PBTShot00Move ;-Unfocused shot power 2 move/collide/remove
.dw PBTShot00Move ;-Focused   shot power 2 move/collide/remove

;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

;=============================================================================
;CHARACTER FIRING CODE (what happens when you push the fire button)
;

DevBlockUnfPwr1:  ;These routines pretty much all do the same thing
TestRoutineUnFocPwr1:
TestRoutineUnFocPwr2:
DevBlockUnfPwr2:
;This routine fires a single centered shot on even cycles and
;two side shots on odd cycles, every other game cycle
 ld hl,firedelay
 dec (hl)
 ret nz
 ld (hl),2  ;FIRE DELAY FOR STANDARD SHOT IS TWO
 ld hl,charweapondat
 inc (hl)
 bit 0,(hl)  ;check to see if even or odd. Using it to alternate bullet sets
 ld hl,(chary)
 jp z,_      ;jump to two side bullets thing
 PBTSHOT(3,-1,0) ;xofs,yofs,cnt. centered bullet
 ret
_:
 PBTSHOT(0,-1,0) ;left side
 PBTSHOT(6,-1,0) ;right side
 ret

DevBlockFocPwr1:  ;Again, these routines all pretty much do the same thing
DevBlockFocPwr2:
TestRoutineFocusPwr1:
TestRoutineFocusPwr2:
;This routine fires two centered shots every game cycle
;
 ld hl,firedelay
 dec (hl)
 ret nz
 ld (hl),1  ;ONE GAME CYCLE. THIS CYCLING PROBABLY ISN'T NEEDED THO.
 PBTSHOT(2,-1,0) ;left center
 PBTSHOT(4,-1,0) ;right center
 ret


ShotHyperdrive:
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 PBTSHOT(3,-1,0)
 ret
;=============================================================================
;BULLET RENDERING CODE (cycle 2)
;

PBTShot00Draw:    ;standard 2x3 bullet
;E=Y D=X normalized (00yy yyyy,00xx xxxx)
 ld c,d    ;keeping a backup of C for later screen merriment :)
 ex de,hl  ;HL=00xxxxxx 00yyyyyy
 sla h
 sla h     ;HL=xxxxxx00 00yyyyyy
 xor a
 add hl,hl
 rla
 add hl,hl
 rla
 add hl,hl ;HL=xxx0000y yyyyy000 A=00000xxx (after next instruction)
 rla
 or L
 ld L,a
 ld a,h
 and %00000001
 or  %10000000
 ld h,a         ;HL=address get. 99ccs. Not the best but filters out bad coord
 ld a,c         ;saved X
 ld b,7
 and b
 xor b          ;checking to see if xxx=7 (straddling bullet)
 jr z,_  ;skip to special case bullets straddling the 8 bit boundary
 xor b
 add a,$20 ;bullet2x2 table, except we're drawing 2x3's
 ld d,$40
 ld e,a
 ld a,(de)
 ld c,a
 ld de,8
 ld a,(hl)
 or c
 ld (hl),a
 add hl,de
 ld a,(hl)
 or c
 ld (hl),a
 add hl,de
 ld a,(hl)
 or c
 ld (hl),a
 jp PBTMainDrawRet     ;go back to main loop
_:
 ld de,7
 set 0,(hl) \ inc hl \ set 7,(hl) \ add hl,de
 set 0,(hl) \ inc hl \ set 7,(hl) \ add hl,de
 set 0,(hl) \ inc hl \ set 7,(hl)
 jp PBTMainDrawRet


;=============================================================================
;BULLET MOVEMENT/COLLISION CODE (cycle 5)
;

PBTShot00Move:    ;standard move by however manieth.
;E=Y D=X
 inc e \ inc d           ;modify for collision routine
 ld ix,PBTShot00MoveCont ;return address for collision routine
 jp SmallBulletCollision ;IN: DE=XY,
PBTShot00MoveCont:
 dec e \ dec d     ;unmodify from collision routine
 ld a,-3           ;Move the Y direction up by 3 pixels
 add a,e           ;
 bit 7,a           ;
 jp nz,PBTDestroy  ;But if it went above the top (carry), then kill the bullet
 ld e,a            ;Else store the result back to E and wait for the push
 push de           ;save result of movement

;********************************
;If you needed to modify the counter, you will need the following code.
;AND DON'T FORGET TO PRESERVE BIT 7 OF L SINCE THAT IS THE FOCUSED FLAG.
 dec sp \ pop hl   ;ENTER CODE
 inc L
 ld a,L
 and %01111111
 cp 10
 jr nz,_
 push hl \ inc sp  ;EXIT CODE
 pop de            ;back to the way it was...
 jp PBTDestroy     ;and get rid of the bullet.
_:
 push hl \ inc sp  ;EXIT CODE
;********************************
 pop de            ;then advance SP so the bullet table handler can continue
 jp PBTMainMoveRet ;stack unavailable


SmallBulletCollision: ;E=Y D=X (bullet)
 ld hl,$8E01 ;starting off with byte needed to see if anything is there
 ld bc,$0A08 ;ten enemies, using C as a constant for adjustments
SmallBulletCollisionLoop:
 xor a
 cp (hl)
 jr z,SmallBulletCollisionSkip
 inc L
 inc L
 inc L  ;position Y
 ld a,(hl)
 sub e   ;bY-eY. 10-12. Carry means no collide
 jr nc,SmallBulletCollisionSkipY
 add a,c
 jr nc,SmallBulletCollisionSkipY
 inc L
 ld a,(hl) ;position X
 sub d   ;same deal as above. Skipping comments.
 jr nc,SmallBulletCollisionSkipX
 add a,c    ;
 jr nc,SmallBulletCollisionSkipX
;Collision happened. We may trash this bullet entry now via calling.
 ld c,1  ;BASE WEAPON POWER
 call DamageEnemy
 jp PBTDestroy
SmallBulletCollisionSkip:
 ld a,20
 jp _
SmallBulletCollisionSkipY:
 ld a,17
 jp _
SmallBulletCollisionSkipX:
 ld a,16
_:
 add a,L
 ld L,a
 djnz SmallBulletCollisionLoop
SmallBulletCollisionBossCheck:

 xor a
 cp (hl)
 jp z,SmallBulletCollideReturn
 inc L
 inc L
 inc L  ;position Y
 ld a,(hl)
 sub e   ;bY-eY. 10-12. Carry means no collide
 jp nc,SmallBulletCollideReturn
 add a,c    ;(bY-eY)-8. (22-20)-8. Carry means CAN collide, else no collide
 jp nc,SmallBulletCollideReturn
 inc L
 ld a,(hl) ;position X
 sub d   ;same deal as above. Skipping comments.
 jp nc,SmallBulletCollideReturn
 add a,c    ;
 jp nc,SmallBulletCollideReturn
 ld c,1 ;BASE POWER
 call DamageBoss
 jp PBTDestroy
SmallBulletCollideReturn;
 jp (ix)

Add100ToScore:
 ld a,8
 ld (scoretime),a  ;resetting score timer
 ld de,100
 ld hl,(tempscore)
 add hl,de
 ld (tempscore),hl
 ld e,0
 ld hl,(tempscore+2)
 adc hl,de
 ld (tempscore+2),hl
 ret

DamageBoss:
 ld a,(charpower)
 add a,c ;base power
 ld hl,bossArmor
 sub (hl)
 jr nc,_
 xor a   ;cannot pierce that armor.
_:
 ld c,a
 ld b,0
 ld hl,(bossHP)
 sbc hl,bc
 jr nc,_
 ld hl,0  ;boss HP never go below 0. Check when script system is invoked
_:
 ld (bossHP),hl
 jp Add100ToScore

DamageEnemy:
 inc L
 ld a,(hl) ;enemyHP
 or a
 jp z,Add100ToScore    ;skip trying to kill enemy. Enemy is invincible.
 ld a,(charpower)
 add a,c
 ld c,a
 ld a,(hl) ;curhp-dmg
 sub c
 ld (hl),a
 jr z,$+4
 jp nc,Add100ToScore   ;enemy still alive. Don't destruct
 ld a,-5
 add a,L
 ld L,a
 ld (hl),$00 ;remove enemy. Might want to make a fancy explosion. Not now.
 jp Add100ToScore