API tools faq
paste
Advertisement
Guest User

QTGMC for avs 2.60

a guest
Dec 22nd, 2016
147
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 79.30 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.345, by Vit, 2012, 2016 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.345s
  16. # - work with SMDegrain_KNLMeansCL now to process chroma too
  17. #
  18. # v3.343s
  19. # - edit in ChromaEdi
  20. # - others
  21. #
  22. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  23. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  24. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  25. #
  26. # v3.33s (mod) 2016 12 06
  27. # - Add TR2=4 and TR2=5
  28. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  29. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  30. #
  31. # v3.33s (mod) 2016 04 11
  32. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  33. # - others
  34. #
  35. # v3.33s (mod) 2016 01 19
  36. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  37. #
  38. # v3.33s (mod) 2015 10 23
  39. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  40. #
  41. # v3.33s (mod) 2015 9 10
  42. # - fix Multiple QTGMC Calls
  43. # - others fix
  44. #
  45. # v3.33s (mod) 2015 8 6
  46. # - some changes in bob to speed up
  47. #
  48. # v3.33s (mod) 2015 8 4
  49. # - fix bug in YUY2 with SourceMatch
  50. # - add slice=false to ditherpost to avoid artefacts
  51. #
  52. # v3.33s (mod)
  53. # - fix bob chroma
  54. # - work with new masktool2 for avs 2.60 in YUY2
  55. #
  56. # v3.33d (mod)
  57. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  58. # - optimized some mask handling a bit as originally suggested by Vit
  59. # - others
  60. #
  61. # v3.33
  62. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  63. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  64. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  65. # - Minor change to denoising
  66. #
  67. # v3.32
  68. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  69. # - Tweaked vector recalculation for shutter motion blur
  70. # - Changed defaults for TR2 when using source-match
  71. # - Minor bugfix with SLMode/SLRad on pass-through settings
  72. #
  73. # --- REQUIREMENTS ---
  74. #
  75. # Input colorspaces: YV12, YUY2, others as plugins supports
  76. #
  77. # Core plugins:
  78. #   MVTools2 (2.7.5.22 or above from pinterf https://github.com/pinterf/mvtools/releases)
  79. #   MaskTools v2 (2.0b1 or above)
  80. #   NNEDI3 (0.9.4.6 or above)
  81. #   RgTools
  82. #
  83. # Additional plugins:
  84. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  85. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  86. #   FFT3DFilter - if selected for noise processing
  87. #   dfttest (1.9.4 or above) - if selected for noise processing
  88. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  89. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  90. #   KNLMeansCL - if selected for noise processing
  91. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  92.  
  93.  
  94. # --- GETTING STARTED ---
  95. #
  96. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  97. # To use QTGMC write a script like this:
  98. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  99. #   QTGMC( Preset="Slow" )
  100. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  101. #
  102. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  103. #
  104. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  105. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  106. # The default preset is "Slower"
  107. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  108. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  109. #
  110. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  111. #   QTGMC( Preset="Slow", ShowSettings=true )
  112.  
  113.  
  114. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  115.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  116.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  117.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  118.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  119.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  120.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  121.                     int "DftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  122.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  123.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  124.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  125.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "lsbd", bool "lsb" )
  126. {
  127.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  128.  
  129.     # Temporary Warnings
  130.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  131.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  132.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  133.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  134.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  135.  
  136.     #---------------------------------------
  137.     # Presets
  138.     lsbd         = default( lsbd,    false)
  139.     lsb          = default( lsb,     false)
  140.     Str          = default( Str,      1.0 )
  141.     Amp          = default( Amp,   0.0625 )
  142.     TV_range     = default( TV_range, true)
  143.  
  144.     # Select presets / tuning
  145.     Preset = default( Preset, "Slower" )
  146.     pNum = (Preset == "Placebo"   ) ? 0 : \
  147.            (Preset == "Very Slow" ) ? 1 : \
  148.            (Preset == "Slower"    ) ? 2 : \
  149.            (Preset == "Slow"      ) ? 3 : \
  150.            (Preset == "Medium"    ) ? 4 : \
  151.            (Preset == "Fast"      ) ? 5 : \
  152.            (Preset == "Faster"    ) ? 6 : \
  153.            (Preset == "Very Fast" ) ? 7 : \
  154.            (Preset == "Super Fast") ? 8 : \
  155.            (Preset == "Ultra Fast") ? 9 : \
  156.            (Preset == "Draft"     ) ? 10 : 11
  157.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  158.  
  159.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  160.              (MatchPreset == "Placebo"   ) ? 0 : \
  161.              (MatchPreset == "Very Slow" ) ? 1 : \
  162.              (MatchPreset == "Slower"    ) ? 2 : \
  163.              (MatchPreset == "Slow"      ) ? 3 : \
  164.              (MatchPreset == "Medium"    ) ? 4 : \
  165.              (MatchPreset == "Fast"      ) ? 5 : \
  166.              (MatchPreset == "Faster"    ) ? 6 : \
  167.              (MatchPreset == "Very Fast" ) ? 7 : \
  168.              (MatchPreset == "Super Fast") ? 8 : \
  169.              (MatchPreset == "Ultra Fast") ? 9 : \
  170.              (MatchPreset == "Draft"     ) ? 10 : 11
  171.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  172.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  173.  
  174.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  175.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  176.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  177.              (MatchPreset2 == "Slower"    ) ? 2 : \
  178.              (MatchPreset2 == "Slow"      ) ? 3 : \
  179.              (MatchPreset2 == "Medium"    ) ? 4 : \
  180.              (MatchPreset2 == "Fast"      ) ? 5 : \
  181.              (MatchPreset2 == "Faster"    ) ? 6 : \
  182.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  183.              (MatchPreset2 == "Super Fast") ? 8 : \
  184.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  185.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  186.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  187.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  188.  
  189.     NoisePreset = default( NoisePreset, "Fast" )
  190.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  191.             (NoisePreset == "Slow"   ) ? 1 : \
  192.             (NoisePreset == "Medium" ) ? 2 : \
  193.             (NoisePreset == "Fast"   ) ? 3 : \
  194.             (NoisePreset == "Faster" ) ? 4 : 5
  195.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  196.  
  197.     Tuning = default( Tuning, "None" )
  198.     tNum = (Tuning == "None"  ) ? 0 : \
  199.            (Tuning == "DV-SD" ) ? 1 : \
  200.            (Tuning == "DV-HD" ) ? 2 : 3
  201.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  202.  
  203.     # Tunings only affect blocksize in this version
  204.     bs = Select( tNum,  16, 16, 32 )
  205.     bs2 = (bs >= 16) ? 32 : bs * 2
  206.  
  207.     #                                                               Very                                                        Very      Super      Ultra
  208.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  209.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  210.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  211.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  212.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  213.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  214.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  215.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  216.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  217.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  218.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  219.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  220.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  221.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  222.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  223.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  224.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  225.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  226.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  227.     bs = Blocksize
  228.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  229.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  230.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  231.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  232.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  233.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  234.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  235.  
  236.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  237.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  238.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  239.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  240.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  241.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  242.  
  243.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  244.     SourceMatch   = default( SourceMatch, 0 )
  245.     MatchNNSize   = NNSize
  246.     MatchNNeurons = NNeurons
  247.     MatchEdiMaxD  = EdiMaxD
  248.     MatchEdiQual  = EdiQual
  249.  
  250.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  251.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  252.     #                                                                    Very                                                        Very      Super     Ultra
  253.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  254.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  255.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  256.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  257.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  258.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  259.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  260.     MatchEdi = TempEdi
  261.  
  262.     #                                                          Very                                                        Very      Super     Ultra
  263.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  264.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  265.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  266.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  267.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  268.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  269.  
  270.  
  271.     #---------------------------------------
  272.     # Settings
  273.  
  274.     # Core and Interpolation defaults
  275.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  276.     RepChroma  = default( RepChroma,  true )
  277.     EdiThreads = default( EdiThreads, 0    )
  278.     ChromaEdi  = default( ChromaEdi,  ""   )
  279.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  280.     EdiQual    = (EdiMode == "NNEDI3" && EdiQual > 2 ) ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  281.  
  282.     # Source-match / lossless defaults
  283.     MatchTR1     = TR1
  284.     MatchTR2     = default( MatchTR2,     1   )
  285.     MatchEnhance = default( MatchEnhance, 0.5 )
  286.     Lossless     = default( Lossless,     0   )
  287.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  288.  
  289.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  290.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  291.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  292.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  293.     spatialSL  = (SLMode == 1 || SLMode == 3)
  294.     temporalSL = (SLMode == 2 || SLMode == 4)
  295.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  296.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  297.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  298.     Sbb        = (SMode == 0) ? 0 : Sbb
  299.     SOvs       = default( SOvs,   0   )
  300.     SVThin     = default( SVThin, 0.0 )
  301.  
  302.     # Noise processing settings
  303.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  304.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  305.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  306.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  307.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  308.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  309.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  310.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  311.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  312.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  313.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  314.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  315.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  316.     Sigma        = defined(Sigma)       ? Sigma : \
  317.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  318.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  319.     DftThreads   = default( DftThreads, EdiThreads )
  320.     ChromaNoise  = default( ChromaNoise, false )
  321.     ShowNoise    = default( ShowNoise, 0.0 )
  322.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  323.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  324.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  325.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  326.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  327.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  328.     totalRestore = GrainRestore + NoiseRestore
  329.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  330.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  331.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  332.  
  333.     # MVTools settings
  334.     SubPelInterp = default( SubPelInterp, 2     )
  335.     TrueMotion   = default( TrueMotion,   false )
  336.     GlobalMotion = default( GlobalMotion, true  )
  337.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  338.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  339.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  340.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  341.     DCT          = default( DCT,     0          )
  342.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  343.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  344.     ThSCD1       = default( ThSCD1,  180        )
  345.     ThSCD2       = default( ThSCD2,  98         )
  346.  
  347.     # Motion blur settings
  348.     FPSDivisor  = default( FPSDivisor, 1 )
  349.     ShutterBlur = default( ShutterBlur, 0 )
  350.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  351.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  352.     SBlurLimit  = default( SBlurLimit, 4 )
  353.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  354.  
  355.     # Miscellaneous
  356.     InputType      = default( InputType,     0        )
  357.     Border         = default( Border,        false    )
  358.     ShowSettings   = default( ShowSettings,  false    )
  359.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  360.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  361.     ForceTR        = default( ForceTR,       0        )
  362.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  363.     ReuseGlobals   = (PrevGlobals == "Reuse")
  364.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  365.     rgBlur         = (Precise) ? 11 : 12
  366.  
  367.     # Get maximum temporal radius needed
  368.     maxTR = (temporalSL)       ? SLRad : 0
  369.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  370.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  371.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  372.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  373.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  374.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  375.  
  376.  
  377.     #---------------------------------------
  378.     # Pre-Processing
  379.  
  380.     w = Input.Width()
  381.     h = Input.Height()
  382.     yuy2 = Input.IsYUY2()
  383.     epsilon = 0.0001
  384.  
  385.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  386.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  387.  
  388.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  389.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  390.     h = (Border) ? h+8 : h
  391.  
  392.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  393.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  394.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  395.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  396.     vpad = (vpad > 8) ? vpad : 8
  397.  
  398.  
  399.     #---------------------------------------
  400.     # Motion Analysis
  401.  
  402.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  403.     planarClip = yuy2 ? clip.converttoyv16() : clip
  404.  
  405.     # Bob the input as a starting point for motion search clip
  406.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  407.              (InputType == 1) ? planarClip : \
  408.                                 planarClip.Blur( 0,1 )
  409.  
  410.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  411.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  412.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  413.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  414.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  415.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  416.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  417.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  418.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  419.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  420.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  421.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  422.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  423.  
  424.     CMmt = ChromaMotion ? 3   :  1
  425.     CMts = ChromaMotion ? 255 :  0
  426.     CMrg = ChromaMotion ? 12  : -1
  427.  
  428.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  429.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  430.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  431.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  432.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  433.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  434.  
  435.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  436.     binomial0 = IsClip(srchClip) ? NOP() : \
  437.                 (TR0 == 0)       ? bobbed : \
  438.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  439.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  440.  
  441.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  442.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  443.  
  444.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  445.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  446.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  447.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  448.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  449.  
  450.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  451.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : NOP()
  452.     srchcheck   = IsClip(srchClip)
  453.     srchClip    = srchcheck         ? srchClip : \
  454.                   (SrchClipPP == 0) ? repair0 : \
  455.                   (SrchClipPP < 3)  ? spatialBlur : \
  456.                                       spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  457.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  458.     # Calculate forward and backward motion vectors from motion search clip
  459.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  460.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  461.     bVec5 = IsClip(bVec5) ? bVec5 : \
  462.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  463.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  464.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  465.     bVec4 = IsClip(bVec4) ? bVec4 : \
  466.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  467.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  468.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  469.     bVec3 = IsClip(bVec3) ? bVec3 : \
  470.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  471.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  472.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  473.     bVec2 = IsClip(bVec2) ? bVec2 : \
  474.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  475.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  476.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  477.     bVec1 = IsClip(bVec1) ? bVec1 : \
  478.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  479.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  480.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  481.     fVec1 = IsClip(fVec1) ? fVec1 : \
  482.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  483.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  484.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  485.     fVec2 = IsClip(fVec2) ? fVec2 : \
  486.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  487.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  488.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  489.     fVec3 = IsClip(fVec3) ? fVec3 : \
  490.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  491.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  492.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  493.     fVec4 = IsClip(fVec4) ? fVec4 : \
  494.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  495.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  496.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  497.     fVec5 = IsClip(fVec5) ? fVec5 : \
  498.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  499.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  500.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  501.  
  502.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  503.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  504.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  505.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  506.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  507.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  508.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  509.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  510.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  511.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  512.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  513.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  514.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  515.  
  516.  
  517.     #---------------------------------------
  518.     # Noise Processing
  519.  
  520.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  521.  
  522.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  523.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  524.                 (InputType > 0)     ? clip : \
  525.                                       clip.QTGMC_Bob( 0,1.0 )
  526.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.converttoyv16() : fullClip
  527.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  528.  
  529.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  530.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  531.                   (!DenoiseMC)        ? fullClip : \
  532.                   (NoiseTR == 0)      ? fullClip : \
  533.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  534.                                                     fullClip, \
  535.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  536.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  537.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  538.                                                     fullClip, \
  539.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  540.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  541.     noiseWindow = yuy2 && (Denoiser == "FFT3DFilter") && NoiseTR > 0 ? noiseWindow.ConvertToYUY2() : noiseWindow
  542.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  543.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=DftThreads, lsb=lsbd ) : \
  544.             (Denoiser == "KNLMeansCL")  ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU") : \
  545.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD )
  546.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  547.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.ConvertToYUY2() : dnWindow
  548.  
  549.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  550.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  551.     denoised = (NoiseProcess == 0) ? NOP() : \
  552.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  553.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  554.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  555.  
  556.     # >>>> Switch to planar YUY2 for noise bypass
  557.  
  558.     CNmt1   = ChromaNoise ? 3 : 1
  559.     CNmt2   = ChromaNoise ? 3 : 2
  560.     CNmt128 = ChromaNoise ? 3 : -128
  561.  
  562.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  563.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.converttoyv16() : denoised
  564.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  565.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  566.                  (InputType != 0)                           ? noise : \
  567.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  568.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  569.                                                               noise.DoubleWeave()
  570.     # Motion-compensated stabilization of generated noise
  571.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  572.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  573.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  574.  
  575.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  576.     innerClip = (NoiseProcess == 1) ? denoised : clip
  577.  
  578.  
  579.     #---------------------------------------
  580.     # Interpolation
  581.  
  582.     # >>>> Interleaved YUY2 for interpolation
  583.  
  584.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  585.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  586.  
  587.     # Create interpolated image as starting point for output
  588.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  589.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  590.  
  591.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  592.  
  593.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  594.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  595.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.ConvertToYV16()) :\
  596.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).ConvertToYV16()) : \
  597.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  598.                                                         mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend, U=2,V=2 ))
  599.  
  600.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  601.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  602.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  603.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  604.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  605.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  606.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  607.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  608.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  609.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  610.  
  611.  
  612.     #---------------------------------------
  613.     # Create basic output
  614.  
  615.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  616.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  617.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  618.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  619.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  620.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  621.     degrain1 = (TR1 > 0) && lsb ? degrain1.ditherpost(mode=6, slice=false) : degrain1
  622.     degrain2 = (TR1 > 1) && lsb ? degrain2.ditherpost(mode=6, slice=false) : degrain2
  623.  
  624.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  625.     binomial1 = (TR1 == 0) ? edi : \
  626.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  627.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  628.  
  629.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  630.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  631.  
  632.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  633.     match = (SourceMatch == 0) ? repair1 : \
  634.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  635.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  636.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  637.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  638.  
  639.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  640.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  641.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  642.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  643.  
  644.  
  645.     #---------------------------------------
  646.     # Resharpen / retouch output
  647.  
  648.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  649.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  650.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  651.     resharp   = (SMode == 0) ? lossed1 : \
  652.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  653.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  654.  
  655.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  656.     SVThinSc = SVThin * 6.0
  657.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  658.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  659.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  660.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  661.  
  662.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  663.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  664.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  665.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  666.  
  667.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  668.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  669.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  670.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  671.                                   backBlend1
  672.  
  673.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  674.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  675.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  676.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  677.  
  678.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  679.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  680.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  681.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  682.  
  683.     # Final light linear temporal smooth for denoising
  684.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  685.     stable  = (TR2 == 0) ? addNoise1 : \
  686.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  687.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  688.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  689.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  690.                            addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb )
  691.     stable  = (TR2 > 0) && lsb ? stable.ditherpost(mode=6, slice=false) : stable
  692.  
  693.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  694.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  695.  
  696.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  697.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  698.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  699.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  700.                                   repair2
  701.  
  702.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  703.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  704.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  705.  
  706.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  707.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  708.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  709.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  710.  
  711.  
  712.     #---------------------------------------
  713.     # Post-Processing
  714.  
  715.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  716.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  717.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  718.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  719.  
  720.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  721.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  722.     rBlockSize = BlockSize / rBlockDivide
  723.     rOverlap   = Overlap   / rBlockDivide
  724.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  725.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  726.     rBlockDivide = BlockSize / rBlockSize
  727.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  728.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  729.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  730.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  731.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  732.  
  733.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  734.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  735.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  736.  
  737.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  738.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  739.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  740.                    (SBlurLimit == 0)  ? sblur : \
  741.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  742.     # Reduce frame rate
  743.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  744.  
  745.     # Crop off temporary vertical padding
  746.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  747.     h = Border ? h-8 : h
  748.  
  749.     # Show output of choice + settings
  750.     # >>>> Restore YUY2 to interleaved
  751.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  752.     output = yuy2 ? output.ConvertToYUY2() : output
  753.     return (ShowSettings == false) ? output : \
  754.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  755.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  756.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  757.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  758.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  759.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  760.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  761.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  762.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  763.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  764.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  765.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  766.         Denoiser + "' | DftThreads=" + string(DftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  767.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  768.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  769.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  770.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  771.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  772.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  773.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  774. }
  775.  
  776.  
  777. #---------------------------------------
  778. # Helpers
  779.  
  780. # Same as Bob, but keeps the field order the same.
  781. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  782. {
  783.   ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  784.   h = Default(height, cp.Height)
  785.   w = cp.Width
  786.   shift = GetParity(cp) ? 0.25 : -0.25
  787.  
  788.   c420 = ssispmt ? Is420(cp) : IsYV12(cp)
  789.  
  790.   c420 ? cp.SeparateFields() : nop()
  791.  
  792.   oeven=c420 ? SelectEven() : nop()
  793.   oodd=c420 ? SelectOdd() : nop()
  794.  
  795.   even=c420 ? ssispmt ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  796.   odd=c420 ? ssispmt ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  797.  
  798.   evenChr=c420 ? Interleave(ssispmt ? oeven.ExtractU() : oeven.UToY8(), ssispmt ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  799.   oddChr=c420 ? Interleave(ssispmt ? oodd.ExtractU() : oodd.UToY8(), ssispmt ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  800.  
  801.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  802.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  803. }
  804.  
  805.  
  806. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  807. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  808. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  809.                             string "ChromaEdi" )
  810. {
  811.     # >>>> YUY2 is interleaved here
  812.  
  813.     ChromaEdi = default( ChromaEdi, "" )
  814.     CEed = (ChromaEdi == "")
  815.  
  816.     interp = (InputType == 1)            ? Input : \
  817.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  818.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  819.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  820.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  821.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  822.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  823.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  824.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  825.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  826.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  827.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.ConvertToYv16().Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  828.                                                            Input.Yadifmod2( mode=3 ) : \   
  829.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).ConvertToYv16(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  830.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  831.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  832.  
  833.     interpuv = (InputType == 1)        ? NOP() : \
  834.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  835.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  836.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  837.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  838.                                          NOP()
  839.  
  840.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  841. }
  842.  
  843.  
  844. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  845. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  846. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  847. {
  848.     # >>>> YUY2 is planar here
  849.     mtY =default( Y, 3 )
  850.     mtU =default( U, 1 )
  851.     mtV =default( V, 1 )
  852.     rgY = (mtY == 3) ? 20 : -1
  853.     rgU = (mtU == 3) ? 20 : -1
  854.     rgV = (mtV == 3) ? 20 : -1
  855.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  856. }
  857.  
  858. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  859. {
  860.     # >>>> YUY2 is planar here
  861.     mtY =default( Y, 3 )
  862.     mtU =default( U, 1 )
  863.     mtV =default( V, 1 )
  864.     rgY = (mtY == 3) ? 20 : -1
  865.     rgU = (mtU == 3) ? 20 : -1
  866.     rgV = (mtV == 3) ? 20 : -1
  867.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  868. }
  869.  
  870. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  871. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  872. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  873. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  874. {
  875.     # >>>> YUY2 is planar here
  876.  
  877.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  878.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  879.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  880.     Rep    = default( Rep,    1    )
  881.     Chroma = default( Chroma, true )
  882.     ed = (Rep < 10) ? Rep : Rep / 10
  883.     od = (Rep < 10) ? 0   : Rep % 10
  884.     RCrg  = Chroma ? 3 : 1
  885.     RCrgo = Chroma ? 3 : 2
  886.  
  887.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  888.  
  889.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  890.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  891.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  892.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  893.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  894.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  895.                                                                                                                      
  896.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  897.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  898.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  899.  
  900.     # Over-dilation - extra reflation up to about 1 pixel
  901.     choke1 = (od == 0)            ? choke1 : \
  902.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  903.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  904.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  905.  
  906.     # Areas of negative difference (similar to above)
  907.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  908.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  909.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  910.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  911.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  912.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  913.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  914.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  915.     choke2 = (od == 0)            ? choke2 : \
  916.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  917.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  918.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  919.  
  920.     # Combine above areas to find those areas of difference to restore
  921.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  922.  
  923.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  924. }
  925.  
  926.  
  927. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  928. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  929. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  930. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  931. {
  932.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  933.     ChromaNoise = default( ChromaNoise, false )
  934.     CNmt1 = ChromaNoise ? 3 : 1
  935.     origNoise = Input.SeparateFields()
  936.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  937.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  938.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  939.     random    = InterleavedClip.IsYUY2() ? random.converttoyv16() : random
  940.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  941.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  942.     return Interleave( origNoise, newNoise ).Weave()
  943. }
  944.  
  945.  
  946. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  947. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  948. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  949. {
  950.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  951.  
  952.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  953.  
  954.     # Weave the source fields and the "new" fields that have generated in the input
  955.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  956.     srcFields  = Source.IsYUY2() ? srcFields1.converttoyv16() : srcFields1
  957.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  958.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  959.  
  960.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  961.     vertMedian  = processed.VerticalCleaner( mode=1 )
  962.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  963.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  964.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  965.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  966.  
  967.     # Reweave final result
  968.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  969. }
  970.  
  971.  
  972. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  973. # the source without introducing shimmer. All other arguments defined in main script
  974. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  975.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  976.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  977.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  978.                                  float MatchEnhance, int EdiThreads, bool lsb )
  979. {
  980.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  981.     yuy2 = Source.IsYUY2()
  982.     Source = yuy2 ? Source.converttoyv16() : Source
  983.  
  984.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  985.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  986.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  987.     # this new source. Result will still be shimmer-free and closer to the original source.
  988.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  989.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  990.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  991.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  992.     errorTemporalSimilarity = 0.5  # S in formula described above
  993.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  994.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  995.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  996.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  997.     yv16match1Edi  = EdiMode=="NNEDI2" || EdiMode=="NNEDI" || EdiMode=="EEDI3+NNEDI3" || EdiMode=="EEDI3" || EdiMode=="EEDI2" || EdiMode=="TDeint" || EdiMode=="cYadif" || EdiMode=="RepcYadif" || ChromaEdi=="cYadif"
  998.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  999.    !yv16match1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1000.                              match1Update.ConvertToYUY2() \
  1001.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1002.                                          .ConvertToYv16()
  1003.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1004.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1005.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1006.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1007.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1008.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1009.                      (MatchTR1 == 0)   ? match1Edi : \
  1010.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1011.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1012.  
  1013.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1014.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : match1
  1015.  
  1016.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1017.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1018.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1019.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1020.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1021.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1022.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1023.     yv16match1Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1024.                              match2Diff.ConvertToYUY2() \
  1025.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1026.                                        .ConvertToYv16()
  1027.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1028.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1029.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1030.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1031.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1032.     match2         = (SourceMatch < 2) ? match1 : \
  1033.                      (MatchTR2 == 0)   ? match2Edi : \
  1034.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1035.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1036.  
  1037.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1038.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1039.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1040.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 )
  1041.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1042.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1043.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1044.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1045.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1046.     match3         = (SourceMatch < 3) ? match2 : \
  1047.                      (MatchTR2 == 0)   ? match3Update : \
  1048.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1049.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1050.  
  1051.     # Apply difference calculated in source-match refinement
  1052.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1053. }
  1054.  
  1055.  
  1056. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1057. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1058. {
  1059.     Replace = default( Replace, false )
  1060.     globalName = Prefix + "_" + Name
  1061.  
  1062.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1063.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1064.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1065.     catch (e)
  1066.     {
  1067.         Eval( "global " + globalName + " = Value" )
  1068.         Replace = true
  1069.     }
  1070.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1071. }
  1072.  
  1073. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1074. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1075. {
  1076.     Reuse = default( Reuse, false )
  1077.     globalName = Prefix + "_" + Name
  1078.  
  1079.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1080.     catch (e) { ret = NOP() }
  1081.     return ret
  1082. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!