payon,163,204,5	script	新大陸附魔	4_DR_SOLDIER,{
	disable_items;
	mes "[新大陸附魔]";
	mes "你有沒有想過用洛克理奇硬幣硬幣購買一些違禁物品嗎？我可以讓你的違禁品更好。";
	next;
	.@reset = select( "讓他們變得更好？要怎麼做？", "附魔違禁物品", "重置違禁品附魔等級" ) - 2;
	if (.@reset == -1) {
		mes "[新大陸附魔]";
		mes "啊! 我們以前見過面? 我每天遇到這麼多人，我不記得他們所有人的面孔。讓我趕上你的速度吧。";
		next;
		mes "[新大陸附魔]";
		mes "我來讓你了解可以用洛克理奇硬幣硬幣購買的裝備，最多3個插槽用於裝甲和服裝，最多2個插槽用於配件。";
		next;
		mes "[新大陸附魔]";
		mes "我為每個插槽充電2個洛克理奇硬幣硬幣，用於附魔和重置。";
		next;
		mes "[新大陸附魔]";
		mes "哦，請注意這些違禁品很容易被破壞，特別是當它們被重置時。";
		close;
	}
	switch( select( "取消", "盔甲", "服裝", "附件（右槽）" ) ) {
	case 1:
		mes "[新大陸附魔]";
		mes "你很傻。";
		close;
	case 2:
		.@part = EQI_ARMOR;
		break;
	case 3:
		.@part = EQI_GARMENT;
		break;
	case 4:
		.@part = EQI_ACC_R;
		break;
	}
	.@equip_id = getequipid(.@part);
	switch( .@equip_id ) {
	case 15176:	//巡守隊外套 Vigilante_Suit
	case 15177:	//元素外袍 Elemental_Robe
	case 15178:	//黃金忍者外套 Golden_Ninja_Suit
	case 15179:	//礦工背心 Mine_Worker's_Vest
	case 15180:	//嬉皮摩登外袍 Hippie Clothes

	case 20820:	//元素斗篷 Elemental_Cape
	case 20821:	//黃金圍巾 Golden_Scarf
	case 20822:	//礦工背包 Mine_Worker's_Backpack

	case 28441:	//巡守隊徽章 Vigilante_Badge
	case 28442:	//嬉皮羽毛手鐲 Hippie_Feather
		break;
	case -1:
		mes "[新大陸附魔]";
		mes "你為什麼要浪費我的時間？先穿上你的裝備。";
		close;
	default:
		mes "[新大陸附魔]";
		mes "我不處理這樣的物品。";
		close;
	}
	.@refine = getequiprefinerycnt(.@part);
	setarray .@card[0], getequipcardid(.@part,0), getequipcardid(.@part,1), getequipcardid(.@part,2), getequipcardid(.@part,3);
	copyarray .@tmp_card[0], .@card[0], 4;
	if ((.@card[1] && callfunc("F_IsCharm",.@card[1]) == false) || (.@card[2] && callfunc("F_IsCharm",.@card[2]) == false) || (.@card[3] && callfunc("F_IsCharm",.@card[3]) == false)) {// armor enchant system custom check
		mes "[新大陸附魔]";
		mes "發生了一些錯誤。";
		close;
	}
	switch( .@reset ) {
	case TRUE:
		if (.@card[3] == 0) {
			mes "[新大陸附魔]";
			mes "它並不令人著迷。您希望我重置一下？";
			close;
		}
		mes "[新大陸附魔]";
		mes "哦，你真的想重置嗎？正如我之前告訴你的那樣，違禁品巡守隊徽章很容易被破壞。";
		if (select( "我稍後會回來。“，”讓我們這麼做。" ) == 1) {
			mes "[新大陸附魔]";
			mes "好吧，如果你改變主意，請回來。";
			close;
		}
		if (.@part == EQI_ACC_R)
			.@chance_of_breaking_on_reset = 45;
		else
			.@chance_of_breaking_on_reset = 30;
		.@card[1] = .@card[2] = .@card[3] = 0;
		break;
	case FALSE:
		switch( .@part ) {
		case EQI_ARMOR:
		case EQI_GARMENT:
			if (.@card[1] > 0) {
				mes "[新大陸附魔]";
				mes "這已經是魅力的最大限度。也許你應該重置它。";
				close;
			}
			if (.@card[3] == 0)
				.@enchant_slot = 3;
			else if (.@card[2] == 0)
				.@enchant_slot = 2;
			else
				.@enchant_slot = 1;
			if (.@refine >= 9) {
				setarray .@enchant_list[0],
					4701,	// Strength2
					4711,	// Inteligence2
					4721,	// Dexterity2
					4731,	// Agility2
					4892,	// Mdef5
					29026,	// Def20
					4940,	// Cricital3
					4762,	// Evasion6
					4832,	// Expert_Archer1
					4833,	// Expert_Archer2
					4834,	// Expert_Archer3
					4835,	// Expert_Archer4
					4863,	// Fatal1
					4864,	// Fatal2
					4865,	// Fatal3
					4866,	// Fatal4
					4812,	// Spell4
					4813,	// Spell3
					4814,	// Spell2
					4815,	// Spell1
					4869,	// Attack_Delay_1
					4872;	// Attack_Delay_2
			}
			else {
				setarray .@enchant_list[0],
					4700,	// Strength1
					4701,	// Strength2
					4710,	// Inteligence1
					4711,	// Inteligence2
					4720,	// Dexterity1
					4721,	// Dexterity2
					4730,	// Agility1
					4731,	// Agility2
					4786,	// Mdef2
					4892,	// Mdef5
					4893,	// Def15
					29026,	// Def20
					4926,	// Critical1
					4940,	// Critical3
					4860,	// Evasion3
					4762,	// Evasion6
					4832,	// Expert_Archer1
					4833,	// Expert_Archer2
					4863,	// Fatal1
					4864,	// Fatal2
					4814,	// Spell2
					4815;	// Spell1
			}
			break;
		case EQI_ACC_R:
			if (.@card[2] > 0) {
				mes "[新大陸附魔]";
				mes "這已經是魅力的最大限度。也許你應該重置它。";
				close;
			}
			if (.@card[3] == 0)
				.@enchant_slot = 3;
			else
				.@enchant_slot = 2;
			setarray .@enchant_list[0],
				4700,	// Strength1
				4701,	// Strength2
				4730,	// Agility1
				4731,	// Agility2
				4740,	// Vitality1
				4741,	// Vitality2
				4710,	// Inteligence1
				4711,	// Inteligence2
				4720,	// Dexterity1
				4721,	// Dexterity2
				4750,	// Luck1
				4751,	// Luck2
				4795,	// HP100
				4796,	// HP200
				4800,	// SP50
				4801,	// SP100
				4832,	// Expert_Archer1
				4815,	// Spell1
				4811,	// Fighting_Spirit1
				4869,	// Attack_Delay_1
				4863,	// Fatal1
				4807;	// Atk_Speed1
			break;
		default:
			mes "[新大陸附魔]";
			mes "發生了一些錯誤。";
			close;
		}
		.@card[ .@enchant_slot ] = .@enchant_list[ rand( getarraysize(.@enchant_list) ) ];	// unknown rates
		break;
	}
	if (countitem(25250) < 2) {
		mes "[新大陸附魔]";
		mes "我為這項服務收取2枚洛克理奇硬幣硬幣。把它們帶給我。";
		close;
	}
	delitem 25250,2;// Rock_Ridge_Coin

	// anti-hack
	if (callfunc("F_IsEquipIDHack", .@part, .@equip_id) || callfunc("F_IsEquipRefineHack", .@part, .@refine) || callfunc("F_IsEquipCardHack", .@part, .@tmp_card[0], .@tmp_card[1], .@tmp_card[2], .@tmp_card[3]))
		close;
	for (.@ei = 0; .@ei < 4; .@ei++) {
		.@OptId[.@ei] = getequiprandomoption(.EquipPosEN[.@SelectPos],.@ei,ROA_ID);
		.@OptVal[.@ei] = getequiprandomoption(.EquipPosEN[.@SelectPos],.@ei,ROA_VALUE);
		.@OptParam[.@ei] = getequiprandomoption(.EquipPosEN[.@SelectPos],.@ei,ROA_PARAM);
	}
	delequip .@part;
	if (rand(100) < .@chance_of_breaking_on_reset) {
		specialeffect2 EF_LORD;
		mes "[新大陸附魔]";
		mes "啊，結果並不好。";
		mes "好吧，只是我的運氣。";
		close;
	}
	specialeffect2 EF_REPAIRWEAPON;
	getitem3 .@equip_id,1,1,.@refine,0,.@card[0],.@card[1],.@card[2],.@card[3],.@OptId,.@OptVal,.@OptParam;
	mes "[新大陸附魔]";
	mes "完成。看看這個。";
	close;
OnInit:
	waitingroom strnpcinfo(0),0;
	end;
}