/*--------------------------------------------------------------*/
/*-------                  Parameters                   --------*/
/*--------------------------------------------------------------*/

/* [DIMENSIONS] */

// Length (top to bottom)
length = 86;

// Width (left to right)
width = 57;

// Height (thickness)
height = 2;

// The radius of the curve for the corners (roundness)
round = 2;

// Makes the curves smooth
$fn = 20;

// This is how thick each piece will be
thick = 3;

/* [TEXT] */

// Logo name
writing = "mrmath3";

/*--------------------------------------------------------------*/
/*-------                     Code                      --------*/
/*--------------------------------------------------------------*/

/* [HIDDEN] */

fudge = .01; // to get difference command to work properly

/* [RENDER] */

3D();

/* [MODULES] */

module 3D() {
  difference() {
    linear_extrude(thick)
      curve() 2D();
    %translate([0, 0, thick / 2 + fudge])
    linear_extrude(thick / 2)
      text(writing, 8, halign = "center", valign = "center");
  } // end difference
} // end module

module 2D() {
  difference() {
    square([width, length]);
    strap_indent();
    translate([width - 1.35 + fudge * 2, 0, 0])
      strap_indent();
    finger_hole();
  } // end difference
} // end module

module strap_indent() {
  translate([-fudge, 33, 0])
    square([1.35, 21]);
} // end module

module finger_hole() {
  translate([-23.5 / 2 + width / 2, 0, 0])
    polygon(points=[[0,0],[5.5,27],[18,27],[23.5,0]]);
}

module curve() {
  offset(r = round) // add outer roundness
    offset(delta = -round) // make smaller
      offset(r = -round) // add innner roundness
        offset(delta = round) // make bigger
          children();
}