API tools faq
paste
Advertisement
IntergalacticApps

Make Windows 10 Great Again - stop Windows 10 spying!

IntergalacticApps
Jun 26th, 2017
1,524
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Batch 21.46 KB | None | 0 0
raw download clone embed print report
  1. @echo off
  2. setlocal EnableDelayedExpansion
  3.  
  4. ver | find "10." > nul
  5. if errorlevel 1 (
  6.     echo Your Windows version is not Windows 10... yet. Brace yourself, Windows 10 is coming^^!
  7.     pause
  8.     exit
  9. )
  10.  
  11. echo Make Windows 10 Great Again^^! Batch spyware and trash remover, v. 1.0.3 beta
  12. echo Optimized for October 2018 Update.
  13.  
  14. pause
  15.  
  16. echo.
  17. echo | set /p=Checking permissions...
  18. net session >nul 2>&1
  19. if errorlevel 1 (
  20.     echo Permission denied. Run this script as administrator.
  21.     pause
  22.     exit
  23. ) else (
  24.     echo OK.
  25.     timeout /t 1 > nul
  26. )
  27.  
  28. reg query "HKLM\Software\Microsoft\Windows NT\CurrentVersion" /v "ProductName" | findstr "LTSC LTSB" > nul
  29. if not errorlevel 1 (
  30.     set LTSC=1
  31. )
  32.  
  33. whoami /groups | find "Everyone" > nul
  34. if not errorlevel 1 (
  35.     set eng=1
  36. )
  37.  
  38. if not defined LTSC (
  39.     cls
  40.     echo Deleting trash apps...
  41.     powershell -Command "& {Get-AppxPackage -AllUsers *officehub* | Remove-AppxPackage;}"
  42.     powershell -Command "& {Get-AppxPackage -AllUsers *powerbi* | Remove-AppxPackage;}"
  43.     powershell -Command "& {Get-AppxPackage -AllUsers *oneconnect* | Remove-AppxPackage;}"
  44.     powershell -Command "& {Get-AppxPackage -AllUsers *solitaire* | Remove-AppxPackage;}"
  45.     powershell -Command "& {Get-AppxPackage -AllUsers *photoshopexpress* | Remove-AppxPackage;}"
  46.     powershell -Command "& {Get-AppxPackage -AllUsers *eclipsemanager* | Remove-AppxPackage;}"
  47.     powershell -Command "& {Get-AppxPackage -AllUsers *pandora* | Remove-AppxPackage;}"
  48.     powershell -Command "& {Get-AppxPackage -AllUsers *duolingo* | Remove-AppxPackage;}"
  49.     powershell -Command "& {Get-AppxPackage -AllUsers *candycrush* | Remove-AppxPackage;}"
  50.     powershell -Command "& {Get-AppxPackage -AllUsers *zunevideo* | Remove-AppxPackage;}"
  51.     powershell -Command "& {Get-AppxPackage -AllUsers *zunemusic* | Remove-AppxPackage;}"
  52.     powershell -Command "& {Get-AppxPackage -AllUsers *photos* | Remove-AppxPackage;}"
  53.     powershell -Command "& {Get-AppxPackage -AllUsers *gethelp* | Remove-AppxPackage;}"
  54.     powershell -Command "& {Get-AppxPackage -AllUsers *getstarted* | Remove-AppxPackage;}"
  55.     powershell -Command "& {Get-AppxPackage -AllUsers *windowsmaps* | Remove-AppxPackage;}"
  56.     powershell -Command "& {Get-AppxPackage -AllUsers *messaging* | Remove-AppxPackage;}"
  57.     powershell -Command "& {Get-AppxPackage -AllUsers *print3d* | Remove-AppxPackage;}"
  58.     powershell -Command "& {Get-AppxPackage -AllUsers *3dviewer* | Remove-AppxPackage;}"
  59.     powershell -Command "& {Get-AppxPackage -AllUsers *stickynotes* | Remove-AppxPackage;}"
  60.     powershell -Command "& {Get-AppxPackage -AllUsers *xbox* | Remove-AppxPackage;}"
  61.     powershell -Command "& {Get-AppxPackage -AllUsers *asphalt8* | Remove-AppxPackage;}"
  62.     powershell -Command "& {Get-AppxPackage -AllUsers *hiddencity* | Remove-AppxPackage;}"
  63.     powershell -Command "& {Get-AppxPackage -AllUsers *onenote* | Remove-AppxPackage;}"
  64.     powershell -Command "& {Get-AppxPackage -AllUsers *freshpaint* | Remove-AppxPackage;}"
  65.     powershell -Command "& {Get-AppxPackage -AllUsers *feedbackhub* | Remove-AppxPackage;}"
  66. )
  67.  
  68. cls
  69. echo Deleting spyware firewall rules...
  70. powershell -Command "& {Get-NetFirewallRule | Where { $_.Group -eq 'DiagTrack' } | Remove-NetFirewallRule;}"
  71. powershell -Command "& {Get-NetFirewallRule | Where { $_.DisplayGroup -eq 'Delivery Optimization' } | Remove-NetFirewallRule;}"
  72.  
  73. cls
  74. echo | set /p=Deleting OneDrive...
  75. taskkill /f /im OneDrive.exe > nul 2>&1
  76. if exist %SystemRoot%\System32\OneDriveSetup.exe (
  77.     start /wait %SystemRoot%\System32\OneDriveSetup.exe /uninstall
  78. ) else if exist %SystemRoot%\SysWOW64\OneDriveSetup.exe (
  79.     start /wait %SystemRoot%\SysWOW64\OneDriveSetup.exe /uninstall
  80. )
  81. rd "%UserProfile%\OneDrive" /q /s > nul 2>&1
  82. rd "%SystemDrive%\OneDriveTemp" /q /s > nul 2>&1
  83. rd "%LocalAppData%\Microsoft\OneDrive" /q /s > nul 2>&1
  84. rd "%ProgramData%\Microsoft OneDrive" /q /s > nul 2>&1
  85. reg delete "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > nul 2>&1
  86. reg delete "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > nul 2>&1
  87. reg delete "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run" /v "OneDrive" /f > nul 2>&1
  88. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\OneDrive" /v "DisableFileSyncNGSC" /t REG_DWORD /d 1 /f > nul
  89. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\OneDrive" /v "DisableFileSync" /t REG_DWORD /d 1 /f > nul
  90. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\OneDrive" /v "DisableLibrariesDefaultSaveToOneDrive" /t REG_DWORD /d 1 /f > nul
  91. reg add "HKCU\SOFTWARE\Microsoft\OneDrive" /v "DisablePersonalSync" /t REG_DWORD /d 1 /f > nul
  92. echo OK.
  93.  
  94. echo.
  95. echo Disabling spyware/unsafe services...
  96. set unsafe_services=^
  97.     DiagTrack,dmwappushservice,diagnosticshub.standardcollector.service,^
  98.     WerSvc,PcaSvc,DoSvc
  99. for %%i in (%unsafe_services%) do (
  100.     echo Current service: %%i
  101.     sc stop %%i > nul
  102.     sc config %%i start= disabled
  103. )
  104.  
  105. echo.
  106. echo Adding antispy firewall rules...
  107. set spy_apps=^
  108.     "Program Files\Microsoft Office\Office16\msoia.exe"^
  109.     "Program Files\Microsoft Office\root\Office16\msoia.exe"^
  110.     "Program Files (x86)\Microsoft Office\Office16\msoia.exe"^
  111.     "Program Files (x86)\Microsoft Office\root\Office16\msoia.exe"^
  112.     "Windows\System32\CompatTelRunner.exe"^
  113.     "Windows\System32\dmclient.exe"^
  114.     "Windows\System32\rundll32.exe"^
  115.     "Windows\System32\SIHClient.exe"^
  116.     "Windows\System32\smartscreen.exe"^
  117.     "Windows\System32\taskhostw.exe"^
  118.     "Windows\System32\wbem\WmiPrvSE.exe"^
  119.     "Windows\System32\WerFault.exe"^
  120.     "Windows\System32\wermgr.exe"^
  121.     "Windows\SystemApps\Microsoft.Windows.Cortana_cw5n1h2txyewy\SearchUI.exe"^
  122.     "Windows\SysWOW64\rundll32.exe"^
  123.     "Windows\SysWOW64\wbem\WmiPrvSE.exe"^
  124.     "Windows\SysWOW64\WerFault.exe"^
  125.     "Windows\SysWOW64\wermgr.exe"
  126. for %%i in (%spy_apps%) do (
  127.     set item=%%i
  128.     set file_path="%SystemDrive%\!item:~1!
  129.     if exist !file_path! (
  130.         echo !file_path! | find "SysWOW64" > nul
  131.         if errorlevel 1 (
  132.             set rule_name=%%~nxi_BLOCK
  133.         ) else (
  134.             set rule_name=%%~nxi-SysWOW64_BLOCK
  135.         )
  136.         netsh advfirewall firewall show rule !rule_name! > nul
  137.         if errorlevel 1 (
  138.             echo | set /p=!rule_name!
  139.             netsh advfirewall firewall add rule name=!rule_name! dir=out interface=any action=block program=!file_path! > nul
  140.             set frw_rule_added=1
  141.             echo [OK]
  142.         )
  143.     )
  144. )
  145. set spy_svc=WSearch
  146. netsh advfirewall firewall show rule %spy_svc%_BLOCK > nul
  147. if errorlevel 1 (
  148.     echo | set /p=%spy_svc%_BLOCK
  149.     netsh advfirewall firewall add rule name="%spy_svc%_BLOCK" dir=out interface=any action=block service=%spy_svc% > nul
  150.     set frw_rule_added=1
  151.     echo [OK]
  152. )
  153. if not defined frw_rule_added (
  154.     echo Antispy rules already present.
  155. )
  156.  
  157. echo.
  158. echo Blocking spyware domains...
  159. set spy_domains=^
  160.     nullroute,^
  161.     v10.vortex-win.data.microsoft.com,watson.telemetry.microsoft.com,^
  162.     settings-win.data.microsoft.com,ris.api.iris.microsoft.com,^
  163.     ars.smartscreen.microsoft.com,www.msftconnecttest.com,^
  164.     www.bing.com,c.bing.com,g.bing.com,appex.bing.com,^
  165.     statsfe1.ws.microsoft.com,statsfe2.ws.microsoft.com,^
  166.     statsfe1-df.ws.microsoft.com,statsfe2-df.ws.microsoft.com,^
  167.     ocos-office365-s2s.msedge.net,client-office365-tas.msedge.net,^
  168.     config.edge.skype.com,insights.notes.microsoft.com,^
  169.     iceprime_msnapp-iceprime-c2s.msedge.net,g.msn.com,^
  170.     nexus.officeapps.live.com,nexusrules.officeapps.live.com,^
  171.     cs.dds.microsoft.com,mobile.pipe.aria.microsoft.com
  172. set hosts=%SystemRoot%\System32\drivers\etc\hosts
  173. for %%i in (%spy_domains%) do (
  174.     find /c " %%i" %hosts% > nul
  175.     if errorlevel 1 (
  176.         echo %%i
  177.         echo 0.0.0.0 %%i>>%hosts%
  178.         set hosts_added=1
  179.     )
  180. )
  181. if not defined hosts_added (
  182.     echo Spyware domains already blocked.
  183. ) else (
  184.     echo.
  185.     echo | set /p=Flushing DNS cache
  186.     ipconfig /flushdns > nul
  187.     echo [OK]
  188. )
  189.  
  190. echo.
  191. echo Adding registry tweaks...
  192.  
  193. echo | set /p=Disable telemetry
  194. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection" /v "AllowTelemetry" /t REG_DWORD /d 0 /f > nul
  195. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection" /v "AllowTelemetry" /t REG_DWORD /d 0 /f > nul
  196. echo [OK]
  197.  
  198. echo | set /p=Disable Windows Customer Experience Improvement Program
  199. reg add "HKLM\SOFTWARE\Policies\Microsoft\SQMClient\Windows" /v "CEIPEnable" /t REG_DWORD /d 0 /f > nul
  200. reg add "HKLM\SOFTWARE\Policies\Microsoft\SQMClient" /v "CorporateSQMURL" /t REG_SZ /d "0.0.0.0" /f > nul
  201. echo [OK]
  202.  
  203. echo | set /p=Disable Application Telemetry
  204. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\AppCompat" /v "AITEnable" /t REG_DWORD /d 0 /f > nul
  205. echo [OK]
  206.  
  207. echo | set /p=Disable Advertising ID
  208. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d 0 /f > nul
  209. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d 0 /f > nul
  210. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\AdvertisingInfo" /v "DisabledByGroupPolicy" /t REG_DWORD /d 1 /f > nul
  211. echo [OK]
  212.  
  213. echo | set /p=Disable keylogger
  214. reg add "HKCU\SOFTWARE\Microsoft\InputPersonalization" /v "RestrictImplicitInkCollection" /t REG_DWORD /d 1 /f > nul
  215. reg add "HKCU\SOFTWARE\Microsoft\InputPersonalization" /v "RestrictImplicitTextCollection" /t REG_DWORD /d 1 /f > nul
  216. reg add "HKCU\SOFTWARE\Microsoft\InputPersonalization\TrainedDataStore" /v "HarvestContacts" /t REG_DWORD /d 0 /f > nul
  217. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\TabletPC" /v "PreventHandwritingDataSharing" /t REG_DWORD /d 1 /f > nul
  218. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\HandwritingErrorReports" /v "PreventHandwritingErrorReports" /t REG_DWORD /d 1 /f > nul
  219. echo [OK]
  220.  
  221. echo | set /p=Disable browser access to local language
  222. reg add "HKCU\Control Panel\International\User Profile" /v "HttpAcceptLanguageOptOut" /t REG_DWORD /d 1 /f > nul
  223. echo [OK]
  224.  
  225. echo | set /p=Disable SmartScreen
  226. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer" /v "SmartScreenEnabled" /t REG_SZ /d "Off" /f > nul
  227. reg add "HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Explorer" /v "SmartScreenEnabled" /t REG_SZ /d "Off" /f > nul
  228. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\AppHost" /v "EnableWebContentEvaluation" /t REG_DWORD /d 0 /f > nul
  229. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\AppHost" /v "EnableWebContentEvaluation" /t REG_DWORD /d 0 /f > nul
  230. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\System" /v "EnableSmartScreen" /t REG_DWORD /d 0 /f > nul
  231. echo [OK]
  232.  
  233. echo | set /p=Disable Cortana and web search
  234. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "AllowCortana" /t REG_DWORD /d 0 /f > nul
  235. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "AllowSearchToUseLocation" /t REG_DWORD /d 0 /f > nul
  236. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchPrivacy" /t REG_DWORD /d 3 /f > nul
  237. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb" /t REG_DWORD /d 0 /f > nul
  238. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "DisableWebSearch" /t REG_DWORD /d 1 /f > nul
  239. reg add "HKLM\SOFTWARE\Microsoft\PolicyManager\default\Experience\AllowCortana" /v "value" /t REG_DWORD /d 0 /f > nul
  240. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v "CortanaEnabled" /t REG_DWORD /d 0 /f > nul
  241. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v "BingSearchEnabled" /t REG_DWORD /d 0 /f > nul
  242. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v "CortanaEnabled" /t REG_DWORD /d 0 /f > nul
  243. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v "CanCortanaBeEnabled" /t REG_DWORD /d 0 /f > nul
  244. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v "DeviceHistoryEnabled" /t REG_DWORD /d 0 /f > nul
  245. echo [OK]
  246.  
  247. echo | set /p=Disable Windows Defender
  248. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender" /v "DisableAntiSpyware" /t REG_DWORD /d 1 /f > nul
  249. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender\Real-Time Protection" /v "DisableBehaviorMonitoring" /t REG_DWORD /d 1 /f > nul
  250. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender\Real-Time Protection" /v "DisableOnAccessProtection" /t REG_DWORD /d 1 /f > nul
  251. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender\Real-Time Protection" /v "DisableScanOnRealtimeEnable" /t REG_DWORD /d 1 /f > nul
  252. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender\Spynet" /v "SpyNetReporting" /t REG_DWORD /d 0 /f > nul
  253. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender\Spynet" /v "SubmitSamplesConsent" /t REG_DWORD /d 2 /f > nul
  254. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows Defender Security Center\Systray" /v "HideSystray" /t REG_DWORD /d 1 /f > nul
  255. reg add "HKLM\SOFTWARE\Policies\Microsoft\MRT" /v "DontOfferThroughWUAU" /t REG_DWORD /d 1 /f > nul
  256. reg add "HKLM\SOFTWARE\Policies\Microsoft\MRT" /v "DontReportInfectionInformation" /t REG_DWORD /d 1 /f > nul
  257. regsvr32 /s /u "%ProgramFiles%\Windows Defender\shellext.dll"
  258. taskkill /f /im MSASCuiL.exe > nul 2>&1
  259. reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "WindowsDefender" /f > nul 2>&1
  260. reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "SecurityHealth" /f > nul 2>&1
  261. echo [OK]
  262.  
  263. echo | set /p=Disable Delivery Optimization
  264. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\DeliveryOptimization" /v "SystemSettingsDownloadMode" /t REG_DWORD /d 0 /f > nul
  265. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\DeliveryOptimization\Config" /v "DODownloadMode" /t REG_DWORD /d 0 /f > nul
  266. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\DeliveryOptimization" /v "DODownloadMode" /t REG_DWORD /d 0 /f > nul
  267. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\DeliveryOptimization" /v "SystemSettingsDownloadMode" /t REG_DWORD /d 0 /f > nul
  268. echo [OK]
  269.  
  270. echo | set /p=Disable Program Compatibility Assistant
  271. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\AppCompat" /v "DisablePCA" /t REG_DWORD /d 1 /f > nul
  272. echo [OK]
  273.  
  274. echo | set /p=Disable Windows Error Reporting
  275. reg add "HKLM\SOFTWARE\Microsoft\Windows\Windows Error Reporting" /v "Disabled" /t REG_DWORD /d 1 /f > nul
  276. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Error Reporting" /v "Disabled" /t REG_DWORD /d 1 /f > nul
  277. echo [OK]
  278.  
  279. echo | set /p=Disable Windows Tips
  280. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\CloudContent" /v "DisableSoftLanding" /t REG_DWORD /d 1 /f > nul
  281. echo [OK]
  282.  
  283. echo | set /p=Disable Windows Consumer Features (App Suggestions on Start)
  284. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SystemPaneSuggestionsEnabled" /t REG_DWORD /d 0 /f > nul
  285. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\CloudContent" /v "DisableWindowsConsumerFeatures" /t REG_DWORD /d 1 /f > nul
  286. echo [OK]
  287.  
  288. echo | set /p=Disable "Get tips, tricks and suggestions as you use Windows"
  289. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SoftLandingEnabled" /t REG_DWORD /d 0 /f > nul
  290. echo [OK]
  291.  
  292. echo | set /p=Disable ads in File Explorer
  293. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "ShowSyncProviderNotifications" /t REG_DWORD /d 0 /f > nul
  294. echo [OK]
  295.  
  296. echo | set /p=Disable People Bar
  297. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\People" /v "PeopleBand" /t REG_DWORD /d 0 /f > nul
  298. echo [OK]
  299.  
  300. echo | set /p=Disable loggers
  301. reg add "HKLM\SYSTEM\ControlSet001\Control\WMI\AutoLogger\AutoLogger-Diagtrack-Listener" /v "Start" /t REG_DWORD /d 0 /f > nul
  302. reg add "HKLM\SYSTEM\CurrentControlSet\Control\WMI\AutoLogger\AutoLogger-Diagtrack-Listener" /v "Start" /t REG_DWORD /d 0 /f > nul
  303. reg add "HKLM\SYSTEM\CurrentControlSet\Control\WMI\AutoLogger\SQMLogger" /v "Start" /t REG_DWORD /d 0 /f > nul
  304. echo [OK]
  305.  
  306. echo | set /p=Disable Windows Feedback
  307. reg add "HKCU\SOFTWARE\Microsoft\Siuf\Rules" /v "NumberOfSIUFInPeriod" /t REG_DWORD /d 0 /f > nul
  308. reg add "HKCU\SOFTWARE\Microsoft\Siuf\Rules" /v "PeriodInNanoSeconds" /t REG_DWORD /d 0 /f > nul
  309. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection" /v "DoNotShowFeedbackNotifications" /t REG_DWORD /d 1 /f > nul
  310. echo [OK]
  311.  
  312. echo | set /p=Disable Microsoft Help feedback
  313. reg add "HKCU\SOFTWARE\Policies\Microsoft\Assistance\Client\1.0" /v "NoExplicitFeedback" /t REG_DWORD /d 1 /f > nul
  314. echo [OK]
  315.  
  316. echo | set /p=Disable feedback on write
  317. reg add "HKLM\SOFTWARE\Microsoft\Input\TIPC" /v "Enabled" /t REG_DWORD /d 0 /f > nul
  318. reg add "HKCU\SOFTWARE\Microsoft\Input\TIPC" /v "Enabled" /t REG_DWORD /d 0 /f > nul
  319. echo [OK]
  320.  
  321. echo | set /p=Disable Office 2016 telemetry
  322. reg add "HKCU\SOFTWARE\Policies\Microsoft\Office\16.0\osm" /v "Enablelogging" /t REG_DWORD /d 0 /f > nul
  323. reg add "HKCU\SOFTWARE\Policies\Microsoft\Office\16.0\osm" /v "EnableUpload" /t REG_DWORD /d 0 /f > nul
  324. echo [OK]
  325.  
  326. echo | set /p=Disable Office 2016 OneDrive Integration
  327. reg add "HKCU\SOFTWARE\Policies\Microsoft\office\16.0\Common\SignIn" /v "SignInOptions" /t REG_DWORD /d "3" /f > nul
  328. reg add "HKCU\SOFTWARE\Policies\Microsoft\office\Common\WebIntegration" /v "WebIntegrationEnabled" /t REG_DWORD /d "0" /f > nul
  329. echo [OK]
  330.  
  331. echo | set /p=Turn off "You have new apps that can open this type of file" alert
  332. reg add "HKLM\SOFTWARE\Policies\Microsoft\Windows\Explorer" /v "NoNewAppAlert" /t REG_DWORD /d 1 /f > nul
  333. echo [OK]
  334.  
  335. echo | set /p=Open File Explorer to This PC instead of Quick Access
  336. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "LaunchTo" /t REG_DWORD /d 1 /f > nul
  337. echo [OK]
  338.  
  339. echo | set /p=Show hidden files, folders and drives in File Explorer
  340. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Hidden" /t REG_DWORD /d 1 /f > nul
  341. echo [OK]
  342.  
  343. echo | set /p=Show file extensions in File Explorer
  344. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "HideFileExt" /t REG_DWORD /d 0 /f > nul
  345. echo [OK]
  346.  
  347. echo | set /p=Launch folder windows in a separate process
  348. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "SeparateProcess" /t REG_DWORD /d 1 /f > nul
  349. echo [OK]
  350.  
  351. echo | set /p=Auto-end non responsive tasks
  352. reg add "HKCU\Control Panel\Desktop" /v "AutoEndTasks" /t REG_SZ /d "1" /f > nul
  353. echo [OK]
  354.  
  355. echo | set /p=Maximize wallpaper quality
  356. reg add "HKCU\Control Panel\Desktop" /v "JPEGImportQuality" /t REG_DWORD /d 100 /f > nul
  357. echo [OK]
  358.  
  359. echo | set /p=Set icon cache size to 4096 KB
  360. reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer" /v "Max Cached Icons" /t REG_SZ /d "4096" /f > nul
  361. echo [OK]
  362.  
  363. echo | set /p=Remove 3D Objects from This PC
  364. reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\{0DB7E03F-FC29-4DC6-9020-FF41B59E513A}" /f > nul 2>&1
  365. reg delete "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Explorer\MyComputer\NameSpace\{0DB7E03F-FC29-4DC6-9020-FF41B59E513A}" /f > nul 2>&1
  366. echo [OK]
  367.  
  368. echo | set /p=Add Recycle Bin to Navigation Pane
  369. reg add "HKCU\SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}" /v "System.IsPinnedToNameSpaceTree" /t REG_DWORD /d 1 /f > nul
  370. echo [OK]
  371.  
  372. echo | set /p=Set "Do this for all current items" checkbox by default in the file operation conflict dialog
  373. reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\OperationStatusManager" /v "ConfirmationCheckBoxDoForAll" /t REG_DWORD /d 1 /f > nul
  374. echo [OK]
  375.  
  376. echo | set /p=Enable NTFS long paths
  377. reg add "HKLM\SYSTEM\CurrentControlSet\Policies" /v "LongPathsEnabled" /t REG_DWORD /d 1 /f > nul
  378. echo [OK]
  379.  
  380. echo.
  381. echo | set /p=Restarting Explorer...
  382. taskkill /f /im explorer.exe >nul & explorer.exe
  383. schtasks /delete /tn "CreateExplorerShellUnelevatedTask" /f > nul
  384. echo OK.
  385.  
  386.  
  387. echo.
  388. echo Deleting spyware tasks...
  389. set spy_tasks=^
  390.     "Microsoft\Office\OfficeTelemetryAgentFallBack2016"^
  391.     "Microsoft\Office\OfficeTelemetryAgentLogOn2016"^
  392.     "Microsoft\Windows\AppID\SmartScreenSpecific"^
  393.     "Microsoft\Windows\Application Experience\AitAgent"^
  394.     "Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser"^
  395.     "Microsoft\Windows\Application Experience\ProgramDataUpdater"^
  396.     "Microsoft\Windows\Autochk\Proxy"^
  397.     "Microsoft\Windows\Customer Experience Improvement Program\BthSQM"^
  398.     "Microsoft\Windows\Customer Experience Improvement Program\Consolidator"^
  399.     "Microsoft\Windows\Customer Experience Improvement Program\KernelCeipTask"^
  400.     "Microsoft\Windows\Customer Experience Improvement Program\UsbCeip"^
  401.     "Microsoft\Windows\DiskDiagnostic\Microsoft-Windows-DiskDiagnosticDataCollector"^
  402.     "Microsoft\Windows\Feedback\Siuf\DmClient"^
  403.     "Microsoft\Windows\Feedback\Siuf\DmClientOnScenarioDownload"^
  404.     "Microsoft\Windows\Windows Error Reporting\QueueReporting"^
  405.     "Microsoft\Windows\WindowsUpdate\sih"^
  406.     "Microsoft\Windows\WindowsUpdate\sihboot"
  407. set tasks_dir=%SystemRoot%\System32\Tasks
  408. for %%i in (%spy_tasks%) do (
  409.     schtasks /query /tn %%i > nul 2>&1
  410.     if not errorlevel 1 (
  411.         echo | set /p=%%i
  412.         schtasks /delete /tn %%i /f > nul
  413.         set item=%%i
  414.         set dir_path="%tasks_dir%\!item:~1!
  415.         mkdir !dir_path!
  416.         if defined eng (
  417.             icacls !dir_path! /deny "Everyone:(OI)(CI)W" > nul
  418.         )
  419.         set spy_task_deleted=1
  420.         echo  [OK]
  421.     )
  422. )
  423. if not defined spy_task_deleted (
  424.     echo Spyware tasks already deleted.
  425. )
  426.  
  427. set update_orchestrator_dir=%tasks_dir%\Microsoft\Windows\UpdateOrchestrator
  428. if not exist %update_orchestrator_dir%\Reboot\ (
  429.     echo.
  430.     echo | set /p=Prevent Windows 10 reboots after installing updates...
  431.     schtasks /delete /tn "Microsoft\Windows\UpdateOrchestrator\Reboot" /f > nul 2>&1
  432.     del %update_orchestrator_dir%\Reboot
  433.     mkdir %update_orchestrator_dir%\Reboot
  434.     if defined eng (
  435.         icacls %update_orchestrator_dir%\Reboot /deny "Everyone:(OI)(CI)W" > nul
  436.     )
  437.     echo OK.
  438. )
  439.  
  440. echo.
  441. echo Finished.
  442. pause
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!