Pivot HiLo SR Levels R2

//@version=2

study(title="Pivot Hilo Support n Resistance Levels R2 by JustUncleL", shorttitle="PVTLVLS R2", overlay=true)

// By: JustUncleL
// Date: 20-Mar-2017
// Version: R2
//
// Description:
//   This Pivot Points marked with "star" and with Optional Support and Resistance extension Levels.
//
//   Options:
//   - Show Pivot Points (default true)
//   - Pivot Length Left Side (default 7), the number of bars left hand side of the Pivot candle.
//   - Pivot Length Right Side (default 7), the number of bars right hand side of the Pivot candle.
//   - Show S/R Extension Levels (default true)
//   - Maximum S/R Extension Length (default 0, no limit)
//   - Show Pivot Labels (instead of "star") "[P.H]" and "[P.L]"
//
// Modifications:
//  R2 - added option for different length test for each side of Pivot.
//  R1 - original.
//

// - INPUTS
ShowPivots       = input(true,title="Show Pivot Points")
pvtLenL          = input(7,minval=1,title="Pivot Length Left Hand Side")
pvtLenR          = input(7,minval=1,title="Pivot Length Right Hand Side")
ShowSRLevels     = input(true,title="Show S/R Level Extensions")
ShowPivotLabels  = input(false)
maxLvlLen        = input(0,minval=0, title="Maximum S/R Level Extension Length")

// - /INPUTS


// Get High and Low Pivot Points
pvthi = pivothigh(pvtLenL,pvtLenR)
pvtlo = pivotlow(pvtLenL,pvtLenR)


// If Selected Display Pivot points
plotchar(ShowPivots and not ShowPivotLabels? pvthi :na, title='High Pivot *', location=location.abovebar, color=green, offset=-pvtLenR,transp=0,size=size.auto)
plotchar(ShowPivots and not ShowPivotLabels? pvtlo :na,  title='Low Pivot *', location=location.belowbar, color=red, offset=-pvtLenR,transp=0,size=size.auto)
plotshape(ShowPivotLabels? pvthi: na, title='Pivot High Label', style=shape.diamond, location=location.abovebar, color=green, text="[P.H]", offset=-pvtLenR,transp=0)
plotshape(ShowPivotLabels? pvtlo: na, title='Pivot Low Label', style=shape.diamond, location=location.belowbar, color=red, text="[P.L]", offset=-pvtLenR,transp=0)

//plotshape(ShowPivots? toppvt :na, title='TOPPVT', style=shape.triangleup, location=location.abovebar, color=green, offset=-3,transp=0,size=size.tiny)
//plotshape(ShowPivots? botpvt :na, title='BOTPVT', style=shape.triangledown, location=location.belowbar, color=red, offset=-3,transp=0,size=size.tiny)


//Count How many candles for current Pivot Level, If new reset.
counthi = pvthi ? 0 : nz(counthi[1])+1
countlo = pvtlo ? 0 : nz(countlo[1])+1

pvthis = pvthi ? high[pvtLenR] : pvthis[1]
pvtlos = pvtlo ? low[pvtLenR] :  pvtlos[1]

hipc = (pvthis != pvthis[1]) ? na : green
lopc = (pvtlos != pvtlos[1]) ? na : red

plot(ShowSRLevels and (maxLvlLen==0 or counthi<maxLvlLen)? pvthis : na, color=hipc, transp=0, linewidth=2, offset=-pvtLenR, title="Top Levels")
plot(ShowSRLevels and (maxLvlLen==0 or countlo<maxLvlLen)? pvtlos : na, color=lopc, transp=0, linewidth=2, offset=-pvtLenR, title="Bottom Levels")

//
//EOF