Dolphin-root 17.12.3 pkgbuild

# Maintainer: David P. <[email protected]>
# Contributor: Antonio Rojas <arojas@archlinux,org>
# Contributor: Felix Yan <[email protected]>
# Contributor: Andrea Scarpino <[email protected]>
# Contributor: Pierre Schmitz <[email protected]>

_pkgname=dolphin
pkgname=dolphin-root
pkgver=17.12.3
pkgrel=1
pkgdesc="File Manager, patched to be able to run as root"
arch=('armv7h' 'i686' 'x86_64')
url="https://kde.org/applications/system/dolphin/"
license=(LGPL)
depends=(baloo-widgets knewstuff kio-extras kuiserver kcmutils kparts kinit)
makedepends=(extra-cmake-modules kdoctools python)
optdepends=('kde-cli-tools: for editing file type options' 'ffmpegthumbs: video thumbnails' 'kde-thumbnailer-odf: ODF thumbnails'
            'ruby: installing new service menus from KDE Store' 'kdegraphics-thumbnailers: PDF and PS thumbnails' 'konsole: terminal panel')
conflicts=('kdebase-dolphin<15.08' 'dolphin')
provides=(dolphin)
replaces=(kdebase-dolphin)
source=("https://download.kde.org/stable/applications/$pkgver/src/${_pkgname}-$pkgver.tar.xz"{,.sig}
        "https://gitlab.com/Megver83/kdebase-root-patches/raw/master/0001-Revert-Disallow-executing-Dolphin-as-root-on-Linux.patch"{,.sig})
sha512sums=('44cf8baaeead69dd5529ce7da96d78f507029fa47ac9ac50de9d77cb15335dd0b0e0c916f2cdd0d5cadc465e461115dbfd02c51af38d03da985d66bd22456136'
            'SKIP'
            'f96ce74603d868785cece5cec4a7dc57dd1b50c9423604382065235c8930c5679496cfb9e08b2956520e8205468caf2e36cdb0ad18738d3bf75fc5dfdba114ed'
            'SKIP')
validpgpkeys=('CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7' # Albert Astals Cid <[email protected]>
              'F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87' # Christoph Feck <[email protected]>
              '6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78' # David P.
)

prepare() {
  mkdir -p build
  cd $srcdir/${_pkgname}-$pkgver
  patch -p1 -i $srcdir/0001-Revert-Disallow-executing-Dolphin-as-root-on-Linux.patch
}

build() {
  cd build
  cmake ../${_pkgname}-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}