on *:TEXT:*:*:{
  if ($me == [UCT]Bot) {
    if ($nick isop $chan) {
      if ($regex($1,/[!@.]h(igh)?l(ight)?tag(s|z)?$/Si)) {
        msg # $iif($fline($chan,*[UCT]*,0,1) = 0,$tit(Hltag) $c1(No tags online), $tit(Hltag) $c2($remove($regsubex($str(.,$fline($chan,*[UCT]*,0,1)),/./g,$fline($chan,*[UCT]*,\n,1).text $+ $chr(32)), [UCT]Bot)))
      }
      if ($regex($1,/[!@.]set(web)?(site|forum(s|z)?)$/Si)) {
        writeini $qt($+($mircdir,UCT\Settings.ini)) Site site $2-
        msg # $tit(Site) $c1(The site has been set! Type) $c2(!site) $c1(to see it.)
      }
      if ($regex($1,/[!@.]setreq(uirement)?(s|z)?$/Si)) {
        writeini $qt($+($mircdir,UCT\Settings.ini)) Reqs reqs $2-
        msg # $tit(Reqs) $c1(The requirements have been set! Type) $c2(!reqs) $c1(to see them.)
      }
      if ($regex($1,/[!@.]setc(lan)?c(hat)?$/Si)) {
        writeini $qt($+($mircdir,UCT\Settings.ini)) Cc cc $2-
        msg # $tit(Clanchat) $c1(The clan chat has been set! Type) $c2(!cc) $c1(to see it.)
      }
      if ($regex($1,/^[!@.]inv(ite)/)) {
        invite $2 #
      }
      if ($regex($1,/^[+-].*/)) {
        if ($regex($1,/^([+-][mpi]+)+/)) {
          mode # $1
        }
        if ($regex($1,/^([+-][qaohv]+)+/)) {
          mode # $1 $2-
        }
        var %regex = /^([+-][beI]+)+/i
        if ($regex($1,%regex)) {
          who #
          var %B $count($1,b,e,I) + 1
          var %X 2
          while (%X <= %B) {
            var %Ban = %Ban $address($ [ $+ [ %X ] ],2)
            inc %X
          }
          mode # $1 %Ban
        }
      }

    }
    if ($regex($1,/[!@.]c(ount)?tag(s|z)?$/Si)) {
      $iif(@ isin $1,msg #,notice $nick) $tit(Counttag) $c1(There are currently) $c2($calc($fline($chan,*[UCT]*,0,1) - 1)) $c1(nicknames with the tag) $c2([UCT]) $c1(in them. (Not including me))
    }
    if ($regex($1,/[!@.](web)?(site|forum(s|z)?)$/Si)) {
      $iif(@ isin $1,msg #,notice $nick) $tit(Site) $c1(The site for) $c2(Uncontrollable) $c1(is) $c2($readini($qt($+($mircdir,UCT\Settings.ini)),Site,site))
    }
    if ($regex($1,/[!@.]req(uirement)?(s|z)?$/Si)) {
      $iif(@ isin $1,msg #,notice $nick) $tit(Reqs) $c1(The requirements for) $c2(Uncontrollable) $c1(are) $c2($readini($qt($+($mircdir,UCT\Settings.ini)),Reqs,reqs))
    }
    if ($regex($1,/[!@.]c(lan)?c(hat)?$/Si)) {
      $iif(@ isin $1,msg #,notice $nick) $tit(Clanchat) $c1(The clan chat for) $c2(Uncontrollable) $c1(is) $c2($readini($qt($+($mircdir,UCT\Settings.ini)),Cc,cc))
    }
  }
}