API tools faq
paste
Advertisement
Guest User

QTGMC for avs 2.60

a guest
Dec 17th, 2016
223
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 79.25 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.343, by Vit, 2012, 2016 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.343s
  16. # - edit in ChromaEdi
  17. # - others
  18. #
  19. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  20. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  21. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  22. #
  23. # v3.33s (mod) 2016 12 06
  24. # - Add TR2=4 and TR2=5
  25. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  26. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  27. #
  28. # v3.33s (mod) 2016 04 11
  29. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  30. # - others
  31. #
  32. # v3.33s (mod) 2016 01 19
  33. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  34. #
  35. # v3.33s (mod) 2015 10 23
  36. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  37. #
  38. # v3.33s (mod) 2015 9 10
  39. # - fix Multiple QTGMC Calls
  40. # - others fix
  41. #
  42. # v3.33s (mod) 2015 8 6
  43. # - some changes in bob to speed up
  44. #
  45. # v3.33s (mod) 2015 8 4
  46. # - fix bug in YUY2 with SourceMatch
  47. # - add slice=false to ditherpost to avoid artefacts
  48. #
  49. # v3.33s (mod)
  50. # - fix bob chroma
  51. # - work with new masktool2 for avs 2.60 in YUY2
  52. #
  53. # v3.33d (mod)
  54. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  55. # - optimized some mask handling a bit as originally suggested by Vit
  56. # - others
  57. #
  58. # v3.33
  59. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  60. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  61. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  62. # - Minor change to denoising
  63. #
  64. # v3.32
  65. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  66. # - Tweaked vector recalculation for shutter motion blur
  67. # - Changed defaults for TR2 when using source-match
  68. # - Minor bugfix with SLMode/SLRad on pass-through settings
  69. #
  70. # --- REQUIREMENTS ---
  71. #
  72. # Input colorspaces: YV12, YUY2, others as plugins supports
  73. #
  74. # Core plugins:
  75. #   MVTools2 (2.7.5.22 or above from pinterf https://github.com/pinterf/mvtools/releases)
  76. #   MaskTools v2 (2.0b1 or above)
  77. #   NNEDI3 (0.9.4.6 or above)
  78. #   RgTools
  79. #
  80. # Additional plugins:
  81. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  82. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  83. #   FFT3DFilter - if selected for noise processing
  84. #   dfttest (1.9.4 or above) - if selected for noise processing
  85. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  86. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  87. #   KNLMeansCL - if selected for noise processing
  88. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  89.  
  90.  
  91. # --- GETTING STARTED ---
  92. #
  93. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  94. # To use QTGMC write a script like this:
  95. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  96. #   QTGMC( Preset="Slow" )
  97. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  98. #
  99. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  100. #
  101. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  102. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  103. # The default preset is "Slower"
  104. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  105. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  106. #
  107. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  108. #   QTGMC( Preset="Slow", ShowSettings=true )
  109.  
  110.  
  111. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  112.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  113.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  114.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  115.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  116.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  117.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  118.                     int "DftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  119.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  120.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  121.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  122.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "lsbd", bool "lsb" )
  123. {
  124.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  125.  
  126.     # Temporary Warnings
  127.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  128.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  129.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  130.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  131.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  132.  
  133.     #---------------------------------------
  134.     # Presets
  135.     lsbd         = default( lsbd,    false)
  136.     lsb          = default( lsb,     false)
  137.     Str          = default( Str,      1.0 )
  138.     Amp          = default( Amp,   0.0625 )
  139.     TV_range     = default( TV_range, true)
  140.  
  141.     # Select presets / tuning
  142.     Preset = default( Preset, "Slower" )
  143.     pNum = (Preset == "Placebo"   ) ? 0 : \
  144.            (Preset == "Very Slow" ) ? 1 : \
  145.            (Preset == "Slower"    ) ? 2 : \
  146.            (Preset == "Slow"      ) ? 3 : \
  147.            (Preset == "Medium"    ) ? 4 : \
  148.            (Preset == "Fast"      ) ? 5 : \
  149.            (Preset == "Faster"    ) ? 6 : \
  150.            (Preset == "Very Fast" ) ? 7 : \
  151.            (Preset == "Super Fast") ? 8 : \
  152.            (Preset == "Ultra Fast") ? 9 : \
  153.            (Preset == "Draft"     ) ? 10 : 11
  154.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  155.  
  156.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  157.              (MatchPreset == "Placebo"   ) ? 0 : \
  158.              (MatchPreset == "Very Slow" ) ? 1 : \
  159.              (MatchPreset == "Slower"    ) ? 2 : \
  160.              (MatchPreset == "Slow"      ) ? 3 : \
  161.              (MatchPreset == "Medium"    ) ? 4 : \
  162.              (MatchPreset == "Fast"      ) ? 5 : \
  163.              (MatchPreset == "Faster"    ) ? 6 : \
  164.              (MatchPreset == "Very Fast" ) ? 7 : \
  165.              (MatchPreset == "Super Fast") ? 8 : \
  166.              (MatchPreset == "Ultra Fast") ? 9 : \
  167.              (MatchPreset == "Draft"     ) ? 10 : 11
  168.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  169.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  170.  
  171.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  172.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  173.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  174.              (MatchPreset2 == "Slower"    ) ? 2 : \
  175.              (MatchPreset2 == "Slow"      ) ? 3 : \
  176.              (MatchPreset2 == "Medium"    ) ? 4 : \
  177.              (MatchPreset2 == "Fast"      ) ? 5 : \
  178.              (MatchPreset2 == "Faster"    ) ? 6 : \
  179.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  180.              (MatchPreset2 == "Super Fast") ? 8 : \
  181.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  182.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  183.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  184.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  185.  
  186.     NoisePreset = default( NoisePreset, "Fast" )
  187.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  188.             (NoisePreset == "Slow"   ) ? 1 : \
  189.             (NoisePreset == "Medium" ) ? 2 : \
  190.             (NoisePreset == "Fast"   ) ? 3 : \
  191.             (NoisePreset == "Faster" ) ? 4 : 5
  192.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  193.  
  194.     Tuning = default( Tuning, "None" )
  195.     tNum = (Tuning == "None"  ) ? 0 : \
  196.            (Tuning == "DV-SD" ) ? 1 : \
  197.            (Tuning == "DV-HD" ) ? 2 : 3
  198.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  199.  
  200.     # Tunings only affect blocksize in this version
  201.     bs = Select( tNum,  16, 16, 32 )
  202.     bs2 = (bs >= 16) ? 32 : bs * 2
  203.  
  204.     #                                                               Very                                                        Very      Super      Ultra
  205.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  206.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  207.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  208.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  209.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  210.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  211.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  212.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  213.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  214.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  215.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  216.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  217.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  218.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  219.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  220.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  221.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  222.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  223.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  224.     bs = Blocksize
  225.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  226.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  227.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  228.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  229.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  230.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  231.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  232.  
  233.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  234.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  235.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  236.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  237.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  238.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  239.  
  240.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  241.     SourceMatch   = default( SourceMatch, 0 )
  242.     MatchNNSize   = NNSize
  243.     MatchNNeurons = NNeurons
  244.     MatchEdiMaxD  = EdiMaxD
  245.     MatchEdiQual  = EdiQual
  246.  
  247.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  248.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  249.     #                                                                    Very                                                        Very      Super     Ultra
  250.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  251.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  252.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  253.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  254.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  255.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  256.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  257.     MatchEdi = TempEdi
  258.  
  259.     #                                                          Very                                                        Very      Super     Ultra
  260.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  261.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  262.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  263.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  264.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  265.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  266.  
  267.  
  268.     #---------------------------------------
  269.     # Settings
  270.  
  271.     # Core and Interpolation defaults
  272.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  273.     RepChroma  = default( RepChroma,  true )
  274.     EdiThreads = default( EdiThreads, 0    )
  275.     ChromaEdi  = default( ChromaEdi,  ""   )
  276.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  277.     EdiQual    = (EdiMode == "NNEDI3" && EdiQual > 2 ) ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  278.  
  279.     # Source-match / lossless defaults
  280.     MatchTR1     = TR1
  281.     MatchTR2     = default( MatchTR2,     1   )
  282.     MatchEnhance = default( MatchEnhance, 0.5 )
  283.     Lossless     = default( Lossless,     0   )
  284.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  285.  
  286.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  287.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  288.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  289.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  290.     spatialSL  = (SLMode == 1 || SLMode == 3)
  291.     temporalSL = (SLMode == 2 || SLMode == 4)
  292.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  293.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  294.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  295.     Sbb        = (SMode == 0) ? 0 : Sbb
  296.     SOvs       = default( SOvs,   0   )
  297.     SVThin     = default( SVThin, 0.0 )
  298.  
  299.     # Noise processing settings
  300.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  301.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  302.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  303.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  304.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  305.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  306.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  307.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  308.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  309.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  310.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  311.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  312.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  313.     Sigma        = defined(Sigma)       ? Sigma : \
  314.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  315.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  316.     DftThreads   = default( DftThreads, EdiThreads )
  317.     ChromaNoise  = default( ChromaNoise, false )
  318.     ShowNoise    = default( ShowNoise, 0.0 )
  319.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  320.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  321.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  322.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  323.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  324.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  325.     totalRestore = GrainRestore + NoiseRestore
  326.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  327.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  328.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  329.  
  330.     # MVTools settings
  331.     SubPelInterp = default( SubPelInterp, 2     )
  332.     TrueMotion   = default( TrueMotion,   false )
  333.     GlobalMotion = default( GlobalMotion, true  )
  334.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  335.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  336.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  337.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  338.     DCT          = default( DCT,     0          )
  339.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  340.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  341.     ThSCD1       = default( ThSCD1,  180        )
  342.     ThSCD2       = default( ThSCD2,  98         )
  343.  
  344.     # Motion blur settings
  345.     FPSDivisor  = default( FPSDivisor, 1 )
  346.     ShutterBlur = default( ShutterBlur, 0 )
  347.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  348.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  349.     SBlurLimit  = default( SBlurLimit, 4 )
  350.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  351.  
  352.     # Miscellaneous
  353.     InputType      = default( InputType,     0        )
  354.     Border         = default( Border,        false    )
  355.     ShowSettings   = default( ShowSettings,  false    )
  356.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  357.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  358.     ForceTR        = default( ForceTR,       0        )
  359.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  360.     ReuseGlobals   = (PrevGlobals == "Reuse")
  361.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  362.     rgBlur         = (Precise) ? 11 : 12
  363.  
  364.     # Get maximum temporal radius needed
  365.     maxTR = (temporalSL)       ? SLRad : 0
  366.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  367.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  368.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  369.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  370.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  371.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  372.  
  373.  
  374.     #---------------------------------------
  375.     # Pre-Processing
  376.  
  377.     w = Input.Width()
  378.     h = Input.Height()
  379.     yuy2 = Input.IsYUY2()
  380.     epsilon = 0.0001
  381.  
  382.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  383.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  384.  
  385.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  386.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  387.     h = (Border) ? h+8 : h
  388.  
  389.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  390.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  391.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  392.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  393.     vpad = (vpad > 8) ? vpad : 8
  394.  
  395.  
  396.     #---------------------------------------
  397.     # Motion Analysis
  398.  
  399.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  400.     planarClip = yuy2 ? clip.converttoyv16() : clip
  401.  
  402.     # Bob the input as a starting point for motion search clip
  403.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  404.              (InputType == 1) ? planarClip : \
  405.                                 planarClip.Blur( 0,1 )
  406.  
  407.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  408.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  409.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  410.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  411.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  412.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  413.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  414.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  415.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  416.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  417.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  418.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  419.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  420.  
  421.     CMmt = ChromaMotion ? 3   :  1
  422.     CMts = ChromaMotion ? 255 :  0
  423.     CMrg = ChromaMotion ? 12  : -1
  424.  
  425.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  426.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  427.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  428.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  429.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  430.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  431.  
  432.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  433.     binomial0 = IsClip(srchClip) ? NOP() : \
  434.                 (TR0 == 0)       ? bobbed : \
  435.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  436.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  437.  
  438.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  439.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  440.  
  441.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  442.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  443.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  444.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  445.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  446.  
  447.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  448.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : NOP()
  449.     srchcheck   = IsClip(srchClip)
  450.     srchClip    = srchcheck         ? srchClip : \
  451.                   (SrchClipPP == 0) ? repair0 : \
  452.                   (SrchClipPP < 3)  ? spatialBlur : \
  453.                                       spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  454.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  455.     # Calculate forward and backward motion vectors from motion search clip
  456.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  457.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  458.     bVec5 = IsClip(bVec5) ? bVec5 : \
  459.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  460.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  461.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  462.     bVec4 = IsClip(bVec4) ? bVec4 : \
  463.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  464.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  465.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  466.     bVec3 = IsClip(bVec3) ? bVec3 : \
  467.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  468.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  469.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  470.     bVec2 = IsClip(bVec2) ? bVec2 : \
  471.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  472.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  473.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  474.     bVec1 = IsClip(bVec1) ? bVec1 : \
  475.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  476.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  477.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  478.     fVec1 = IsClip(fVec1) ? fVec1 : \
  479.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  480.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  481.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  482.     fVec2 = IsClip(fVec2) ? fVec2 : \
  483.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  484.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  485.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  486.     fVec3 = IsClip(fVec3) ? fVec3 : \
  487.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  488.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  489.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  490.     fVec4 = IsClip(fVec4) ? fVec4 : \
  491.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  492.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  493.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  494.     fVec5 = IsClip(fVec5) ? fVec5 : \
  495.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  496.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  497.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  498.  
  499.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  500.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  501.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  502.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  503.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  504.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  505.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  506.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  507.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  508.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  509.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  510.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  511.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  512.  
  513.  
  514.     #---------------------------------------
  515.     # Noise Processing
  516.  
  517.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  518.  
  519.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  520.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  521.                 (InputType > 0)     ? clip : \
  522.                                       clip.QTGMC_Bob( 0,1.0 )
  523.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.converttoyv16() : fullClip
  524.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  525.  
  526.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  527.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  528.                   (!DenoiseMC)        ? fullClip : \
  529.                   (NoiseTR == 0)      ? fullClip : \
  530.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  531.                                                     fullClip, \
  532.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  533.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  534.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  535.                                                     fullClip, \
  536.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  537.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  538.     noiseWindow = yuy2 && (Denoiser == "FFT3DFilter") && NoiseTR > 0 ? noiseWindow.ConvertToYUY2() : noiseWindow
  539.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  540.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=DftThreads, lsb=lsbd ) : \
  541.             (Denoiser == "KNLMeansCL")  ? KNLMeansCL( lsbd ? noiseWindow.Dither_convert_8_to_16() : noiseWindow, d=NoiseTR, h=Sigma, lsb_inout=lsbd, device_type="GPU") : \
  542.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD )
  543.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  544.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.ConvertToYUY2() : dnWindow
  545.  
  546.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  547.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  548.     denoised = (NoiseProcess == 0) ? NOP() : \
  549.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  550.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  551.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  552.  
  553.     # >>>> Switch to planar YUY2 for noise bypass
  554.  
  555.     CNmt1   = ChromaNoise ? 3 : 1
  556.     CNmt2   = ChromaNoise ? 3 : 2
  557.     CNmt128 = ChromaNoise ? 3 : -128
  558.  
  559.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  560.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.converttoyv16() : denoised
  561.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  562.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  563.                  (InputType != 0)                           ? noise : \
  564.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  565.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  566.                                                               noise.DoubleWeave()
  567.     # Motion-compensated stabilization of generated noise
  568.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  569.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  570.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  571.  
  572.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  573.     innerClip = (NoiseProcess == 1) ? denoised : clip
  574.  
  575.  
  576.     #---------------------------------------
  577.     # Interpolation
  578.  
  579.     # >>>> Interleaved YUY2 for interpolation
  580.  
  581.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  582.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  583.  
  584.     # Create interpolated image as starting point for output
  585.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  586.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  587.  
  588.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  589.  
  590.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  591.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  592.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.ConvertToYV16()) :\
  593.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).ConvertToYV16()) : \
  594.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  595.                                                         mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend, U=2,V=2 ))
  596.  
  597.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  598.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  599.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  600.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  601.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  602.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  603.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  604.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  605.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  606.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  607.  
  608.  
  609.     #---------------------------------------
  610.     # Create basic output
  611.  
  612.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  613.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  614.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  615.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  616.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  617.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  618.     degrain1 = (TR1 > 0) && lsb ? degrain1.ditherpost(mode=6, slice=false) : degrain1
  619.     degrain2 = (TR1 > 1) && lsb ? degrain2.ditherpost(mode=6, slice=false) : degrain2
  620.  
  621.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  622.     binomial1 = (TR1 == 0) ? edi : \
  623.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  624.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  625.  
  626.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  627.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  628.  
  629.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  630.     match = (SourceMatch == 0) ? repair1 : \
  631.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  632.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  633.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  634.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  635.  
  636.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  637.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  638.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  639.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  640.  
  641.  
  642.     #---------------------------------------
  643.     # Resharpen / retouch output
  644.  
  645.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  646.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  647.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  648.     resharp   = (SMode == 0) ? lossed1 : \
  649.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  650.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  651.  
  652.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  653.     SVThinSc = SVThin * 6.0
  654.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  655.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  656.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  657.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  658.  
  659.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  660.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  661.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  662.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  663.  
  664.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  665.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  666.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  667.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  668.                                   backBlend1
  669.  
  670.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  671.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  672.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  673.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  674.  
  675.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  676.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  677.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  678.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  679.  
  680.     # Final light linear temporal smooth for denoising
  681.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  682.     stable  = (TR2 == 0) ? addNoise1 : \
  683.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  684.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  685.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  686.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  687.                            addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb )
  688.     stable  = (TR2 > 0) && lsb ? stable.ditherpost(mode=6, slice=false) : stable
  689.  
  690.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  691.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  692.  
  693.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  694.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  695.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  696.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  697.                                   repair2
  698.  
  699.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  700.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  701.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  702.  
  703.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  704.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  705.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  706.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  707.  
  708.  
  709.     #---------------------------------------
  710.     # Post-Processing
  711.  
  712.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  713.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  714.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  715.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  716.  
  717.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  718.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  719.     rBlockSize = BlockSize / rBlockDivide
  720.     rOverlap   = Overlap   / rBlockDivide
  721.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  722.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  723.     rBlockDivide = BlockSize / rBlockSize
  724.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  725.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  726.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  727.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  728.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  729.  
  730.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  731.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  732.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  733.  
  734.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  735.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  736.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  737.                    (SBlurLimit == 0)  ? sblur : \
  738.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  739.     # Reduce frame rate
  740.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  741.  
  742.     # Crop off temporary vertical padding
  743.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  744.     h = Border ? h-8 : h
  745.  
  746.     # Show output of choice + settings
  747.     # >>>> Restore YUY2 to interleaved
  748.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  749.     output = yuy2 ? output.ConvertToYUY2() : output
  750.     return (ShowSettings == false) ? output : \
  751.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  752.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  753.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  754.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  755.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  756.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  757.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  758.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  759.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  760.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  761.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  762.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  763.         Denoiser + "' | DftThreads=" + string(DftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  764.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  765.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  766.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  767.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  768.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  769.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  770.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  771. }
  772.  
  773.  
  774. #---------------------------------------
  775. # Helpers
  776.  
  777. # Same as Bob, but keeps the field order the same.
  778. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  779. {
  780.   ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  781.   h = Default(height, cp.Height)
  782.   w = cp.Width
  783.   shift = GetParity(cp) ? 0.25 : -0.25
  784.  
  785.   c420 = ssispmt ? Is420(cp) : IsYV12(cp)
  786.  
  787.   c420 ? cp.SeparateFields() : nop()
  788.  
  789.   oeven=c420 ? SelectEven() : nop()
  790.   oodd=c420 ? SelectOdd() : nop()
  791.  
  792.   even=c420 ? ssispmt ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  793.   odd=c420 ? ssispmt ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  794.  
  795.   evenChr=c420 ? Interleave(ssispmt ? oeven.ExtractU() : oeven.UToY8(), ssispmt ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  796.   oddChr=c420 ? Interleave(ssispmt ? oodd.ExtractU() : oodd.UToY8(), ssispmt ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  797.  
  798.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  799.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  800. }
  801.  
  802.  
  803. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  804. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  805. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  806.                             string "ChromaEdi" )
  807. {
  808.     # >>>> YUY2 is interleaved here
  809.  
  810.     ChromaEdi = default( ChromaEdi, "" )
  811.     CEed = (ChromaEdi == "")
  812.  
  813.     interp = (InputType == 1)            ? Input : \
  814.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  815.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  816.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  817.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  818.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  819.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  820.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  821.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  822.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  823.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  824.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.ConvertToYv16().Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  825.                                                            Input.Yadifmod2( mode=3 ) : \   
  826.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).ConvertToYv16(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  827.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  828.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  829.  
  830.     interpuv = (InputType == 1)        ? NOP() : \
  831.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  832.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  833.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  834.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  835.                                          NOP()
  836.  
  837.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  838. }
  839.  
  840.  
  841. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  842. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  843. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  844. {
  845.     # >>>> YUY2 is planar here
  846.     mtY =default( Y, 3 )
  847.     mtU =default( U, 1 )
  848.     mtV =default( V, 1 )
  849.     rgY = (mtY == 3) ? 20 : -1
  850.     rgU = (mtU == 3) ? 20 : -1
  851.     rgV = (mtV == 3) ? 20 : -1
  852.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  853. }
  854.  
  855. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  856. {
  857.     # >>>> YUY2 is planar here
  858.     mtY =default( Y, 3 )
  859.     mtU =default( U, 1 )
  860.     mtV =default( V, 1 )
  861.     rgY = (mtY == 3) ? 20 : -1
  862.     rgU = (mtU == 3) ? 20 : -1
  863.     rgV = (mtV == 3) ? 20 : -1
  864.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  865. }
  866.  
  867. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  868. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  869. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  870. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  871. {
  872.     # >>>> YUY2 is planar here
  873.  
  874.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  875.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  876.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  877.     Rep    = default( Rep,    1    )
  878.     Chroma = default( Chroma, true )
  879.     ed = (Rep < 10) ? Rep : Rep / 10
  880.     od = (Rep < 10) ? 0   : Rep % 10
  881.     RCrg  = Chroma ? 3 : 1
  882.     RCrgo = Chroma ? 3 : 2
  883.  
  884.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  885.  
  886.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  887.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  888.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  889.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  890.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  891.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  892.                                                                                                                      
  893.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  894.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  895.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  896.  
  897.     # Over-dilation - extra reflation up to about 1 pixel
  898.     choke1 = (od == 0)            ? choke1 : \
  899.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  900.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  901.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  902.  
  903.     # Areas of negative difference (similar to above)
  904.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  905.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  906.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  907.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  908.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  909.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  910.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  911.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  912.     choke2 = (od == 0)            ? choke2 : \
  913.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  914.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  915.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  916.  
  917.     # Combine above areas to find those areas of difference to restore
  918.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  919.  
  920.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  921. }
  922.  
  923.  
  924. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  925. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  926. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  927. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  928. {
  929.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  930.     ChromaNoise = default( ChromaNoise, false )
  931.     CNmt1 = ChromaNoise ? 3 : 1
  932.     origNoise = Input.SeparateFields()
  933.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  934.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  935.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  936.     random    = InterleavedClip.IsYUY2() ? random.converttoyv16() : random
  937.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  938.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  939.     return Interleave( origNoise, newNoise ).Weave()
  940. }
  941.  
  942.  
  943. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  944. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  945. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  946. {
  947.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  948.  
  949.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  950.  
  951.     # Weave the source fields and the "new" fields that have generated in the input
  952.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  953.     srcFields  = Source.IsYUY2() ? srcFields1.converttoyv16() : srcFields1
  954.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  955.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  956.  
  957.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  958.     vertMedian  = processed.VerticalCleaner( mode=1 )
  959.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  960.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  961.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  962.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  963.  
  964.     # Reweave final result
  965.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  966. }
  967.  
  968.  
  969. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  970. # the source without introducing shimmer. All other arguments defined in main script
  971. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  972.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  973.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  974.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  975.                                  float MatchEnhance, int EdiThreads, bool lsb )
  976. {
  977.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  978.     yuy2 = Source.IsYUY2()
  979.     Source = yuy2 ? Source.converttoyv16() : Source
  980.  
  981.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  982.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  983.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  984.     # this new source. Result will still be shimmer-free and closer to the original source.
  985.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  986.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  987.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  988.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  989.     errorTemporalSimilarity = 0.5  # S in formula described above
  990.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  991.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  992.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  993.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  994.     yv16match1Edi  = EdiMode=="NNEDI2" || EdiMode=="NNEDI" || EdiMode=="EEDI3+NNEDI3" || EdiMode=="EEDI3" || EdiMode=="EEDI2" || EdiMode=="TDeint" || EdiMode=="cYadif" || EdiMode=="RepcYadif" || ChromaEdi=="cYadif"
  995.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  996.    !yv16match1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  997.                              match1Update.ConvertToYUY2() \
  998.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  999.                                          .ConvertToYv16()
  1000.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1001.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1002.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1003.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1004.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1005.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1006.                      (MatchTR1 == 0)   ? match1Edi : \
  1007.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1008.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1009.  
  1010.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1011.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : match1
  1012.  
  1013.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1014.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1015.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1016.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1017.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1018.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1019.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1020.     yv16match1Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1021.                              match2Diff.ConvertToYUY2() \
  1022.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1023.                                        .ConvertToYv16()
  1024.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1025.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1026.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1027.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1028.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1029.     match2         = (SourceMatch < 2) ? match1 : \
  1030.                      (MatchTR2 == 0)   ? match2Edi : \
  1031.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1032.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1033.  
  1034.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1035.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1036.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1037.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 )
  1038.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1039.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1040.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1041.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1042.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1043.     match3         = (SourceMatch < 3) ? match2 : \
  1044.                      (MatchTR2 == 0)   ? match3Update : \
  1045.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1046.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1047.  
  1048.     # Apply difference calculated in source-match refinement
  1049.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1050. }
  1051.  
  1052.  
  1053. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1054. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1055. {
  1056.     Replace = default( Replace, false )
  1057.     globalName = Prefix + "_" + Name
  1058.  
  1059.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1060.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1061.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1062.     catch (e)
  1063.     {
  1064.         Eval( "global " + globalName + " = Value" )
  1065.         Replace = true
  1066.     }
  1067.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1068. }
  1069.  
  1070. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1071. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1072. {
  1073.     Reuse = default( Reuse, false )
  1074.     globalName = Prefix + "_" + Name
  1075.  
  1076.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1077.     catch (e) { ret = NOP() }
  1078.     return ret
  1079. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!