demo.zs

import crafttweaker.events.IEventManager;
import crafttweaker.event.BlockHarvestDropsEvent;
import crafttweaker.item.IItemStack;
import crafttweaker.item.WeightedItemStack;
import crafttweaker.block.IBlockPattern;
import crafttweaker.block.IBlock;
import crafttweaker.block.IBlockDefinition;
import crafttweaker.block.IBlockState;
import crafttweaker.world.IWorld;
import mods.ctutils.utils.Math;
import scripts.demo_statics as stats;

events.onBlockHarvestDrops(function(event as BlockHarvestDropsEvent)
{
  if(event.world.isRemote()) { return; }


  if(stats.leafLayers has event.block.definition)
  {
    event.drops = [] as WeightedItemStack[];
    if (stats.silkEvent(event) || stats.toolMatchEvent(event, "shears"))
    {
      event.addItem(stats.leafLayers[event.block.definition] * (event.block.meta + 1));
    }
    else if (stats.toolMatchEvent(event, "axe"))
    {
      for i in 0 to (event.block.meta + 1)
      {
        if(Math.random()  < (0.005 * event.fortuneLevel))
        {
          event.addItem(<minecraft:stick>);
        }
      }
    }
  }
  return;
});