wimlib-1.0.3/PKGBUILD

# Maintainer:  Eric Biggers <ebiggers3 at gmail dot com>

pkgname=wimlib
pkgver=1.0.3
pkgrel=1
pkgdesc="A library to extract, create, and modify WIM files"
arch=("i686" "x86_64")
url="http://sourceforge.net/projects/wimlib"
license=("GPL3")
depends=("openssl" "fuse" "libxml2" "ntfs-3g" "attr")
optdepends=("cdrkit: for making ISO image of Windows PE"
    "mtools: for making disk image of Windows PE"
    "syslinux: for making disk image of Windows PE"
    "cabextract: for extracting Windows PE from the WAIK"
    "ntfsprogs: for making NTFS filesystems")
checkdepends=("ntfsprogs")
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
        "http://pastebin.com/download.php?i=wci9wrzn")

build() {
    cd "$pkgname-$pkgver"
    patch -p1 -i '../download.php?i=wci9wrzn'
    ./configure --disable-verify-compression --with-libcrypto --with-fuse \
            --with-ntfs-3g --enable-xattr --prefix=/usr
    make
}

check() {
    cd "$pkgname-$pkgver"
    make check
}

package() {
    cd "$pkgname-$pkgver"
    make DESTDIR="$pkgdir" install
}
md5sums=('fe9676938640d5072001d5d0b15a7e52'
         '13dcd59fab005f7cf1157b959a5a0a31')